Skip to main content
Version: v20 R4 BETA

Collection

The Collection class manages Collection type variables.

A collection is initialized with:

New collection {( ...value : any )} : Collection     creates a new empty or prefilled collection
New shared collection {( ...value : any )} : Collection     creates a new empty or prefilled shared collection

Example

 var $colVar : Collection //creation of collection type 4D variable
$colVar:=New collection //initialization of the collection and assignment to the 4D variable

Summary

.at( index : Integer ) : any     returns the item at position index, allowing for positive and negative integers
.average( {propertyPath : Text } ) : Real    returns the arithmetic mean (average) of defined values in the collection instance
.clear() : Collection    removes all elements from the collection instance and returns an empty collection
.combine( col2 : Collection {; index : Integer } ) : Collection    inserts col2 elements at the end or at the specified index position in the collection instance and returns the edited collection
.concat( value : any { ;...valueN } ) : Collection    returns a new collection containing the elements of the original collection with all elements of the value parameter added to the end
.copy() : Collection
.copy( option : Integer ) : Collection
.copy( option : Integer ; groupWithCol : Collection ) : Collection
.copy( option : Integer ; groupWithObj : Object ) : Collection
     returns a deep copy of the collection instance
.count( { propertyPath : Text } ) : Real    returns the number of non-null elements in the collection
.countValues( value : any {; propertyPath : Text } ) : Real    returns the number of times value is found in the collection
.distinct( {options : Integer} ) : Collection
.distinct( propertyPath : Text {; options : Integer } ) : Collection
    returns a collection containing only distinct (different) values from the original collection
.equal( collection2 : Collection {; option : Integer } ) : Boolean    compares the collection with collection2
.every( { startFrom : Integer ; } formula : 4D.Function { ;...param : any } ) : Boolean
.every( { startFrom : Integer ; } methodName : Text { ;...param : any } ) : Boolean
    returns true if all elements in the collection successfully passed a test implemented in the provided formula object or methodName name
.extract( propertyPath : Text { ; option : Integer } ) : Collection
.extract( propertyPath : Text ; targetPath : Text { ;...propertyPathOrTargetPathN : Text } ) : Collection
    creates and returns a new collection containing propertyPath values extracted from the original collection of objects
.fill( value : any ) : Collection
.fill( value : any ; startFrom : Integer { ; end : Integer } ) : Collection
    fills the collection with the specified value, optionally from startFrom index to end index, and returns the resulting collection
.filter( formula : 4D.Function { ; ...param : any } ) : Collection
.filter( methodName : Text { ; ...param : any } ) : Collection
    returns a new collection containing all elements of the original collection for which the formula or methodName result is true
.find( { startFrom : Integer ; } formula : 4D.Function { ; ...param : any } ) : any
.find( { startFrom : Integer ; } methodName : Text { ; ...param : any } ) : any
    returns the first value in the collection for which formula or methodName result, applied on each element, returns true
.findIndex( { startFrom : Integer ; } formula : 4D.Function { ; ...param : any } ) : Integer
.findIndex( { startFrom : Integer ; } methodName : Text { ; ...param : any } ) : Integer
    returns the index, in the collection, of the first value for which formula or methodName, applied on each element, returns true
.first() : any     returns the first element of the collection
.flat( { depth : Integer } ) : Collection    creates a new collection with all sub-collection elements concatenated into it recursively up to the specified depth
.flatMap( formula : 4D.Function { ; ...param : any } ) : Collection
.flatMap( methodName : Text { ; ...param : any } ) : Collection
    creates a new collection based upon the result of the call of the formula 4D function or methodName method on each element of the original collection and flattened by a depth of 1
.includes( toSearch : expression { ; startFrom : Integer } ) : Boolean    returns True if the toSearch expression is found among collection elements, otherwise False
.indexOf( toSearch : expression { ; startFrom : Integer } ) : Integer     searches the toSearch expression among collection elements and returns the index of the first found occurrence, or -1 if it was not found
.indices( queryString : Text { ; ...value : any } ) : Collection     returns indexes, in the original collection, of object collection elements that match the queryString search conditions
.insert( index : Integer ; element : any ) : Collection      inserts element at the specified index position in the collection instance and returns the edited collection
.join( delimiter : Text { ; option : Integer } ) : Text     converts all elements of the collection to strings and concatenates them using the specified delimiter string as separator
.last() : any     returns the last element of the collection
.lastIndexOf( toSearch : expression { ; startFrom : Integer } ) : Integer     searches the toSearch expression among collection elements and returns the index of the last occurrence
.length : Integer    returns the number of elements in the collection
.map( formula : 4D.Function { ; ...param : any } ) : Collection
.map( methodName : Text { ; ...param : any } ) : Collection
    creates a new collection based upon the result of the call of the formula 4D function or methodName method on each element of the original collection
.max( { propertyPath : Text } ) : any     returns the element with the highest value in the collection
.min( { propertyPath : Text } ) : any     returns the element with the smallest value in the collection
.multiSort() : Collection
.multiSort( colsToSort : Collection ) : Collection
.multiSort( formula : 4D.Function ; colsToSort : Collection ) : Collection
    enables you to carry out a multi-level synchronized sort on a set of collections
.orderBy( ) : Collection
.orderBy( pathStrings : Text ) : Collection
.orderBy( pathObjects : Collection ) : Collection
.orderBy( ascOrDesc : Integer ) : Collection
    returns a new collection containing all elements of the collection in the specified order
.orderByMethod( formula : 4D.Function { ; ...extraParam : expression } ) : Collection
.orderByMethod( methodName : Text { ; ...extraParam : expression } ) : Collection
    returns a new collection containing all elements of the collection in the order defined through the formula 4D function or methodName method
.pop() : any     removes the last element from the collection and returns it as the function result
.push( element : any { ;...elementN } ) : Collection     appends one or more element(s) to the end of the collection instance and returns the edited collection
.query( queryString : Text ; ...value : any ) : Collection
.query( queryString : Text ; querySettings : Object ) : Collection
    returns all elements of a collection of objects that match the search conditions
.reduce( formula : 4D.Function { ; initValue : any { ; ...param : expression }} ) : any
.reduce( methodName : Text { ; initValue : any { ; ...param : expression }} ) : any
    applies the formula or methodName callback against an accumulator and each element in the collection (from left to right) to reduce it to a single value
.reduceRight( formula : 4D.Function { ; initValue : any { ; ...param : expression }} ) : any
.reduceRight( methodName : Text { ; initValue : any { ; ...param : expression }} ) : any
    applies the formula or methodName callback against an accumulator and each element in the collection (from right to left) to reduce it to a single value
.remove( index : Integer { ; howMany : Integer } ) : Collection     removes one or more element(s) from the specified index position in the collection and returns the edited collection
.resize( size : Integer { ; defaultValue : any } ) : Collection     sets the collection length to the specified new size and returns the resized collection
.reverse( ) : Collection     returns a deep copy of the collection with all its elements in reverse order
.shift() : any    removes the first element of the collection and returns it as the function result
.slice( startFrom : Integer { ; end : Integer } ) : Collection    returns a portion of a collection into a new collection
.some( { startFrom : Integer ; } formula : 4D.Function { ; ...param : any } ) : Boolean
.some( { startFrom : Integer ; } methodName : Text { ; ...param : any } ) : Boolean
    returns true if at least one element in the collection successfully passed a test implemented in the provided formula or methodName code
.sort() : Collection
.sort( formula : 4D.Function { ; ...extraParam : any } ) : Collection
.sort( methodName : Text { ; ...extraParam : any } ) : Collection
    sorts the elements of the original collection and also returns the sorted collection
.sum( { propertyPath : Text } ) : Real    returns the sum for all values in the collection instance
.unshift( value : any { ;...valueN : any } ) : Collection    inserts the given value(s) at the beginning of the collection

New collection

New collection {( ...value : any )} : Collection

ParameterTypeDescription
valueNumber, Text, Date, Time, Boolean, Object, Collection, Picture, Pointer->Collection's value(s)
ResultCollection<-New collection

Description

The New collection command creates a new empty or prefilled collection and returns its reference.

If you do not pass any parameters, New collection creates an empty collection and returns its reference.

You must assign the returned reference to a 4D variable of the Collection type.

Keep in mind that var : Collection or C_COLLECTION statements declare a variable of the Collection type but does not create any collection.

Optionally, you can prefill the new collection by passing one or several value(s) as parameter(s).

Otherwise, you can add or modify elements subsequently through assignment. For example:

 myCol[10]:="My new element"

If the new element index is beyond the last existing element of the collection, the collection is automatically resized and all new intermediary elements are assigned a null value.

You can pass any number of values of any supported type (number, text, date, picture, pointer, object, collection...). Unlike arrays, collections can mix data of different types.

You must pay attention to the following conversion issues:

  • If you pass a pointer, it is kept "as is"; it is evaluated using the JSON Stringify command
  • Dates are stored as "yyyy-mm-dd" dates or strings with the "YYYY-MM-DDTHH:mm:ss.SSSZ" format, according to the current "dates inside objects" database setting. When converting 4D dates into text prior to storing them in the collection, by default the program takes the local time zone into account. You can modify this behavior using the Dates inside objects selector of the SET DATABASE PARAMETER command.
  • If you pass a time, it is stored as a number of milliseconds (Real).

Example 1

You want to create a new empty collection and assign it to a 4D collection variable:

 var $myCol : Collection
$myCol:=New collection
//$myCol=[]

Example 2

You want to create a prefilled collection:

 var $filledColl : Collection
$filledColl:=New collection(33;"mike";"november";->myPtr;Current date)
//$filledColl=[33,"mike","november","->myPtr","2017-03-28T22:00:00.000Z"]

Example 3

You create a new collection and then add a new element:

 var $coll : Collection
$coll:=New collection("a";"b";"c")
//$coll=["a","b","c"]
$coll[9]:="z" //add a 10th element with value "z"
$vcolSize:=$coll.length //10
//$coll=["a","b","c",null,null,null,null,null,null,"z"]

New shared collection

History
VersionChanges
v16 R6Added

New shared collection {( ...value : any )} : Collection

ParameterTypeDescription
valueNumber, Text, Date, Time, Boolean, Shared object, Shared collection->Shared collection's value(s)
ResultCollection<-New shared collection

Description

The New shared collection command creates a new empty or prefilled shared collection and returns its reference.

Adding an element to this collection using the assignment operator must be surrounded by the Use...End use structure, otherwise an error is generated (this is not necessary when adding elements using functions such as push() or map() because they automatically trigger an internal Use...End use). Reading an element without a Use...End use structure is, however, possible.

info

For more information on shared collections, please refer to the Shared objects and collections page.

If you do not pass any parameters, New shared collection creates an empty shared collection and returns its reference.

You must assign the returned reference to a 4D variable of the Collection type.

Keep in mind that var : Collection or C_COLLECTION statements declare a variable of the Collection type but do not create any collection.

Optionally, you can prefill the new shared collection by passing one or several value(s) as parameter(s). Otherwise, you can add or modify elements subsequently through object notation assignment (see example).

If the new element index is beyond the last existing element of the shared collection, the collection is automatically resized and all new intermediary elements are assigned a null value.

You can pass any number of values of the following supported types:

  • number (real, longint...). Number values are always stored as reals.
  • text
  • boolean
  • date
  • time (stored as number of milliseconds - real)
  • null
  • shared object(*)
  • shared collection(*)
note

Unlike standard (not shared) collections, shared collections do not support pictures, pointers, and objects or collections that are not shared.

(*)When a shared object or collection is added to a shared collection, they share the same locking identifier. For more information on this point, refer to 4D Doc Center.

Example

 $mySharedCol:=New shared collection("alpha";"omega")
Use($mySharedCol)
$mySharedCol[1]:="beta"
End use

.at()

History
VersionChanges
v20Added

.at( index : Integer ) : any

ParameterTypeDescription
indexInteger->Index of element to return
Resultany<-The element at that index

Description

The .at() function returns the item at position index, allowing for positive and negative integers.

This function does not modify the original collection.

Negative integers count back from the last item in the collection.

The function returns Undefined if index is beyond collection limits.

Example

var $col : Collection 
$col:=New collection(10; 20; 30; 40; 50)
$element:=$col.at(0) // 10
$element:=$col.at(1) // 20
$element:=$col.at(-1) // 50
$element:=$col.at(-2) // 40
$element:=$col.at(10) // undefined

.average()

History
VersionChanges
v16 R6Added

.average( {propertyPath : Text } ) : Real

ParameterTypeDescription
propertyPathText->Object property path to be used for calculation
ResultReal, Undefined<-Arithmetic mean (average) of collection values

Description

The .average() function returns the arithmetic mean (average) of defined values in the collection instance.

Only numerical elements are taken into account for the calculation (other element types are ignored).

If the collection contains objects, pass the propertyPath parameter to indicate the object property to take into account.

.average() returns undefined if:

  • the collection is empty,
  • the collection does not contain numerical elements,
  • propertyPath is not found in the collection.

Example 1

 var $col : Collection
$col:=New collection(10;20;"Monday";True;6)
$vAvg:=$col.average() //12

Example 2

 var $col : Collection
$col:=New collection
$col.push(New object("name";"Smith";"salary";10000))
$col.push(New object("name";"Wesson";"salary";50000))
$col.push(New object("name";"Gross";"salary";10500))
$vAvg:=$col.average("salary") //23500

.clear()

History
VersionChanges
v16 R6Added

.clear() : Collection

ParameterTypeDescription
ResultCollection<-Original collection with all elements removed

Description

The .clear() function removes all elements from the collection instance and returns an empty collection.

This function modifies the original collection.

Example

var $col : Collection
$col:=New collection(1;2;5)
$col.clear()
$vSize:=$col.length //$vSize=0

.combine()

History
VersionChanges
v16 R6Added

.combine( col2 : Collection {; index : Integer } ) : Collection

ParameterTypeDescription
col2Collection->Collection to combine
indexInteger->Position to which insert elements to combine in collection (default=length+1)
ResultCollection<-Original collection containing combined element(s)

Description

The .combine() function inserts col2 elements at the end or at the specified index position in the collection instance and returns the edited collection. Unlike the .insert() function, .combine() adds each value of col2 in the original collection, and not as a single collection element.

This function modifies the original collection.

By default, col2 elements are added at the end of the orginal collection. You can pass in index the position where you want the col2 elements to be inserted in the collection.

Warning: Keep in mind that collection elements are numbered from 0.

  • If index > the length of the collection, the actual starting index will be set to the length of the collection.
  • If index < 0, it is recalculated as index:=index+length (it is considered as the offset from the end of the collection).
  • If the calculated value is negative, index is set to 0.

Example

var $c; $fruits : Collection
$c:=New collection(1;2;3;4;5;6)
$fruits:=New collection("Orange";"Banana";"Apple";"Grape")
$c.combine($fruits;3) //[1,2,3,"Orange","Banana","Apple","Grape",4,5,6]

.concat()

History
VersionChanges
v16 R6Added

.concat( value : any { ;...valueN } ) : Collection

ParameterTypeDescription
valueNumber, Text, Object, Collection, Date, Time, Boolean, Picture->Value(s) to concatenate. If value is a collection, all collection elements are added to the original collection
ResultCollection<-New collection with value(s) added to the original collection

Description

The .concat() function returns a new collection containing the elements of the original collection with all elements of the value parameter added to the end.

This function does not modify the original collection.

If value is a collection, all its elements are added as new elements at the end of the original collection. If value is not a collection, it is added itself as a new element.

Example

var $c : Collection
$c:=New collection(1;2;3;4;5)
$fruits:=New collection("Orange";"Banana";"Apple";"Grape")
$fruits.push(New object("Intruder";"Tomato"))
$c2:=$c.concat($fruits) //[1,2,3,4,5,"Orange","Banana","Apple","Grape",{"Intruder":"Tomato"}]
$c2:=$c.concat(6;7;8) //[1,2,3,4,5,6,7,8]

.copy()

History
VersionChanges
v18 R3New ck shared option. New groupWith parameters
v16 R6Added

.copy() : Collection
.copy( option : Integer ) : Collection
.copy( option : Integer ; groupWithCol : Collection ) : Collection
.copy( option : Integer ; groupWithObj : Object ) : Collection

ParameterTypeDescription
optionInteger->ck resolve pointers: resolve pointers before copying,
ck shared: return a shared collection
groupWithColCollection->Shared collection to be grouped with the resulting collection
groupWithObjObject->Shared object to be grouped with the resulting collection
ResultCollection<-Deep copy of the original collection

Description

The .copy() function returns a deep copy of the collection instance.Deep copy means that objects or collections within the original collection are duplicated and do not share any reference with the returned collection.

This function does not modify the original collection.

If passed, the option parameter can contain one of the following constants (or both):

optionDescription
ck resolve pointersIf the original collection contains pointer type values, by default the copy also contains the pointers. However, you can resolve pointers when copying by passing the ck resolve pointers constant. In this case, each pointer present in the collection is evaluated when copying and its dereferenced value is used.
ck sharedBy default, copy() returns a regular (not shared) collection, even if the command is applied to a shared collection. Pass the ck shared constant to create a shared collection. In this case, you can use the groupWith parameter to associate the shared collection with another collection or object (see below).

The groupWithCol or groupWithObj parameters allow you to designate a collection or an object with which the resulting collection should be associated.

note

Datastore, dataclass, and entity objects are not copiable. If .copy() is called with them, Null values are returned.

Example 1

We want to copy the $lastnames regular (non shared) collection into the $sharedObject shared object. To do this, we must create a shared copy of the collection ($sharedLastnames).

var $sharedObject : Object
var $lastnames;$sharedLastnames : Collection
var $text : Text

$sharedObject:=New shared object

$text:=Document to text(Get 4D folder(Current resources folder)+"lastnames.txt")
$lastnames:=JSON Parse($text) //$lastnames is a regular collection

$sharedLastnames:=$lastnames.copy(ck shared) //$sharedLastnames is a shared collection

//Now we can put $sharedLastnames into $sharedObject
Use($sharedObject)
$sharedObject.lastnames:=$sharedLastnames
End use

Example 2

We want to combine $sharedColl1 and $sharedColl2. Since they belong to different shared groups, a direct combination would result in an error. Therefore, we must make a shared copy of $sharedColl1 and designate $sharedColl2 as a shared group for the copy.

var $sharedColl1;$sharedColl2;$copyColl : Collection

$sharedColl1:=New shared collection(New shared object("lastname";"Smith"))
$sharedColl2:=New shared collection(New shared object("lastname";"Brown"))

//$copyColl belongs to the same shared group as $sharedColl2
$copyColl:=$sharedColl1.copy(ck shared;$sharedColl2)
Use($sharedColl2)
$sharedColl2.combine($copyColl)
End use

Example 3

We have a regular collection ($lastnames) and we want to put it in the Storage of the application. To do this, we must create a shared copy beforehand ($sharedLastnames).

var $lastnames;$sharedLastnames : Collection
var $text : Text

$text:=Document to text(Get 4D folder(Current resources folder)+"lastnames.txt")
$lastnames:=JSON Parse($text) //$lastnames is a regular collection

$sharedLastnames:=$lastnames.copy(ck shared) // shared copy

Use(Storage)
Storage.lastnames:=$sharedLastnames
End use

Example 4

This example illustrates the use of the ck resolve pointers option:

 var $col : Collection
var $p : Pointer
$p:=->$what

$col:=New collection
$col.push(New object("alpha";"Hello";"num";1))
$col.push(New object("beta";"You";"what";$p))

$col2:=$col.copy()
$col2[1].beta:="World!"
ALERT($col[0].alpha+" "+$col2[1].beta) //displays "Hello World!"

$what:="You!"
$col3:=$col2.copy(ck resolve pointers)
ALERT($col3[0].alpha+" "+$col3[1].what) //displays "Hello You!"

.count()

History
VersionChanges
v16 R6Added

.count( { propertyPath : Text } ) : Real

ParameterTypeDescription
propertyPathText->Object property path to be used for calculation
ResultReal<-Number of elements in the collection

Description

The .count() function returns the number of non-null elements in the collection.

If the collection contains objects, you can pass the propertyPath parameter. In this case, only elements that contain the propertyPath are taken into account.

Example

 var $col : Collection
var $count1;$count2 : Real
$col:=New collection(20;30;Null;40)
$col.push(New object("name";"Smith";"salary";10000))
$col.push(New object("name";"Wesson";"salary";50000))
$col.push(New object("name";"Gross";"salary";10500))
$col.push(New object("lastName";"Henry";"salary";12000))
$count1:=$col.count() //$count1=7
$count2:=$col.count("name") //$count2=3

.countValues()

History
VersionChanges
v16 R6Added

.countValues( value : any {; propertyPath : Text } ) : Real

ParameterTypeDescription
valueText, Number, Boolean, Date, Object, Collection->Value to count
propertyPathText->Object property path to be used for calculation
ResultReal<-Number of occurrences of the value

Description

The .countValues() function returns the number of times value is found in the collection.

You can pass in value:

  • a scalar value (text, number, boolean, date),
  • an object or a collection reference.

For an element to be found, the type of value must be equivalent to the type of the element; the method uses the equality operator.

The optional propertyPath parameter allows you to count values inside a collection of objects: pass in propertyPath the path of the property whose values you want to count.

This function does not modify the original collection.

Example 1

 var $col : Collection
var $vCount : Integer
$col:=New collection(1;2;5;5;5;3;6;4)
$vCount:=$col.countValues(5) // $vCount=3

Example 2

 var $col : Collection
var $vCount : Integer
$col:=New collection
$col.push(New object("name";"Smith";"age";5))
$col.push(New object("name";"Wesson";"age";2))
$col.push(New object("name";"Jones";"age";3))
$col.push(New object("name";"Henry";"age";4))
$col.push(New object("name";"Gross";"age";5))
$vCount:=$col.countValues(5;"age") //$vCount=2

Example 3

 var $numbers; $letters : Collection
var $vCount : Integer

$letters:=New collection("a";"b";"c")
$numbers:=New collection(1;2;$letters;3;4;5)

$vCount:=$numbers.countValues($letters) //$vCount=1

.distinct()

History
VersionChanges
v20Support of ck count values
v16 R6Added

.distinct( {options : Integer} ) : Collection
.distinct( propertyPath : Text {; options : Integer } ) : Collection

ParameterTypeDescription
propertyPathText->Path of attribute whose distinct values you want to get
optionsInteger->ck diacritical, ck count values
ResultCollection<-New collection with only distinct values

Description

The .distinct() function returns a collection containing only distinct (different) values from the original collection.

This function does not modify the original collection.

The returned collection is automatically sorted. Null values are not returned.

If the collection contains objects, you can pass the propertyPath parameter to indicate the object property whose distinct values you want to get.

In the options parameter, you can pass one or a combination of the following constants:

ConstantValueComment
ck diacritical8Evaluation is case sensitive and differentiates accented characters. By default if omitted, a non-diacritical evaluation is performed
ck count values32Return the count of elements for every distinct value. When this option is passed, .distinct() returns a collection of objects containing a pair of {"value":*value*;"count":*count*} attributes.

Examples

 var $c; $c2; $c3 : Collection
$c:=New collection
$c.push("a";"b";"c";"A";"B";"c";"b";"b")
$c.push(New object("size";1))
$c.push(New object("size";3))
$c.push(New object("size";1))
$c2:=$c.distinct() //$c2=["a","b","c",{"size":1},{"size":3},{"size":1}]
$c2:=$c.distinct(ck diacritical) //$c2=["a","A","b","B","c",{"size":1},{"size":3},{"size":1}]
$c2:=$c.distinct("size") //$c2=[1,3]
$c3:=$c.distinct("size";ck count values) //$c3=[{value:1,count:2},{value:3,count:1}]

.equal()

History
VersionChanges
v16 R6Added

.equal( collection2 : Collection {; option : Integer } ) : Boolean

ParameterTypeDescription
collection2Collection->Collection to compare
optionInteger->ck diacritical: diacritical evaluation ("A" # "a" for example)
ResultBoolean<-True if collections are identical, false otherwise

Description

The .equal() function compares the collection with collection2 and returns true if they are identical (deep comparison).

By default, a non-diacritical evaluation is performed. If you want the evaluation to be case sensitive or to differentiate accented characters, pass the ck diacritical constant in the option parameter.

Elements with Null values are not equal to Undefined elements.

Example

 var $c; $c2 : Collection
var $b : Boolean

$c:=New collection(New object("a";1;"b";"orange");2;3)
$c2:=New collection(New object("a";1;"b";"orange");2;3;4)
$b:=$c.equal($c2) // false

$c:=New collection(New object("1";"a";"b";"orange");2;3)
$c2:=New collection(New object("a";1;"b";"orange");2;3)
$b:=$c.equal($c2) // false

$c:=New collection(New object("a";1;"b";"orange");2;3)
$c2:=New collection(New object("a";1;"b";"ORange");2;3)
$b:=$c.equal($c2) // true

$c:=New collection(New object("a";1;"b";"orange");2;3)
$c2:=New collection(New object("a";1;"b";"ORange");2;3)
$b:=$c.equal($c2;ck diacritical) //false

.every()

History
VersionChanges
v19 R6Support of formula
v16 R6Added

.every( { startFrom : Integer ; } formula : 4D.Function { ;...param : any } ) : Boolean
.every( { startFrom : Integer ; } methodName : Text { ;...param : any } ) : Boolean

ParameterTypeDescription
startFromInteger->Index to start the test at
formula4D.Function->Formula object
methodNameText->Name of a method
paramMixed->Parameter(s) to pass to formula or methodName
ResultBoolean<-True if all elements successfully passed the test

Description

The .every() function returns true if all elements in the collection successfully passed a test implemented in the provided formula object or methodName name.

You designate the callback to be executed to evaluate collection elements using either:

  • formula (recommended syntax), a Formula object that can encapsulate any executable expressions, including functions and project methods;
  • or methodName, the name of a project method (text).

The callback is called with the parameter(s) passed in param (optional). The callback can perform any test, with or without the parameter(s) and must return true for every element fulfilling the test. It receives an Object in first parameter ($1).

The callback receives the following parameters:

  • in $1.value: element value to be evaluated
  • in $2: param
  • in $N...: paramN...

It can set the following parameter(s):

  • (mandatory if you used a method) $1.result (Boolean): true if the element value evaluation is successful, false otherwise.
  • $1.stop (Boolean, optional): true to stop the method callback. The returned value is the last calculated.

In all cases, at the point when the .every() function encounters the first collection element evaluated to false, it stops calling the callback and returns false.

By default, .every() tests the whole collection. Optionally, you can pass in startFrom the index of the element from which to start the test.

  • If startFrom >= the collection's length, false is returned, which means the collection is not tested.
  • If startFrom < 0, it is considered as the offset from the end of the collection ( startFrom:=startFrom+length).
  • If startFrom = 0, the whole collection is searched (default).

Example 1

var $c : Collection  
var $b : Boolean
var $f : 4D.Function

$f:=Formula($1.value>0)
$c:=New collection
$c.push(5;3;1;4;6;2)
$b:=$c.every($f) //returns true
$c.push(-1)
$b:=$c.every($f) //returns false

Example 2

This example tests that all elements of a collection are of the real type:

var $c : Collection
var $b : Boolean
var $f : 4D.Function

$f:=Formula(Value type($1.value)=$2
$c:=New collection
$c.push(5;3;1;4;6;2)
$b:=$c.every($f;Is real) //$b=true
$c:=$c.push(New object("name";"Cleveland";"zc";35049))
$c:=$c.push(New object("name";"Blountsville";"zc";35031))
$b:=$c.every($f;Is real) //$b=false

.extract()

History
VersionChanges
v16 R6Added

.extract( propertyPath : Text { ; option : Integer } ) : Collection
.extract( propertyPath : Text ; targetPath : Text { ;...propertyPathOrTargetPathN : Text } ) : Collection

ParameterTypeDescription
propertyPathText->Object property path whose values must be extracted to the new collection
targetpathText->Target property path or property name
optionInteger->ck keep null: include null properties in the returned collection (ignored by default). Parameter ignored if targetPath passed.
ResultCollection<-New collection containing extracted values

Description

The .extract() function creates and returns a new collection containing propertyPath values extracted from the original collection of objects.

This function does not modify the original collection.

The contents of the returned collection depends on the targetPath parameter:

  • If the targetPath parameter is omitted, .extract() populates the new collection with the propertyPath values of the original collection.

    By default, elements for which propertyPath is null or undefined are ignored in the resulting collection. You can pass the ck keep null constant in the option parameter to include these values as null elements in the returned collection.

  • If one or more targetPath parameter(s) are passed (corresponding to one or more propertyPath parameter(s)), .extract() populates the new collection with the propertyPath properties and each element of the new collection is an object with targetPath properties filled with the matching propertyPath properties. Null values are kept (option parameter is ignored with this syntax).

Example 1

var $c : Collection
$c:=New collection
$c.push(New object("name";"Cleveland"))
$c.push(New object("zip";5321))
$c.push(New object("name";"Blountsville"))
$c.push(42)
$c2:=$c.extract("name") // $c2=[Cleveland,Blountsville]
$c2:=$c.extract("name";ck keep null) //$c2=[Cleveland,null,Blountsville,null]

Example 2

var $c : Collection
$c:=New collection
$c.push(New object("zc";35060))
$c.push(New object("name";Null;"zc";35049))
$c.push(New object("name";"Cleveland";"zc";35049))
$c.push(New object("name";"Blountsville";"zc";35031))
$c.push(New object("name";"Adger";"zc";35006))
$c.push(New object("name";"Clanton";"zc";35046))
$c.push(New object("name";"Clanton";"zc";35045))
$c2:=$c.extract("name";"City") //$c2=[{City:null},{City:Cleveland},{City:Blountsville},{City:Adger},{City:Clanton},{City:Clanton}]
$c2:=$c.extract("name";"City";"zc";"Zip") //$c2=[{Zip:35060},{City:null,Zip:35049},{City:Cleveland,Zip:35049},{City:Blountsville,Zip:35031},{City:Adger,Zip:35006},{City:Clanton,Zip:35046},{City:Clanton,Zip:35045}]

.fill()

History
VersionChanges
v16 R6Added

.fill( value : any ) : Collection
.fill( value : any ; startFrom : Integer { ; end : Integer } ) : Collection

ParameterTypeDescription
valuenumber, Text, Collection, Object, Date, Boolean->Filling value
startFromInteger->Start index (included)
endInteger->End index (not included)
Resultcollection<-Original collection with filled values

Description

The .fill() function fills the collection with the specified value, optionally from startFrom index to end index, and returns the resulting collection.

This function modifies the original collection.

  • If the startFrom parameter is omitted, value is set to all collection elements (startFrom=0).
  • If the startFrom parameter is passed and end omitted, value is set to collection elements starting at startFrom to the last element of the collection (end=length).
  • If both the startFrom parameter and end are passed, value is set to collection elements starting at startFrom to the element end.

In case of inconsistency, the following rules apply:

  • If startFrom < 0, it is recalculated as startFrom:=startFrom+length (it is considered as the offset from the end of the collection). If the calculated value is negative, startFrom is set to 0.
  • If end < 0 , it is recalculated as end:=end+length.
  • If end < startFrom (passed or calculated values), the method does nothing.

Example

 var $c : Collection
$c:=New collection(1;2;3;"Lemon";Null;"";4;5)
$c.fill("2") // $c:=[2,2,2,2,2,2,2,2]
$c.fill("Hello";5) // $c=[2,2,2,2,2,Hello,Hello,Hello]
$c.fill(0;1;5) // $c=[2,0,0,0,0,Hello,Hello,Hello]
$c.fill("world";1;-5) //-5+8=3 -> $c=[2,"world","world",0,0,Hello,Hello,Hello]

.filter()

History
VersionChanges
v19 R6Support of formula
v16 R6Added

.filter( formula : 4D.Function { ; ...param : any } ) : Collection
.filter( methodName : Text { ; ...param : any } ) : Collection

ParameterTypeDescription
formula4D.Function->Formula object
methodNameText->Name of a method
paramany->Parameter(s) to pass to formula or methodName
ResultCollection<-New collection containing filtered elements (shallow copy)

Description

The .filter() function returns a new collection containing all elements of the original collection for which the formula or methodName result is true. This function returns a shallow copy, which means that objects or collections in both collections share the same reference. If the original collection is a shared collection, the returned collection is also a shared collection.

This function does not modify the original collection.

You designate the callback to be executed to filter collection elements using either:

  • formula (recommended syntax), a Formula object that can encapsulate any executable expressions, including functions and project methods;
  • or methodName, the name of a project method (text).

The callback is called with the parameter(s) passed in param (optional) and an object in first parameter ($1). The callback can perform any test, with or without the parameter(s) and must return true for each element fulfilling the condition and thus, to push to the new collection.

The callback receives the following parameters:

  • in $1.value: element value to be evaluated
  • in $2: param
  • in $N...: paramN...

It can set the following parameter(s):

  • $1.result (Boolean): true if the element value matches the filter condition and must be kept, false otherwise.
  • $1.stop (Boolean, optional): true to stop the method callback. The returned value is the last calculated.
note

When using methodName as callback, and if the method does not return any value, .filter() will look at the property $1.result that you must set to true for each element fulfilling the condition.

Example 1

You want to get the collection of text elements whose length is smaller than 6:

var $col;$colNew : Collection
$col:=New collection("hello";"world";"red horse";66;"tim";"san jose";"miami")
$colNew:=$col.filter(Formula((Value type($1.value)=Is text) && (Length($1.value)<$2)); 6)
//$colNew=["hello","world","tim","miami"]

Example 2

You want to filter elements according to their value type:

 var $c;$c2;$c3 : Collection
var $f : 4D.Function

$f:=Formula(OB Get type($1;"value")=$2)
$c:=New collection(5;3;1;4;6;2)
$c.push(New object("name";"Cleveland";"zc";35049))
$c.push(New object("name";"Blountsville";"zc";35031))
$c2:=$c.filter($f;Is real) // $c2=[5,3,1,4,6,2]
$c3:=$c.filter($f;Is object)
// $c3=[{name:Cleveland,zc:35049},{name:Blountsville,zc:35031}]

.find()

History
VersionChanges
v19 R6Support of formula
v16 R6Added

.find( { startFrom : Integer ; } formula : 4D.Function { ; ...param : any } ) : any
.find( { startFrom : Integer ; } methodName : Text { ; ...param : any } ) : any

ParameterTypeDescription
startFromInteger->Index to start the search at
formula4D.Function->Formula object
methodNameText->Name of a method
paramany->Parameter(s) to pass to formula or methodName
Resultany<-First value found, or Undefined if not found

Description

The .find() function returns the first value in the collection for which formula or methodName result, applied on each element, returns true.

This function does not modify the original collection.

You designate the callback to be executed to evaluate collection elements using either:

  • formula (recommended syntax), a Formula object that can encapsulate any executable expressions, including functions and project methods;
  • or methodName, the name of a project method (text).

The callback is called with the parameter(s) passed in param (optional). The callback can perform any test, with or without the parameter(s) and must return true for the first element fulfilling the condition. It receives an Object in first parameter ($1).

The callback receives the following parameters:

  • in $1.value: element value to be evaluated
  • in $2: param
  • in $N...: paramN...

It can set the following parameter(s):

  • (mandatory if you used a method) $1.result (Boolean): true if the element value matches the search condition, false otherwise.
  • $1.stop (Boolean, optional): true to stop the method callback. The returned value is the last calculated.

By default, .find() searches in the whole collection. Optionally, you can pass in startFrom the index of element from which to start the search.

  • If startFrom >= the collection's length, -1 is returned, which means the collection is not searched.
  • If startFrom < 0, it is considered as the offset from the end of the collection (startFrom:=startFrom+length). Note: Even if startFrom is negative, the collection is still searched from left to right.
  • If startFrom = 0, the whole collection is searched (default).

Example 1

You want to get the first text element with a length smaller than 5:

var $col : Collection
$col:=New collection("hello";"world";4;"red horse";"tim";"san jose")
$value:=$col.find(Formula((Value type($1.value)=Is text) && (Length($1.value)<$2)); 5) //$value="tim"

Example 2

You want to find a city name within a collection:

var $c : Collection
var $c2 : Object
$c:=New collection
$c.push(New object("name"; "Cleveland"; "zc"; 35049))
$c.push(New object("name"; "Blountsville"; "zc"; 35031))
$c.push(New object("name"; "Adger"; "zc"; 35006))
$c.push(New object("name"; "Clanton"; "zc"; 35046))
$c.push(New object("name"; "Clanton"; "zc"; 35045))

$c2:=$c.find(Formula($1.value.name=$2); "Clanton") //$c2={name:Clanton,zc:35046}

.findIndex()

History
VersionChanges
v19 R6Support of formula
v16 R6Added

.findIndex( { startFrom : Integer ; } formula : 4D.Function { ; ...param : any } ) : Integer
.findIndex( { startFrom : Integer ; } methodName : Text { ; ...param : any } ) : Integer

ParameterTypeDescription
startFromInteger->Index to start the search at
formula4D.Function->Formula object
methodNameText->Name of a method
paramany->Parameter(s) to pass to formula or methodName
ResultInteger<-Index of first value found, or -1 if not found

Description

The .findIndex() function returns the index, in the collection, of the first value for which formula or methodName, applied on each element, returns true.

This function does not modify the original collection.

You designate the callback to be executed to evaluate collection elements using either:

  • formula (recommended syntax), a Formula object that can encapsulate any executable expressions, including functions and project methods;
  • methodName, the name of a project method (text).

The callback is called with the parameter(s) passed in param (optional). The callback can perform any test, with or without the parameter(s) and must return true for the first element fulfilling the condition. It receives an Object in first parameter ($1).

The callback receives the following parameters:

  • in $1.value: element value to be evaluated
  • in $2: param
  • in $N...: paramN...

It can set the following parameter(s):

  • (mandatory if you used a method) $1.result (Boolean): true if the element value matches the search condition, false otherwise.
  • $1.stop (Boolean, optional): true to stop the method callback. The returned value is the last calculated.

By default, .findIndex() searches in the whole collection. Optionally, you can pass in startFrom the index of element from which to start the search.

  • If startFrom >= the collection's length, -1 is returned, which means the collection is not searched.
  • If startFrom < 0, it is considered as the offset from the end of the collection (startFrom:=startFrom+length). Note: Even if startFrom is negative, the collection is still searched from left to right.
  • If startFrom = 0, the whole collection is searched (default).

Example

You want to find the position of the first city name within a collection:

var $c : Collection
var $val2;$val3 : Integer
$c:=New collection
$c.push(New object("name";"Cleveland";"zc";35049))
$c.push(New object("name";"Blountsville";"zc";35031))
$c.push(New object("name";"Adger";"zc";35006))
$c.push(New object("name";"Clanton";"zc";35046))
$c.push(New object("name";"Clanton";"zc";35045))
$val2:=$c.findIndex(Formula($1.value.name=$2);"Clanton") // $val2=3
$val3:=$c.findIndex($val2+1;Formula($1.value.name=$2);"Clanton") //$val3=4

.first()

History
VersionChanges
v20Added

.first() : any

ParameterTypeDescription
Resultany<-First element of collection

Description

The .first() function returns the first element of the collection.

This function does not modify the original collection.

The function returns Undefined if the collection is empty.

Example

var $col; $emptyCol : Collection
var $first : Variant
$col:=New collection(10; 20; 30; "hello"; 50)
$first:=$col.first() // 10

$emptyCol:=New collection() //empty
// $first:=$emptyCol[0] //would return error
$first:=$emptyCol.first() // returns Undefined

.flat()

History
VersionChanges
v20Added

.flat( { depth : Integer } ) : Collection

ParameterTypeDescription
depthInteger->How deep a nested collection structure should be flattened. Default=1
ResultCollection<-Flattened collection

Description

The .flat() function creates a new collection with all sub-collection elements concatenated into it recursively up to the specified depth.

By default, if the depth parameter is omitted, only the first level of the nested collection structure will be flattened.

This function does not modify the original collection.

Example

$col:=New collection(1; 2; New collection(3; 4))
$col.flat()
// [1, 2, 3, 4]

$col:=New collection(1; 2; New collection(3; 4; New collection(5; 6)))
$col.flat()
// [1, 2, 3, 4, [5, 6]]

$col:=New collection(1; 2; New collection(3; 4; New collection(5; 6)))
$col.flat(2)
// [1, 2, 3, 4, 5, 6]

$col:=New collection(1; 2; New collection(3; 4; 5; 6; New collection(7; 8; New collection(9; 10))))
$col.flat(MAXLONG)
// [1, 2, 3, 4, 5, 6, 7, 8, 9, 10]

.flatMap()

History
VersionChanges
v20Added

.flatMap( formula : 4D.Function { ; ...param : any } ) : Collection
.flatMap( methodName : Text { ; ...param : any } ) : Collection

ParameterTypeDescription
formula4D.Function->Formula object
methodNameText->Name of a method
paramany->Parameter(s) to pass to formula or methodName
ResultCollection<-Collection of transformed values and flattened by a depth of 1

Description

The .flatMap() function creates a new collection based upon the result of the call of the formula 4D function or methodName method on each element of the original collection and flattened by a depth of 1. Optionally, you can pass parameters to formula or methodName using the param parameter(s).

This function is identical to a map() call followed by a flat() call of depth 1.

This function does not modify the original collection.

You designate the callback to be executed to evaluate collection elements using either:

  • formula (recommended syntax), a Formula object that can encapsulate any executable expressions, including functions and project methods;
  • or methodName, the name of a project method (text).

The callback is called with the parameter(s) passed in param (optional). The callback can perform any operation, with or without the parameter(s) and must return new transformed value to add to the resulting collection. It receives an Object in first parameter ($1).

The callback receives the following parameters:

  • in $1.value: element value to be evaluated
  • in $2: param
  • in $N...: paramN...

It can set the following parameter(s):

  • (mandatory if you used a method) $1.result (any type): new transformed value to add to the resulting collection
  • $1.stop (Boolean, optional): true to stop the method callback. The returned value is the last calculated.

Example 1

var $col ; $result : Collection
$col:=New collection(1; 2; 3; 4)

$result:=$col.map(Formula(New collection($1.value*2))
// [[2],[4],[6],[8]]

$result:=$col.flatMap(Formula(New collection($1.value*2))
// [2,4,6,8]

Example 2

var $col; $result : Collection
$col:=New collection("Hello how"; ""; "are you ?")

$result:=$col.map(Formula(Split string($1.value; " ")))
// [["Hello", "how"], [], ["are", "you", "?"]]

$result:=$col.flatMap(Formula(Split string($1.value; " ")))
// ["Hello", "how", "are", "you", "?"]

Example 3

You want to compute the percentage of each value in the collection to the total:

var $c; $c2 : Collection
var $f : 4D.Function
$c:=New collection(1; 4; 9; 10; 20)
$f:=Formula(New collection($1.value;Round(($1.value/$2)*100; 2)))
$c2:=$c.flatMap($f; $c.sum())
//$c2=[1, 2.27, 4, 9.09,9, 20.45,10, 22.73, 20, 45.45]

.includes()

History
VersionChanges
v20Added

.includes( toSearch : expression { ; startFrom : Integer } ) : Boolean

ParameterTypeDescription
toSearchexpression->Expression to search in the collection
startFromInteger->Index to start the search at
ResultBoolean<-True if toSearch is found in the collection

Description

The .includes() function returns True if the toSearch expression is found among collection elements, otherwise False.

This function does not modify the original collection.

In toSearch, pass the expression to find in the collection. You can pass:

  • a scalar value (text, number, boolean, date),
  • the null value,
  • an object or a collection reference.

toSearch must match exactly the element to find (the same rules as for the equality operator of the data type are applied).

Optionally, you can pass the index of collection from which to start the search in startFrom.

  • If startFrom >= collection's length, False is returned, which means the collection is not searched.
  • If startFrom < 0, it is considered as the offset from the end of the collection (startFrom:=startFrom+length). Note that even if startFrom is negative, the collection is still searched from left to right.
  • If startFrom = 0, the whole collection is searched (default).

Example

 var $col : Collection
var $in : Boolean
var $obj : Object
$obj:=New object("value"; 10)
$col:=New collection(1;2;"Henry";5;3;"Albert";6;4;"Alan";5;$obj)
$in:=$col.includes(3) //True
$in:=$col.includes(5;6) //True
$in:=$col.includes("al@") //True
$in:=$col.includes("Hello") //False
$in:=$col.includes($obj) //True
$in:=$col.includes(New object("value"; 10)) //False

.indexOf()

History
VersionChanges
v16 R6Added

.indexOf( toSearch : expression { ; startFrom : Integer } ) : Integer

ParameterTypeDescription
toSearchexpression->Expression to search in the collection
startFromInteger->Index to start the search at
ResultInteger<-Index of the first occurrence of toSearch in the collection, -1 if not found

Description

The .indexOf() function searches the toSearch expression among collection elements and returns the index of the first found occurrence, or -1 if it was not found.

This function does not modify the original collection.

In toSearch, pass the expression to find in the collection. You can pass:

  • a scalar value (text, number, boolean, date),
  • the null value,
  • an object or a collection reference.

toSearch must match exactly the element to find (the same rules as for the equality operator of the data type are applied).

Optionally, you can pass the index of collection from which to start the search in startFrom.

  • If startFrom >= the collection's length, -1 is returned, which means the collection is not searched.
  • If startFrom < 0, it is considered as the offset from the end of the collection (startFrom:=startFrom+length). Note: Even if startFrom is negative, the collection is still searched from left to right.
  • If startFrom = 0, the whole collection is searched (default).

Example

 var $col : Collection
var $i : Integer
$col:=New collection(1;2;"Henry";5;3;"Albert";6;4;"Alan";5)
$i:=$col.indexOf(3) //$i=4
$i:=$col.indexOf(5;5) //$i=9
$i:=$col.indexOf("al@") //$i=5
$i:=$col.indexOf("Hello") //$i=-1

.indices()

History
VersionChanges
v16 R6Added

.indices( queryString : Text { ; ...value : any } ) : Collection

ParameterTypeDescription
queryStringText->Search criteria
valueany->Value(s) to compare when using placeholder(s)
ResultCollection<-Element index(es) matching queryString in the collection

Description

The .indices() function works exactly the same as the .query() function but returns indexes, in the original collection, of object collection elements that match the queryString search conditions, and not elements themselves. Indexes are returned in ascending order.

This function does not modify the original collection.

The queryString parameter uses the following syntax:

propertyPath comparator value {logicalOperator propertyPath comparator value}

For a detailed description of the queryString and value parameters, please refer to the dataClass.query() function.

Example

 var $c; $icol : Collection
$c:=New collection
$c.push(New object("name";"Cleveland";"zc";35049))
$c.push(New object("name";"Blountsville";"zc";35031))

$c.push(New object("name";"Adger";"zc";35006))
$c.push(New object("name";"Clanton";"zc";35046))
$c.push(New object("name";"Clanton";"zc";35045))
$icol:=$c.indices("name = :1";"Cleveland") // $icol=[0]
$icol:=$c.indices("zc > 35040") // $icol=[0,3,4]

.insert()

History
VersionChanges
v16 R6Added

.insert( index : Integer ; element : any ) : Collection

ParameterTypeDescription
indexInteger->Where to insert the element
elementany->Element to insert in the collection
ResultCollection<-Original collection containing inserted element

Description

The .insert() function inserts element at the specified index position in the collection instance and returns the edited collection.

This function modifies the original collection.

In index, pass the position where you want the element to be inserted in the collection.

Warning: Keep in mind that collection elements are numbered from 0.

  • If index > the length of the collection, actual starting index will be set to the length of the collection.
  • If index <0, it is recalculated as index:=index+length (it is considered as the offset from the end of the collection).
  • If the calculated value is negative, index is set to 0.

Any type of element accepted by a collection can be inserted, even another collection.

Example

 var $col : Collection
$col:=New collection("a";"b";"c";"d") //$col=["a","b","c","d"]
$col.insert(2;"X") //$col=["a","b","X","c","d"]
$col.insert(-2;"Y") //$col=["a","b","X","Y","c","d"]
$col.insert(-10;"Hi") //$col=["Hi","a","b","X","Y","c","d"]

.join()

History
VersionChanges
v16 R6Added

.join( delimiter : Text { ; option : Integer } ) : Text

ParameterTypeDescription
delimiterText->Separator to use between elements
optionInteger->ck ignore null or empty: ignore null and empty strings in the result
ResultText<-String containing all elements of the collection, separated by delimiter

Description

The .join() function converts all elements of the collection to strings and concatenates them using the specified delimiter string as separator.The function returns the resulting string.

This function does not modify the original collection.

By default, null or empty elements of the collection are returned in the resulting string. Pass the ck ignore null or empty constant in the option parameter if you want to remove them from the resulting string.

Example

 var $c : Collection
var $t1;$t2 : Text
$c:=New collection(1;2;3;"Paris";Null;"";4;5)
$t1:=$c.join("|") //1|2|3|Paris|null||4|5
$t2:=$c.join("|";ck ignore null or empty) //1|2|3|Paris|4|5

.last()

History
VersionChanges
v20Added

.last() : any

ParameterTypeDescription
Resultany<-Last element of collection

Description

The .last() function returns the last element of the collection.

This function does not modify the original collection.

The function returns Undefined if the collection is empty.

Example

var $col; $emptyCol : Collection
var $last : Variant
$col:=New collection(10; 20; 30; "hello"; 50)
$last:=$col.last() // 50

$emptyCol:=New collection() //empty
// $last:=$emptyCol[$emptyCol.length-1] //returns an error
$last:=$emptyCol.last() // returns Undefined

.lastIndexOf()

History
VersionChanges
v16 R6Added

.lastIndexOf( toSearch : expression { ; startFrom : Integer } ) : Integer

ParameterTypeDescription
toSearchexpression->The element that is to be searched for within the collection
startFromInteger->Index to start the search at
ResultInteger<-Index of last occurrence of toSearch in the collection, -1 if not found

Description

The .lastIndexOf() function searches the toSearch expression among collection elements and returns the index of the last occurrence, or -1 if it was not found.

This function does not modify the original collection.

In toSearch, pass the expression to find in the collection. You can pass:

  • a scalar value (text, number, boolean, date),
  • the null value,
  • an object or a collection reference.

toSearch must match exactly the element to find (the same rules as for the equality operator are applied).

Optionally, you can pass the index of collection from which to start a reverse search in startFrom.

  • If startFrom >= the collection's length minus one (coll.length-1), the whole collection is searched (default).
  • If startFrom < 0, it is recalculated as startFrom:=startFrom+length (it is considered as the offset from the end of the collection). If the calculated value is negative, -1 is returned (the collection is not searched). Note: Even if startFrom is negative, the collection is still searched from right to left.
  • If startFrom = 0, -1 is returned, which means the collection is not searched.

Example

 var $col : Collection
var $pos1;$pos2;$pos3;$pos4;$pos5 : Integer
$col:=Split string("a,b,c,d,e,f,g,h,i,j,e,k,e";",") //$col.length=13
$pos1:=$col.lastIndexOf("e") //returns 12
$pos2:=$col.lastIndexOf("e";6) //returns 4
$pos3:=$col.lastIndexOf("e";15) //returns 12
$pos4:=$col.lastIndexOf("e";-2) //returns 10
$pos5:=$col.lastIndexOf("x") //returns -1

.length

History
VersionChanges
v16 R5Added

.length : Integer

Description

The .length property returns the number of elements in the collection.

The .length property is initialized when the collection is created. Adding or removing elements updates the length, if necessary. This property is read-only (you cannot use it to set the size of the collection).

Example

 var $col : Collection //$col.length initialized to 0
$col:=New collection("one";"two";"three") //$col.length updated to 3
$col[4]:="five" //$col.length updated to 5
$vSize:=$col.remove(0;3).length //$vSize=2

.map()

History
VersionChanges
v19 R6Support of formula
v16 R6Added

.map( formula : 4D.Function { ; ...param : any } ) : Collection
.map( methodName : Text { ; ...param : any } ) : Collection

ParameterTypeDescription
formula4D.Function->Formula object
methodNameText->Name of a method
paramany->Parameter(s) to pass to formula or methodName
ResultCollection<-Collection of transformed values

Description

The .map() function creates a new collection based upon the result of the call of the formula 4D function or methodName method on each element of the original collection. Optionally, you can pass parameters to formula or methodName using the param parameter(s). .map() always returns a collection with the same size as the original collection, except if $1.stop was used (see below).

This function does not modify the original collection.

You designate the callback to be executed to evaluate collection elements using either:

  • formula (recommended syntax), a Formula object that can encapsulate any executable expressions, including functions and project methods;
  • or methodName, the name of a project method (text).

The callback is called with the parameter(s) passed in param (optional). The callback can perform any operation, with or without the parameter(s) and must return new transformed value to add to the resulting collection. It receives an Object in first parameter ($1).

The callback receives the following parameters:

  • in $1.value: element value to be evaluated
  • in $2: param
  • in $N...: paramN...

It can set the following parameter(s):

  • (mandatory if you used a method) $1.result (any type): new transformed value to add to the resulting collection
  • $1.stop (Boolean, optional): true to stop the method callback. The returned value is the last calculated.

Example

var $c; $c2 : Collection
$c:=New collection(1; 4; 9; 10; 20)
$c2:=$c.map(Formula(Round(($1.value/$2)*100; 2)); $c.sum())
//$c2=[2.27,9.09,20.45,22.73,45.45]

.max()

History
VersionChanges
v16 R6Added

.max( { propertyPath : Text } ) : any

ParameterTypeDescription
propertyPathText->Object property path to be used for evaluation
ResultBoolean, Text, Number, Collection, Object, Date<-Maximum value in the collection

Description

The .max() function returns the element with the highest value in the collection (the last element of the collection as it would be sorted in ascending order using the .sort() function).

This function does not modify the original collection.

If the collection contains different types of values, the .max() function will return the maximum value within the last element type in the type list order (see .sort() description).

If the collection contains objects, pass the propertyPath parameter to indicate the object property whose maximum value you want to get.

If the collection is empty, .max() returns Undefined.

Example

 var $col : Collection
$col:=New collection(200;150;55)
$col.push(New object("name";"Smith";"salary";10000))
$col.push(New object("name";"Wesson";"salary";50000))
$col.push(New object("name";"Alabama";"salary";10500))
$max:=$col.max() //{name:Alabama,salary:10500}
$maxSal:=$col.max("salary") //50000
$maxName:=$col.max("name") //"Wesson"

.min()

History
VersionChanges
v16 R6Added

.min( { propertyPath : Text } ) : any

ParameterTypeDescription
propertyPathText->Object property path to be used for evaluation
ResultBoolean, Text, Number, Collection, Object, Date<-Minimum value in the collection

Description

The .min() function returns the element with the smallest value in the collection (the first element of the collection as it would be sorted in ascending order using the .sort() function).

This function does not modify the original collection.

If the collection contains different types of values, the .min() function will return the minimum value within the first element type in the type list order (see .sort() description).

If the collection contains objects, pass the propertyPath parameter to indicate the object property whose minimum value you want to get.

If the collection is empty, .min() returns Undefined.

Example

 var $col : Collection
$col:=New collection(200;150;55)
$col.push(New object("name";"Smith";"salary";10000))
$col.push(New object("name";"Wesson";"salary";50000))
$col.push(New object("name";"Alabama";"salary";10500))
$min:=$col.min() //55
$minSal:=$col.min("salary") //10000
$minName:=$col.min("name") //"Alabama"

.multiSort()

History
VersionChanges
v20 R3Added

.multiSort() : Collection
.multiSort( colsToSort : Collection ) : Collection
.multiSort( formula : 4D.Function ; colsToSort : Collection ) : Collection

ParameterTypeDescription
formula4D.Function->Formula object
colsToSortCollection->Collection of collections and/or objects with {collection:colToSort;order:ck ascending or ck descending} properties
ResultCollection<-Original collection sorted

Description

The .multiSort() function enables you to carry out a multi-level synchronized sort on a set of collections.

This function modifies the original collection as well as all collections used in colsToSort parameter.

If .multiSort() is called with no parameters, the function has the same effect as the .sort() function: the collection is sorted (only scalar values) in ascending order by default, according to their type. If the collection contains values of different types, they are first grouped by type and sorted afterwards. Types are returned in the following order:

  1. null
  2. booleans
  3. strings
  4. numbers
  5. objects
  6. collections
  7. dates

Single-level synchronized sort

To sort several collections synchronously, just pass in colsToSort a collection of collections to sort. You can pass an unlimited number of collections. The original collection will be sorted in ascending order and all colsToSort collections will be sorted in a synchronized manner.

note

All colsToSort collections must have the same number of elements, otherwise an error is returned.

If you want to sort the collections in some other order than ascending, you must supply a formula (Formula object that defines the sort order. The return value should be a boolean that indicates the relative order of the two elements: True if $1.value is less than $1.value2, False if $1.value is greater than $1.value2. You can provide additional parameters to the formula if necessary.

The formula receives the following parameters:

  • $1 (object), where:
    • $1.value (any type): first element value to be compared
    • $1.value2 (any type): second element value to be compared
  • $2...$N (any type): extra parameters

Multi-level synchronized sort

Defining a multi-level synchronized sort requires that you pass an object containing {collection:colToSort;order:ck ascending or ck descending} properties instead of the colToSort itself for every collection to use as sub-level.

The sort levels are determined by the order in which the collections are passed in the colsToSort parameter: the position of a collection/order object in the syntax determines its sort level.

note

The .multiSort() function uses a stable sort algorithm.

Example 1

A simple synchronized sort of collections with different value types:

var $col;$col2;$col3 : Collection
$col:=["A"; "C"; "B"]
$col2:=[1; 2; 3]
$col3:=[["Jim"; "Philip"; "Maria"]; ["blue"; "green"]; ["11"; 22; "33"]]

$col.multiSort([$col2; $col3])
//$col=["A","B","C"]
//$col2=[1,3,2]
//$col3[0]=["Jim","Philip","Maria"]
//$col3[1]=["11",22,"33"]
//$col3[2]=["blue","green"]

Example 2

You want to sort three synchronized collections: city, country, and continent. You want an ascending sort of the first and the third collections, and synchronization for the second collection:

var $city : Collection
var $country : Collection
var $continent : Collection

$city:=["Paris"; "Lyon"; "Rabat"; "Eching"; "San Diego"]
$country:=["France"; "France"; "Morocco"; "Germany"; "US"]
$continent:=["Europe"; "Europe"; "Africa"; "Europe"; "America"]

$continent.multiSort([$country; {collection: $city; order: ck ascending}])
//$continent=["Africa","America","Europe","Europe","Europe"]
//$country=["Morocco","US","France","France","Germany"]
//$city=["Rabat","San Diego","Lyon","Paris","Eching"]

Example 3

You can also synchronize collections of objects.

var $name : Collection
var $address : Collection
$name:=[]
$name.push({firstname: "John"; lastname: "Smith"})
$name.push({firstname: "Alain"; lastname: "Martin"})
$name.push({firstname: "Jane"; lastname: "Doe"})
$name.push({firstname: "John"; lastname: "Doe"})
$address:=[]
$address.push({city: "Paris"; country: "France"})
$address.push({city: "Lyon"; country: "France"})
$address.push({city: "Eching"; country: "Germany"})
$address.push({city: "Berlin"; country: "Germany"})

$name.multiSort(Formula($1.value.firstname<$1.value2.firstname); [$address])
//"Alain Martin","Jane Doe","John Smith","John Doe"
//"Lyon France","Eching Germany","Paris France","Berlin Germany"

.orderBy()

History
VersionChanges
v16 R6Added

.orderBy( ) : Collection
.orderBy( pathStrings : Text ) : Collection
.orderBy( pathObjects : Collection ) : Collection
.orderBy( ascOrDesc : Integer ) : Collection

ParameterTypeDescription
pathStringsText->Property path(s) on which to order the collection
pathObjectsCollection->Collection of criteria objects
ascOrDescInteger->ck ascending or ck descending (scalar values)
ResultCollection<-Ordered copy of the collection (shallow copy)

Description

The .orderBy() function returns a new collection containing all elements of the collection in the specified order.

This function returns a shallow copy, which means that objects or collections in both collections share the same reference. If the original collection is a shared collection, the returned collection is also a shared collection.

This function does not modify the original collection.

If you pass no parameter, the function orders scalar values in the collection in ascending order (other element types such as objects or collections are returned with an internal order). You can modify this automatic order by passing the ck ascending or ck descending constants in the ascOrDesc parameter (see below).

You can also pass a criteria parameter to define how the collection elements must be sorted. Three syntaxes are supported for this parameter:

  • pathStrings : Text (formula). Syntax: propertyPath1 {desc or asc}, propertyPath2 {desc or asc},... (default order: asc). pathStrings contains a formula made of 1 to x property paths and (optionally) sort orders, separated by commas. The order in which the properties are passed determines the sorting priority of the collection elements. By default, properties are sorted in ascending order. You can set the sort order of a property in the criteria string, separated from the property path by a single space: pass "asc" to sort in ascending order or "desc" in descending order.

  • pathObjects : Collection. You can add as many objects in the pathObjects collection as necessary. By default, properties are sorted in ascending order ("descending" is false). Each element of the collection contains an object structured in the following way:

{
"propertyPath": string,
"descending": boolean

}
  • ascOrDesc : Integer. You pass one of the following constants from the Objects and collections theme:

    ConstantTypeValueComment
    ck ascendingLongint0Elements are ordered in ascending order (default)
    ck descendingLongint1Elements are ordered in descending order

    This syntax orders scalar values in the collection only (other element types such as objects or collections are returned unordered).

If the collection contains elements of different types, they are first grouped by type and sorted afterwards. Types are returned in the following order:

  1. null
  2. booleans
  3. strings
  4. numbers
  5. objects
  6. collections
  7. dates

Example 1

Ordering a collection of numbers in ascending and descending order:

 var $c; $c2; $c3 : Collection
$c:=New collection
For($vCounter;1;10)
$c.push(Random)
End for
$c2:=$c.orderBy(ck ascending)
$c3:=$c.orderBy(ck descending)

Example 2

Ordering a collection of objects based on a text formula with property names:

 var $c; $c2 : Collection
$c:=New collection
For($vCounter;1;10)
$c.push(New object("id";$vCounter;"value";Random))
End for
$c2:=$c.orderBy("value desc")
$c2:=$c.orderBy("value desc, id")
$c2:=$c.orderBy("value desc, id asc")

Ordering a collection of objects with a property path:

 var $c; $c2 : Collection
$c:=New collection
$c.push(New object("name";"Cleveland";"phones";New object("p1";"01";"p2";"02")))
$c.push(New object("name";"Blountsville";"phones";New object("p1";"00";"p2";"03")))

$c2:=$c.orderBy("phones.p1 asc")

Example 3

Ordering a collection of objects using a collection of criteria objects:

 var $crit; $c; $c2 : COllection
$crit:=New collection
$c:=New collection
For($vCounter;1;10)
$c.push(New object("id";$vCounter;"value";Random))
End for
$crit.push(New object("propertyPath";"value";"descending";True))
$crit.push(New object("propertyPath";"id";"descending";False))
$c2:=$c.orderBy($crit)

Ordering with a property path:


var $crit; $c; $c2 : Collection
$c:=New collection
$c.push(New object("name";"Cleveland";"phones";New object("p1";"01";"p2";"02")))
$c.push(New object("name";"Blountsville";"phones";New object("p1";"00";"p2";"03")))
$crit:=New collection(New object("propertyPath";"phones.p2";"descending";True))
$c2:=$c.orderBy($crit)

.orderByMethod()

History
VersionChanges
v19 R6Support of formula
v16 R6Added

.orderByMethod( formula : 4D.Function { ; ...extraParam : expression } ) : Collection
.orderByMethod( methodName : Text { ; ...extraParam : expression } ) : Collection

ParameterTypeDescription
formula4D.Function->Formula object
methodNameText->Name of a method
extraParamany->Parameter(s) to pass
ResultCollection<-Sorted copy of the collection (shallow copy)

Description

The .orderByMethod() function returns a new collection containing all elements of the collection in the order defined through the formula 4D function or methodName method.

This function returns a shallow copy, which means that objects or collections in both collections share the same reference. If the original collection is a shared collection, the returned collection is also a shared collection.

This function does not modify the original collection.

You designate the callback to be executed to evaluate collection elements using either:

  • formula (recommended syntax), a Formula object that can encapsulate any executable expressions, including functions and project methods;

  • or methodName, the name of a project method (text).

In the callback, pass some code that compares two values and returns true if the first value is lower than the second value. You can provide extraParam parameters to the callback if necessary.

The callback receives the following parameters:

  • $1 (object), where:
    • $1.value (any type): first element value to be compared
    • $1.value2 (any type): second element value to be compared
    • $2...$N (any type): extra parameters

If you used a method, it must set the following parameter:

  • $1.result (boolean): true if $1.value < $1.value2, false otherwise

Example 1

You want to sort a collection of strings in numerical order rather than alphabetical order:

 var $c; $c2; $c3 : Collection
$c:=New collection
$c.push("33";"4";"1111";"222")
$c2:=$c.orderBy() //$c2=["1111","222","33","4"], alphabetical order
$c3:=$c.orderByMethod(Formula(Num($1.value)<Num($1.value2))) // $c3=["4","33","222","1111"]

Example 2

You want to sort a collection of strings on their length:

 var $fruits; $c2 : Collection
$fruits:=New collection("Orange";"Apple";"Grape";"pear";"Banana";"fig";"Blackberry";"Passion fruit")
$c2:=$fruits.orderByMethod(Formula(Length(String($1.value))>Length(String($1.value2))))
//$c2=[Passion fruit,Blackberry,Orange,Banana,Apple,Grape,pear,fig]

Example 3

You want to sort a collection by character code or language:

var $strings1; $strings2 : Collection
$strings1:=New collection("Alpha";"Charlie";"alpha";"bravo";"Bravo";"charlie")

//using the character code:
$strings2:=$strings1.orderByMethod(Function(sortCollection);sk character codes)
// result : ["Alpha","Bravo","Charlie","alpha","bravo","charlie"]

//using the language:
$strings2:=$strings1.orderByMethod(Function(sortCollection);sk strict)
// result : ["alpha","Alpha","bravo","Bravo","charlie","Charlie"]

The sortCollection method:

var $1 : Object
var $2: Integer // sort option

$1.result:=(Compare strings($1.value;$1.value2;$2)<0)

.pop()

History
VersionChanges
v16 R6Added

.pop() : any

ParameterTypeDescription
Resultany<-Last element of collection

Description

The .pop() function removes the last element from the collection and returns it as the function result.

This function modifies the original collection.

When applied to an empty collection, .pop() returns undefined.

Example

.pop(), used in conjunction with .push(), can be used to implement a first-in, last-out stack feature:

 var $stack : Collection
$stack:=New collection //$stack=[]
$stack.push(1;2) //$stack=[1,2]
$stack.pop() //$stack=[1] Returns 2
$stack.push(New collection(4;5)) //$stack=[[1,[4,5]]
$stack.pop() //$stack=[1] Returns [4,5]
$stack.pop() //$stack=[] Returns 1

.push()

History
VersionChanges
v16 R6Added

.push( element : any { ;...elementN } ) : Collection

ParameterTypeDescription
elementMixed->Element(s) to add to the collection
ResultCollection<-Original collection containing added elements

Description

The .push() function appends one or more element(s) to the end of the collection instance and returns the edited collection.

This function modifies the original collection.

Example 1

 var $col : Collection
$col:=New collection(1;2) //$col=[1,2]
$col.push(3) //$col=[1,2,3]
$col.push(6;New object("firstname";"John";"lastname";"Smith"))
//$col=[1,2,3,6,{firstname:John,lastname:Smith}

Example 2

You want to sort the resulting collection:

 var $col; $sortedCol : Collection
$col:=New collection(5;3;9) //$col=[5,3,9]
$sortedCol:=$col.push(7;50).sort()
//$col=[5,3,9,7,50]
//$sortedCol=[3,5,7,9,50]

.query()

History
VersionChanges
v17 R5Support of querySettings
v16 R6Added

.query( queryString : Text ; ...value : any ) : Collection
.query( queryString : Text ; querySettings : Object ) : Collection

ParameterTypeDescription
queryStringText->Search criteria
valueMixed->Value(s) to compare when using placeholder(s)
querySettingsObject->Query options: parameters, attributes
ResultCollection<-Element(s) matching queryString in the collection

Description

The .query() function returns all elements of a collection of objects that match the search conditions defined by queryString and (optionally) value or querySettings. If the original collection is a shared collection, the returned collection is also a shared collection.

This function does not modify the original collection.

The queryString parameter uses the following syntax:

propertyPath comparator value {logicalOperator propertyPath comparator value}

For detailed information on how to build a query using queryString, value and querySettings parameters, please refer to the dataClass.query() function description.

Formulas are not supported by the collection.query() function, neither in the queryString parameter nor as formula object parameter.

Example 1

 var $c; $c2; $c3 : Collection
$c:=New collection
$c.push(New object("name";"Cleveland";"zc";35049))
$c.push(New object("name";"Blountsville";"zc";35031))
$c.push(New object("name";"Adger";"zc";35006))
$c.push(New object("name";"Clanton";"zc";35046))
$c.push(New object("name";"Clanton";"zc";35045))
$c2:=$c.query("name = :1";"Cleveland") //$c2=[{name:Cleveland,zc:35049}]
$c3:=$c.query("zc > 35040") //$c3=[{name:Cleveland,zc:35049},{name:Clanton,zc:35046},{name:Clanton,zc:35045}]

Example 2

 var $c : Collection
$c:=New collection
$c.push(New object("name";"Smith";"dateHired";!22-05-2002!;"age";45))
$c.push(New object("name";"Wesson";"dateHired";!30-11-2017!))
$c.push(New object("name";"Winch";"dateHired";!16-05-2018!;"age";36))

$c.push(New object("name";"Sterling";"dateHired";!10-5-1999!;"age";Null))
$c.push(New object("name";"Mark";"dateHired";!01-01-2002!))

This example returns persons whose name contains "in":

 $col:=$c.query("name = :1";"@in@")
//$col=[{name:Winch...},{name:Sterling...}]

This example returns persons whose name does not begin with a string from a variable (entered by the user, for example):

 $col:=$c.query("name # :1";$aString+"@")
//if $astring="W"
//$col=[{name:Smith...},{name:Sterling...},{name:Mark...}]

This example returns persons whose age is not known (property set to null or undefined):

 $col:=$c.query("age=null") //placeholders not allowed with "null"
//$col=[{name:Wesson...},{name:Sterling...},{name:Mark...}]

This example returns persons hired more than 90 days ago:

 $col:=$c.query("dateHired < :1";(Current date-90))
//$col=[{name:Smith...},{name:Sterling...},{name:Mark...}] if today is 01/10/2018

Example 3

More examples of queries can be found in the dataClass.query() page.

.reduce()

History
VersionChanges
v19 R6Support of formula
v16 R6Added

.reduce( formula : 4D.Function { ; initValue : any { ; ...param : expression }} ) : any
.reduce( methodName : Text { ; initValue : any { ; ...param : expression }} ) : any

ParameterTypeDescription
formula4D.Function->Formula object
methodNameText->Name of a method
initValueText, Number, Object, Collection, Date, Boolean->Value to use as the first argument to the first call of formula or methodName
paramexpression->Parameter(s) to pass
ResultText, Number, Object, Collection, Date, Boolean<-Result of the accumulator value

Description

The .reduce() function applies the formula or methodName callback against an accumulator and each element in the collection (from left to right) to reduce it to a single value.

This function does not modify the original collection.

You designate the callback to be executed to evaluate collection elements using either:

  • formula (recommended syntax), a Formula object that can encapsulate any executable expressions, including functions and project methods;
  • or methodName, the name of a project method (text).

The callback takes each collection element and performs any desired operation to accumulate the result into $1.accumulator, which is returned in $1.value.

You can pass the value to initialize the accumulator in initValue. If omitted, $1.accumulator starts with Undefined.

The callback receives the following parameters:

  • in $1.value: element value to be processed
  • in $2: param
  • in $N...: paramN...

The callback sets the following parameter(s):

  • $1.accumulator: value to be modified by the function and which is initialized by initValue.
  • $1.stop (boolean, optional): true to stop the method callback. The returned value is the last calculated.

Example 1

var $c : Collection
$c:=New collection(5;3;5;1;3;4;4;6;2;2)
$r:=$c.reduce(Formula($1.accumulator*=$1.value); 1) //returns 86400

Example 2

This example allows reducing several collection elements to a single one:

 var $c;$r : Collection
$c:=New collection
$c.push(New collection(0;1))
$c.push(New collection(2;3))
$c.push(New collection(4;5))
$c.push(New collection(6;7))
$r:=$c.reduce(Formula(Flatten)) //$r=[0,1,2,3,4,5,6,7]

With the following Flatten method:

 If($1.accumulator=Null)
$1.accumulator:=New collection
End if
$1.accumulator.combine($1.value)

.reduceRight()

History
VersionChanges
v20Added

.reduceRight( formula : 4D.Function { ; initValue : any { ; ...param : expression }} ) : any
.reduceRight( methodName : Text { ; initValue : any { ; ...param : expression }} ) : any

ParameterTypeDescription
formula4D.Function->Formula object
methodNameText->Name of a method
initValueText, Number, Object, Collection, Date, Boolean->Value to use as the first argument to the first call of formula or methodName
paramexpression->Parameter(s) to pass
ResultText, Number, Object, Collection, Date, Boolean<-Result of the accumulator value

Description

The .reduceRight() function applies the formula or methodName callback against an accumulator and each element in the collection (from right to left) to reduce it to a single value.

This function does not modify the original collection.

You designate the callback to be executed to evaluate collection elements using either:

  • formula (recommended syntax), a Formula object that can encapsulate any executable expressions, including functions and project methods;
  • or methodName, the name of a project method (text).

The callback takes each collection element and performs any desired operation to accumulate the result into $1.accumulator, which is returned in $1.value.

You can pass the value to initialize the accumulator in initValue. If omitted, $1.accumulator starts with Undefined.

The callback receives the following parameters:

  • in $1.value: element value to be processed
  • in $2: param
  • in $N...: paramN...

The callback sets the following parameter(s):

  • $1.accumulator: value to be modified by the function and which is initialized by initValue.
  • $1.stop (boolean, optional): true to stop the method callback. The returned value is the last calculated.

Example 1

var $c : Collection
$c:=New collection(5;3;5;1;3;4;4;6;2;2)
$r:=$c.reduceRight(Formula($1.accumulator*=$1.value); 1) //returns 86400

Example 2

This example allows reducing several collection elements to a single one:

 var $c;$r : Collection
$c:=New collection
$c.push(New collection(0;1))
$c.push(New collection(2;3))
$c.push(New collection(4;5))
$c.push(New collection(6;7))
$r:=$c.reduceRight(Formula(Flatten)) //$r=[6,7,4,5,2,3,0,1]

With the following Flatten method:

    //Flatten project method
If($1.accumulator=Null)
$1.accumulator:=New collection
End if
$1.accumulator.combine($1.value)

.remove()

History
VersionChanges
v16 R6Added

.remove( index : Integer { ; howMany : Integer } ) : Collection

ParameterTypeDescription
indexInteger->Element at which to start removal
howManyInteger->Number of elements to remove, or 1 element if omitted
ResultCollection<-Original collection without removed element(s)

Description

The .remove() function removes one or more element(s) from the specified index position in the collection and returns the edited collection.

This function modifies the original collection.

In index, pass the position where you want the element to be removed from the collection.

Warning: Keep in mind that collection elements are numbered from 0. If index is greater than the length of the collection, actual starting index will be set to the length of the collection.

  • If index < 0, it is recalculated as index:=index+length (it is considered as the offset from the end of the collection).
  • If the calculated value < 0, index is set to 0.
  • If the calculated value > the length of the collection, index is set to the length.

In howMany, pass the number of elements to remove from index. If howMany is not specified, then one element is removed.

If you try to remove an element from an empty collection, the method does nothing (no error is generated).

Example

 var $col : Collection
$col:=New collection("a";"b";"c";"d";"e";"f";"g";"h")
$col.remove(3) // $col=["a","b","c","e","f","g","h"]
$col.remove(3;2) // $col=["a","b","c","g","h"]
$col.remove(-8;1) // $col=["b","c","g","h"]
$col.remove(-3;1) // $col=["b","g","h"]

.resize()

History
VersionChanges
v16 R6Added

.resize( size : Integer { ; defaultValue : any } ) : Collection

ParameterTypeDescription
sizeInteger->New size of the collection
defaultValueNumber, Text, Object, Collection, Date, Boolean->Default value to fill new elements
ResultCollection<-Resized original collection

Description

The .resize() function sets the collection length to the specified new size and returns the resized collection.

This function modifies the original collection.

  • If size < collection length, exceeding elements are removed from the collection.
  • If size > collection length, the collection length is increased to size.

By default, new elements are filled will null values. You can specify the value to fill in added elements using the defaultValue parameter.

Example

 var $c : Collection
$c:=New collection
$c.resize(10) // $c=[null,null,null,null,null,null,null,null,null,null]

$c:=New collection
$c.resize(10;0) // $c=[0,0,0,0,0,0,0,0,0,0]

$c:=New collection(1;2;3;4;5)
$c.resize(10;New object("name";"X")) //$c=[1,2,3,4,5,{name:X},{name:X},{name:X},{name:X},{name:X}]

$c:=New collection(1;2;3;4;5)
$c.resize(2) //$c=[1,2]

.reverse()

History
VersionChanges
v16 R6Added

.reverse( ) : Collection

ParameterTypeDescription
ResultCollection<-Inverted copy of the collection

Description

The .reverse() function returns a deep copy of the collection with all its elements in reverse order. If the original collection is a shared collection, the returned collection is also a shared collection.

This function does not modify the original collection.

Example

 var $c; $c2 : Collection
$c:=New collection(1;3;5;2;4;6)
$c2:=$c.reverse() //$c2=[6,4,2,5,3,1]

.shift()

History
VersionChanges
v16 R6Added

.shift() : any

ParameterTypeDescription
Resultany<-First element of collection

Description

The .shift() function removes the first element of the collection and returns it as the function result.

This function modifies the original collection.

If the collection is empty, this method does nothing.

Example

 var $c : Collection
var $val : Variant
$c:=New collection(1;2;4;5;6;7;8)
$val:=$c.shift()
// $val=1
// $c=[2,4,5,6,7,8]

.slice()

History
VersionChanges
v16 R6Added

.slice( startFrom : Integer { ; end : Integer } ) : Collection

ParameterTypeDescription
startFromInteger->Start index (included)
endInteger->End index (not included)
ResultCollection<-New collection containing sliced elements (shallow copy)

Description

The .slice() function returns a portion of a collection into a new collection, selected from startFrom index to end index (end not included). This function returns a shallow copy of the collection. If the original collection is a shared collection, the returned collection is also a shared collection.

This function does not modify the original collection.

The returned collection contains the element specified by startFrom and all subsequent elements up to, but not including, the element specified by end. If only the startFrom parameter is specified, the returned collection contains all elements from startFrom to the last element of the original collection.

  • If startFrom < 0, it is recalculated as startFrom:=startFrom+length (it is considered as the offset from the end of the collection).
  • If the calculated value < 0, startFrom is set to 0.
  • If end < 0 , it is recalculated as end:=end+length.
  • If end < startFrom (passed or calculated values), the method does nothing.

Example

 var $c; $nc : Collection
$c:=New collection(1;2;3;4;5)
$nc:=$c.slice(0;3) //$nc=[1,2,3]
$nc:=$c.slice(3) //$nc=[4,5]
$nc:=$c.slice(1;-1) //$nc=[2,3,4]
$nc:=$c.slice(-3;-2) //$nc=[3]

.some()

History
VersionChanges
v19 R6Support of formula
v16 R6Added

.some( { startFrom : Integer ; } formula : 4D.Function { ; ...param : any } ) : Boolean
.some( { startFrom : Integer ; } methodName : Text { ; ...param : any } ) : Boolean

ParameterTypeDescription
startFromInteger->Index to start the test at
formula4D.Function->Formula object
methodNameText->Name of a method
paramMixed->Parameter(s) to pass
ResultBoolean<-True if at least one element successfully passed the test

Description

The .some() function returns true if at least one element in the collection successfully passed a test implemented in the provided formula or methodName code.

You designate the 4D code (callback) to be executed to evaluate collection elements using either:

  • formula (recommended syntax), a Formula object that can encapsulate any executable expressions, including functions and project methods;
  • or methodName, the name of a project method (text).

The callback is called with the parameter(s) passed in param (optional). The callback can perform any test, with or without the parameter(s) and must return true for every element fulfilling the test. It receives an Object in first parameter ($1).

The callback receives the following parameters:

  • in $1.value: element value to be processed
  • in $2: param
  • in $N...: paramN...

It can set the following parameter(s):

  • (mandatory if you used a method) $1.result (boolean): true if the element value evaluation is successful, false otherwise.
  • $1.stop (boolean, optional): true to stop the method callback. The returned value is the last calculated.

In any case, at the point where .some() function encounters the first collection element returning true, it stops calling the callback and returns true.

By default, .some() tests the whole collection. Optionally, you can pass the index of an element from which to start the test in startFrom.

  • If startFrom >= the collection's length, False is returned, which means the collection is not tested.
  • If startFrom < 0, it is considered as the offset from the end of the collection.
  • If startFrom = 0, the whole collection is searched (default).

Example

You want to know if at least one collection value is >0.

 var $c : Collection
var $b : Boolean
$c:=New collection
$c.push(-5;-3;-1;-4;-6;-2)
$b:=$c.some(Formula($1.value>0)) // $b=false
$c.push(1)
$b:=$c.some(Formula($1.value>0)) // $b=true

$c:=New collection
$c.push(1;-5;-3;-1;-4;-6;-2)
$b:=$c.some(Formula($1.value>0)) //$b=true
$b:=$c.some(1;Formula($1.value>0)) //$b=false

.sort()

History
VersionChanges
v19 R6Support of formula
v16 R6Added

.sort() : Collection
.sort( formula : 4D.Function { ; ...extraParam : any } ) : Collection
.sort( methodName : Text { ; ...extraParam : any } ) : Collection

ParameterTypeDescription
formula4D.Function->Formula object
methodNameText->Name of a method
extraParamany->Parameter(s) for the method
ResultCollection<-Original collection sorted

Description

The .sort() function sorts the elements of the original collection and also returns the sorted collection .

This function modifies the original collection.

If .sort() is called with no parameters, only scalar values (number, text, date, booleans) are sorted. Elements are sorted by default in ascending order, according to their type. If the collection contains elements of different types, they are first grouped by type and sorted afterwards. Types are returned in the following order:

  1. null
  2. booleans
  3. strings
  4. numbers
  5. objects
  6. collections
  7. dates

If you want to sort the collection elements in some other order or sort any type of element, you must supply in formula (Formula object) or methodName (Text) a callback that defines the sort order. The return value should be a boolean that indicates the relative order of the two elements: True if $1.value is less than $1.value2, False if $1.value is greater than $1.value2. You can provide additional parameters to the callback if necessary.

The callback receives the following parameters:

  • $1 (object), where:
    • $1.value (any type): first element value to be compared
    • $1.value2 (any type): second element value to be compared
  • $2...$N (any type): extra parameters

If you used a method, you must set the folllowing parameter:

  • $1.result (boolean): true if $1.value < $1.value2, false otherwise.

Example 1

 var $col; $col2 : Collection
$col:=New collection("Tom";5;"Mary";3;"Henry";1;"Jane";4;"Artie";6;"Chip";2)
$col2:=$col.sort() // $col2=["Artie","Chip","Henry","Jane","Mary","Tom",1,2,3,4,5,6]
// $col=["Artie","Chip","Henry","Jane","Mary","Tom",1,2,3,4,5,6]

Example 2

 var $col; $col2 : Collection
$col:=New collection(10;20)
$col2:=$col.push(5;3;1;4;6;2).sort() //$col2=[1,2,3,4,5,6,10,20]

Example 3

var $col; $col2; $col3 : Collection
$col:=New collection(33;4;66;1111;222)
$col2:=$col.sort() //numerical sort: [4,33,66,222,1111]
$col3:=$col.sort(Formula(String($1.value)<String($1.value2))) //alphabetical sort: [1111,222,33,4,66]

.sum()

History
VersionChanges
v16 R6Added

.sum( { propertyPath : Text } ) : Real

ParameterTypeDescription
propertyPathText->Object property path to be used for calculation
ResultReal<-Sum of collection values

Description

The .sum() function returns the sum for all values in the collection instance.

Only numerical elements are taken into account for the calculation (other element types are ignored).

If the collection contains objects, pass the propertyPath parameter to indicate the object property to take into account.

.sum() returns 0 if:

  • the collection is empty,
  • the collection does not contain numerical elements,
  • propertyPath is not found in the collection.

Example 1

 var $col : Collection
var $vSum : Real
$col:=New collection(10;20;"Monday";True;2)
$vSum:=$col.sum() //32

Example 2

 var $col : Collection
var $vSum : Real
$col:=New collection
$col.push(New object("name";"Smith";"salary";10000))
$col.push(New object("name";"Wesson";"salary";50000))
$col.push(New object("name";"Gross";"salary";10500,5))
$vSum:=$col.sum("salary") //$vSum=70500,5

.unshift()

History
VersionChanges
v16 R6Added

.unshift( value : any { ;...valueN : any } ) : Collection

ParameterTypeDescription
valueText, Number, Object, Collection, Date->Value(s) to insert at the beginning of the collection
ResultReal<-Collection containing added element(s)

|

Description

The .unshift() function inserts the given value(s) at the beginning of the collection and returns the modified collection.

This function modifies the original collection.

If several values are passed, they are inserted all at once, which means that they appear in the resulting collection in the same order as in the argument list.

Example

 var $c : Collection
$c:=New collection(1;2)
$c.unshift(4) // $c=[4,1,2]
$c.unshift(5) //$c=[5,4,1,2]
$c.unshift(6;7) // $c=[6,7,5,4,1,2]