Version: v19 R8 BETA

EntitySelection

Uma seleção de entidades é um objeto que contém uma ou mais referencias a entidades pertencentes à mesma Dataclass. Uma seleção de entidades pode conter 0, 1 ou X entidades da dataclass -- onde X pode representar o número total de entidades contidas na dataclass.

As seleções de entidades podem ser criadas a partir de seleções existentes utilizando varias funções da classe DataClass class tais como .all() ou .query(), ou da classe EntityClass mesma, tal como .and() ou orderBy(). Também pode criar seleções de entidades em branco utilizando a função dataClass.newSelection() ou o comando Create new selection.

Resumo


attributePath for um atributo relativo, permite acessar entidades sem a seleção de entidade usando a sintaxe coleção padrão
*.attributeName* : Collection *.attributeName* : 4D.EntitySelection uma "projeção" de valoress para o atributo na seleção de entidades
.add( entity : 4D.Entity ) : 4D.EntitySelection .add( entitySelection : 4D.EntitySelection ) : 4D.EntitySelection addiciona a entity especificada ou entitySelection para a selleção de entidade original e retona a seleção de entidade modificada
.and( entity : 4D. Entity ) : 4D. EntitySelection .and( entitySelection : 4D. EntitySelection ) : 4D. EntitySelection combines the entity selection with an entity or entitySelection parameter using the logical AND operator
.average( {propertyPath : Text } ) : Real returns the arithmetic mean (average) of all the non-null values of attributePath in the entity selection
attributePath for um atributo relativo, returns true if entity reference belongs to the entity selection
.count( attributePath : Text ) : Real returns the number of entities in the entity selection with a non-null value in attributePath
.distinct( attributePath : Text { ; option : Integer } ) : Collection returns a collection containing only distinct (different) values from the attributePath in the entity selection
.drop( { mode : Integer } ) : 4D. EntitySelection remove as entidades pertencendo à seleção de entidade da tabela relacionada a dataclasse dentro da datastore
.extract( attributePath : Text { ; option : Integer } ) : Collection .extract( attributePath { ; targetPath } { ; ...attributePathN : Text ; targetPathN : Text } ) : Collection returns a collection containing attributePath values extracted from the entity selection
.first() : 4D. Entity returns a reference to the entity in the first position of the entity selection
.getDataClass() : 4D. DataClass returns the dataclass of the entity selection
.getRemoteContextAttributes() : Text retorna informação sobre o contexto de otimização usado pela entidade
.isAlterable() : Boolean returns True if the entity selection is alterable
.isOrdered() : Boolean returns True if the entity selection is ordered
.last() : 4D. Entity returns a reference to the entity in last position of the entity selection
.length : Integer retorna o número de entidades na seleção de entidade
.max( attributePath : Text ) : any retorna o valor mais alto (ou máximo) entre todos os valores de attributePath na seleção de entidade
.min( attributePath : Text ) : any retorna o menor valor (mínimo) entre todos os valores de attributePath na seleção de entidade
.minus( entity : 4D.Entity { ; keepOrder : Integer } ) : 4D.EntitySelection .minus( entitySelection : 4D.EntitySelection { ; keepOrder : Integer } ) : 4D.EntitySelection excludes from the entity selection to which it is applied the entity or the entities of entitySelection and returns the resulting entity selection
.or( entity : 4D.Entity ) : 4D.EntitySelection .or( entitySelection : 4D.EntitySelection ) : 4D.EntitySelection combines the entity selection with the entity or entitySelection parameter using the logical (not exclusive) OR operator
.orderBy( pathString : Text ) : 4D.EntitySelection .orderBy( pathObjects : Collection ) : 4D.EntitySelection returns a new ordered entity selection containing all entities of the entity selection in the order specified by pathString or pathObjects criteria
.orderByFormula( formulaString : Text { ; sortOrder : Integer } { ; settings : Object} ) : 4D.EntitySelection .orderByFormula( formulaObj : Object { ; sortOrder : Integer } { ; settings : Object} ) : 4D.EntitySelection returns a new, ordered entity selection
.query( queryString : Text { ; ...value : any } { ; querySettings : Object } ) : 4D. EntitySelection .query( formula : Object { ; querySettings : Object } ) : 4D. EntitySelection pesquisa por entidades que satisfazem o critério de pesquisa especificado em queryString ou formula e (opcionalmente) value(s) entre todas as entidades na seleção de entidade
.queryPath : Text contém uma descrição detalhada da pesquisa como foi realizada em 4D
.queryPlan : Text contém uma descrição detalhada da pesquisa antes da execução (ou seja, a pesquisa planejada)
.refresh() immediately "invalidates" the entity selection data in the local ORDA cache
.selected( selectedEntities : 4D. EntitySelection ) : Object retorna um objeto descrevendo a posição da selectedEntities na seleção de entidade original
.slice( startFrom : Integer { ; end : Integer } ) : 4D. EntitySelection retorna uma porção da seleção de entidade em uma nova seleção de entidade
.sum( attributePath : Text ) : Real returns the sum for all attributePath values in the entity selection
.toCollection( { options : Integer { ; begin : Integer { ; howMany : Integer } } ) : Collection .toCollection( filterString : Text {; options : Integer { ; begin : Integer { ; howMany : Integer }}} ) : Collection .toCollection( filterCol : Collection {; options : Integer { ; begin : Integer { ; howMany : Integer }}} ) : Collection creates and returns a collection where each element is an object containing a set of properties and values

Criar uma seleção de entidades (entity selection)

attributePath não se encontra na classe de dados da entity selection.

Parâmetros	Tipo		Descrição
dsTable	Tabela	->	Tabela do banco de dados 4D cuja seleção atual se utilizará para construir a seleção de entidades
settings	Objeto	->	Build option: context
Resultados	4D. EntitySelection	<-	Seleção de entidades que coincidem com a classe de dados relacionada com a tabela dada

Descrição

O comando Create entity selection constrói e devolve uma nova, alterável seleção de entidade relacionada com a classe de dados que coincide com a tabela dsTable dada, segundo a seleção atual desta tabela.

Se a seleção atual for ordenada, é criada uma seleção de entidades ordenada (se mantém a ordem da seleção atual). Se a seleção atual não for ordenada, se cria uma seleção de entidades não ordenada.

Se a tabela dsTable não estiver exposta em ds, se devolve um erro. Esse comando não pode usado com uma datastore remota.

No parâmetro opcionalsettings pode passar um objeto contendo as propriedades abaixo:

Propriedade	Tipo	Descrição
context	Text	Etiqueta para contexto de optimização aplicado a entity selection.

Exemplo

var $employees : cs. EmployeeSelection ALL RECORDS([Employee])
$employees:=Create entity selection([Employee]) 
// A entity selection $employees agora contém um conjunto de referências
// em todas as entidades relacionadas com a classe de dados Employee

Veja também

dataClass.newSelection()

USE ENTITY SELECTION

USE ENTITY SELECTION (entitySelection)

Parâmetros	Tipo		Descrição
entitySelection	EntitySelection	->	Seleção de entidades

Descrição

O comando USE ENTITY SELECTION atualiza a seleção atual da tabela correspondendo à dataclass do parâmetro entitySelection de acordo com o contexto da seleção de entidade.

Este comando não pode ser utilizado com um datastore remoto.

Depois de uma chamada a USE ENTITY SELECTION, o primeiro registro da seleção atual (se não vazia) vira o registro atual, mas não é carregado na memória.. Se precisar usar os valores dos campos no registro atual, use o comando LOAD RECORD depois do comando USE ENTITY SELECTION.

Exemplo

var $entitySel : Object

$entitySel:=ds. Employee.query("lastName = :1";"M@") //$entitySel is related to the Employee dataclass REDUCE SELECTION([Employee];0)
USE ENTITY SELECTION($entitySel) //The current selection of the Employee table is updated

[index]

Histórico

Versão	Mudanças
v17	Adicionado

attributePath for um atributo relativo,

Descrição

A notação EntitySelection[index] permite acessar entidades sem a seleção de entidade usando a sintaxe coleção padrão: passe a posição da entidade que quiser colocar o padrão index.

Lembre que a entidade correspondente é recarregada a partir da datastore.

index pode ser qualquer número entre 0 e .length-1.

Se index está fora do intervalo, se devolve um erro.
If attributeName kind is storage: .attributeName returns a collection of values of the same type as attributeName.

caution

EntitySelection[index] é uma expressão não atribuível que significa que não pode ser usada como uma referência de entidade editável com métodos como .lock() ou .save(). Para trabalhar com a entidade correspondente, é necessário atribuir a expressão devolvida a uma expressão atribuível, como uma variável. Exemplos:

 $sel:=ds. Employee.all() //criação da entity selection
  //declarações não válidas:
 $result:=$sel[0].lock() //NÃO funcionará
 $sel[0].lastName:="Smith" //NÃO funcionará
 $result:=$sel[0].save() //NÃO funcionará
  //valid code:
 $entity:=$sel[0]  //OK
 $entity.lastName:="Smith" //OK
 $entity.save() //OK

Exemplo

 var $employees : cs. EmployeeSelection
 var $employee : cs. EmployeeEntity
 $employees:=ds. Employee.query("lastName = :1";"H@")
 $employee:=$employees[2]  // A terceira entidade da seleção de entidades $employees se recarrega do banco de dados

.attributeName

Histórico

Versão	Mudanças
v17	Adicionado

.attributeName : Collection
.attributeName : 4D.EntitySelection

Descrição

Any dataclass attribute can be used as a property of an entity selection to return uma "projeção" de valoress para o atributo na seleção de entidades. Também pode criar seleções de entidades em branco utilizando a função dataClass.newSelection() ou o comando Create new selection.

Se o "kind" de attributeName é storage: .attributeName devolve uma coleção de valores do mesmo tipo que attributeName.
If attributeName kind is relatedEntity: .attributeName returns a new entity selection of related values of the same type as attributeName. Se eliminam os duplicados (se devolve uma seleção de entidades desordenada).
If attributeName kind is relatedEntities: .attributeName returns a new entity selection of related values of the same type as attributeName. Se eliminam os duplicados (se devolve uma seleção de entidades desordenada).

Quando se utiliza um atributo de relação como propriedade de uma seleção de entidades, o resultado é sempre outra seleção de entidades, mesmo que só se devolva uma entidade. If the original entity selection and the entitySelection parameter are empty, an empty entity selection is returned.

Se o atributo não existir na seleção de entidades, se devolve um erro.

Exemplo 1

Projeção de valores de armazenamento:

 var $firstNames : Collection
 $entitySelection:=ds. Employee.all()
 $firstNames:=$entitySelection.firstName // firstName é um string

A coleção resultante é uma coleção de strings, por exemplo:

[
    "Joanna",
    "Alexandra",
    "Rick"
]

Exemplo 2

Projeção da entidade relacionada:

 var $es; $entitySelection : cs. EmployeeSelection
 $entitySelection:=ds. Employee.all()
 $es:=$entitySelection.employer // employer é relacionada aum  Company dataClass

O objeto resultane é uma seleção de entidade da Empresa com duplicações removidas (se houver).

Exemplo 3

Projeção de entidades relacionadas:

 var $es : cs. EmployeeSelection
 $es:=ds. Employee.all().directReports // directReports é relacionada a dataclasse Funcionário

O objeto resultante é uma seleção de entidade da dataclasse Funcionario sem duplicatas (se houver).

.add()

Histórico

Versão	Mudanças
v19 R7	Suporte do parâmetro entitySelection
v18 R5	Compatível apenas com seleções de entidade alteráveis
v17	Adicionado

.add( entity : 4D.Entity ) : 4D.EntitySelection
.add( entitySelection : 4D.EntitySelection ) : 4D.EntitySelection

Parâmetros	Tipo		Descrição
entity	4D. Entity	->	Entidade que deve ser adicinonada à entity selection
entitySelection	4D. EntitySelection	->	Seleção entidade paara ser adicionado a sellleção entidade originaal
Resultados	4D. EntitySelection	->	selelção de entidade inclluindo a entity ou entitySelection

Descrição

A função .add() addiciona a entity especificada ou entitySelection para a selleção de entidade original e retona a seleção de entidade modificada.

Os valores de tipo Date são convertidos em valores numéricos (segundos) e são usados para calcular a média.

warning

a entity selection deve ser alterable, ou seja. foi criada por exemplo por .newSelection() ou Create entity selection, senão .add() vai retornar um erro. As entity selections partilháveis não aceitam a adição de entidades. Para saber mais, consulte Entity selections compartilháveis ou modificáveis .

Adicionar uma entidade

Se a entity selection estiver ordenada, entity se adiciona ao final da seleção. Se uma referência a mesma entidade já pertencer a seleção de entidades, se duplica e se adiciona uma nova referência.
Se a entity selection não estiver ordenada, entity se adiciona em qualquer lugar da seleção, sem uma ordem específica.

Adicionar uma seleção de entidades

Se a entity selection estiver ordenada, entity se adiciona ao final da seleção. Se as referências às mesmas entidades de entitySelection já pertencem à seleção de entidades, se duplicam e se adicionam novas referencias.
Se a seleção de entidade nãofor ordenada, ela fica ordenada.
Para saber mais veja Entity selections ordenada ou não ordenadas.

A entity selection modificada é devolvida pela função, de modo que as chamadas à função podem ser encadeados.

Se produz um erro se entity e a entity selection não estão relacionadas com a mesma dataclass. Se entity for Null, não se produz nenhum erro.

Exemplo 1

 var $employees : cs. EmployeeSelection
 var $employee : cs. EmployeeEntity
 $employees:=ds. Employee.query("lastName = :1";"S@")
 $employee:=ds. Employee.new()
 $employee.lastName:="Smith"
 $employee.save()
 $employees.add($employee) //A entidade $employee se adiciona a entity selection $employees

Exemplo 2

As chamadas à função podem ser encadeadas:

 var $sel : cs. ProductSelection
 var $p1;$p2;$p3 : cs. ProductEntity

 $p1:=ds. Product.get(10)
 $p2:=ds. Product.get(11)
 $p3:=ds. Product.get(12)
 $sel:=ds. Product.query("ID > 50")
 $sel:=$sel.add($p1).add($p2).add($p3)

Exemplo 3

Em uma interface de usuário, temos duas listas. O usuário seleciona itens da lista 1 e as adiciona na lista 2.

$sellist2:=$sellist2.add($sellist1)

.and()

Histórico

Versão	Mudanças
v17	Adicionado

.and( entity : 4D. Entity ) : 4D. EntitySelection
.and( entitySelection : 4D. EntitySelection ) : 4D. EntitySelection

Parâmetros	Tipo		Descrição
entity	4D. Entity	->	Entidade a intersectar
entitySelection	4D. EntitySelection	->	Entity selection a intersectar
Resultados	4D. EntitySelection	<-	Entity selection resultante da intersecção com o operador lógico AND

Descrição

A função .and() combines the entity selection with an entity or entitySelection parameter using the logical AND operator; se retornar uma nova e não ordenada seleção de entidade que contenha só as entidades referenciaadas tanto na seleção de entidade quanto no parâmetro.

Se passar entity como parâmetro, se combina esta entidade com a entity selection. Se a entidade pertencer à entity selection, se devolve uma nova entity selection que só contém a entidade. Senão, uma seleção de entidades vazia é retornada.
If you pass entity as parameter, you compare this entity with the entity selection. If the entity belongs to the entity selection, a new reference to the entity selection is returned. Otherwise, a new entity selection containing the original entity selection and the entity is returned.
Pode comparar entity selections ordenadas ou desordenadas. A seleção resultante é sempre desordenada.

Se a entity selection inicial ou o parâmetro entitySelection estiverem vazios, ou se entity for Null, se devolve uma entity selection vazia.

Se a entity selection inicial e o parâmetro não forem relacionados com a mesma dataclass, se produz um erro.

Exemplo 1

 var $employees; $notDropped : cs. EmployeeSelection
 $employees:=ds.Employee.query("firstName=:1";"S@")
 $notDropped:=$employees.drop(dk stop dropping on first error) //$notDropped é uma entity selection que contém a primeira entidade não eliminada
 If($notDropped.length=0) //A ação de eliminação é exitosa, todas as entidades foram eliminadas
    ALERT("You have dropped "+String($employees.length)+" employees") //A seleção de entidades eliminada permanece na memória
 Else
    ALERT("Problem during drop, try later")
 End if

Exemplo 2

Se quisermos ter uma seleção de empregados chamados "Jones" que morem em Nova York:

 var $sel1; $sel2; $sel3 : cs. EmployeeSelection
 $sel1:=ds. Employee.query("name =:1";"Jones")
 $sel2:=ds. Employee.query("city=:1";"New York")
 $sel3:=$sel1.and($sel2)

.average()

Histórico

Versão	Mudanças
v18 R6	Retorna indefinido se uma seleção de entidade for vazia
v17	Adicionado

.average( {propertyPath : Text } ) : Real

Parâmetros	Tipo		Descrição
attributePath	Text	->	Rota de atributo a utilizar para o cálculo
Resultados	Real	<-	Media aritmética (média) dos valores das entidades para o atributo (Não se define para uma entity selection vazia)

Descrição

A função .average() returns the arithmetic mean (average) of all the non-null values of attributePath in the entity selection.

Passe no parâmetro attributePath a rota de atributo a avaliar.

Só são levados em consideração os valores numéricos para o cálculo. Lembre entretanto que se o attributePath da seleção de entidades conter tipos de valores mistos, .average() considera todos os elementos escalares para calcular o valor médio.

Para saber mais sobre propriedade compartilhável de entity selections, consulte Entity selections compartilháveis ou modificáveis.

.average() returns undefinedse a entity selection estiver vazia ou attributePath não conter valores numéricos.

Um erro é retornado se:

attributePath é um atributo relativo,
attributePath designa um atributo que não existir na dataclass da entity selection.

Exemplo

Se quisermos obter uma lista de funcionários cujo salário for superior ao salário médio:

 var $averageSalary : Real
 var $moreThanAv : cs. EmployeeSelection
 $averageSalary:=ds. Employee.all().average("salary")
 $moreThanAv:=ds. Employee.query("salary > :1";$averageSalary)

.contains()

Histórico

Versão	Mudanças
v17	Adicionado

attributePath for um atributo relativo,

Parâmetros	Tipo		Descrição
entity	4D. Entity	->	Entidade a ser avaliada
Resultados	Booleano	<-	Truse se a entidade pertencer à entity selection, senão False

Descrição

A função .contains() returns true if entity reference belongs to the entity selectione false de outra forma.

Em entity, especifique a entidade a buscar na entity selection. Se a entidade for Null, a função devolverá false.

Se entity e a entity selection não pertencerem à mesma dataclass, se produz um erro.

Exemplo

 var $employees : cs. EmployeeSelection
 var $employee : cs. EmployeeEntity

 $employees:=ds.Employee.query("lastName=:1";"H@")
 $employee:=ds. Employee.get(610)

 If($employees.contains($employee))
    ALERT("A entidade com chave primaria 610 tem um sobrenome começando com H")
 Else
    ALERT("A entidade com chave primária 610 não tem um sobrenome começando com H")
 End if

.count()

Histórico

Versão	Mudanças
v17	Adicionado

.count( attributePath : Text ) : Real

Parâmetros	Tipo		Descrição
attributePath	Text	->	Rota do atributo que se utilizará para o cálculo
Resultados	Real	<-	Número de valores de attributePath que não são null na entity selection

Descrição

A função .count() returns the number of entities in the entity selection with a non-null value in attributePath.

Só são levados em consideração os valores escalares. Os valores de tipo objeto ou coleção são considerados valores nulos.

Um erro é retornado se:

attributePath é um atributo relativo,
attributePath não se encontra na classe de dados da entity selection.

Exemplo

Se quisermos encontrar o número total de empregados para uma empresa sem contar aqueles cujos titulos de mprego não foram especificados:

 var $sel : cs. EmployeeSelection
 var $count : Real

 $sel:=ds. Employee.query("employer = :1";"Acme, Inc")
 $count:=$sel.count("jobtitle")

.copy()

Histórico

Versão	Mudanças
v18 R5	Adicionado

.copy( { option : Integer } ) : 4D. EntitySelection

Parâmetros	Tipo		Descrição
option	Integer	->	`ck shared`: devolve uma entity selection compartilhável
Resultados	4D. EntitySelection	<-	Cópia da entity selection

Descrição

A função .copy() returns a copy of the original entity selection.

Esta função não modifica a entity selection original.

Como padrão, se omitir o parámetro option, a função devolve uma nova entity selection alterável (mesmo se a função se aplicar a uma entity selection compartilhável). Passe a constante ck shared no parâmetro option se quiser criar uma entity selection compartilhável.

Para saber mais sobre propriedade compartilhável de entity selections, consulte Entity selections compartilháveis ou modificáveis.

Exemplo

Se criar uma nova seleção de entidade vazia de produtos quando o formulário for carregado:

 Case of
    :(Form event code=On Load)
       Form.products:=ds. Products.newSelection()
 End case

Então esta seleção de entidades é atualizada com produtos e se quiser compartilhar os produtos entre vários processos. Se copiar a seleçãod a entidade Form.products como compartilhável:

 ...
  // A seleção de entidades de Form.products se atualiza
 Form.products.add(Form.selectedProduct)

 Use(Storage)
    If(Storage.products=Null)
       Storage.products:=New shared object()
    End if

    Use(Storage.products)
       Storage.products:=Form.products.copy(ck shared)
    End use
 End use

.distinct()

Histórico

Versão	Mudanças
v17	Adicionado

.distinct( attributePath : Text { ; option : Integer } ) : Collection

Parâmetros	Tipo		Descrição
attributePath	Text	->	Rota do atributo cujos valores quer obter
option	Integer	->	`dk diacritical`: avaliação diacríticos ("A" # "a" por exemplo)
Resultados	Collection	<-	Coleção apenas com valores distintos

Descrição

A função .distinct() returns a collection containing only distinct (different) values from the attributePath in the entity selection.

A coleção retornada é ordenada automaticamente. Valores Null não são retornados.

No parámetro attributePath, passe o atributo de entidade cujos valores distintos queira obter. Só valores escalares (texto, número, booleano, ou data) podemser manejados. Tipos são retornados na ordem abaixo: Se attributePath levar a uma propriedade de objeto que conter valores de diferentes tipos, primeiro se agrupam por tipo e se ordenam depois.

booleans
strings
números
datas

Pode utilizar a notação [] para designar uma coleção quando attributePath for uma rota dentro de um objeto (ver exemplos).

Como padrão, uma avaliação não-diacrítica é realizada. Se quiser que a avaliação diferencie minúsculas de maiúsculas ou que diferencie letras acentuadas, passe a constante dk diacritical no parâmetrooption.

Um erro é retornado se:

attributePath é um atributo relativo,
attributePath não se encontra na classe de dados da entity selection.

Exemplos

Se quiser obter uma coleção que contenha um só elemento por nome de país:

 var $countries : Collection
 $countries:=ds. Employee.all().distinct("address.country")

nicknames é uma coleção e extra for um atributo de objeto:

$values:=ds. Employee.all().distinct("extra.nicknames[].first")

.drop()

Histórico

Versão	Mudanças
v17	Adicionado

.drop( { mode : Integer } ) : 4D. EntitySelection

Parâmetros	Tipo		Descrição
mode	Integer	->	`dk stop dropping on first error`: para a execução do método na primeira entidade não eliminável
Resultados	4D. EntitySelection	<-	Entidade de seleção vazia se for executada com êxito, se nenhuma entity selection contendo as entidades não elimináveis

Descrição

A função .drop() remove as entidades pertencendo à seleção de entidade da tabela relacionada a dataclasse dentro da datastore. A entity selection permanece na memoria.

A eliminação de entidades é permanente e não pode ser desfeita. É recomendado chamar esta ação em uma transação para ter uma opção de recuperação.

Se encontrar uma entidade bloqueada durante a execução de .drop(), não é eliminado. Como padrão o método processa todas as entidades da seleção de entidades e retorna as entidades não elimináveis na entity selection. Se quiser que o método pare a execução na primeira entidade não eliminável encontrada, passe a constante dk stop dropping on first error no parâmetro mode.

Exemplo

Exemplo sem a opção dk stop dropping on first error:

 var $employees; $notDropped : cs.EmployeeSelection
 $employees:=ds.Employee.query("firstName=:1";"S@")
 $notDropped:=$employees.drop() // $notDropped for uma entity selection que contém todas as entidades não suprimidas
 If($notDropped.length=0) //A ação de eliminação for exitosa, todas as entidades foram eliminadas
    ALERT("You have dropped "+String($employees.length)+" employees") //A seleção de entidades eliminada permanece na memoria
 Else
    ALERT("Problem during drop, try later")
 End if

Exemplo com a opção dk stop dropping on first error:

 var $employees; $notDropped : cs.EmployeeSelection
 $employees:=ds.Employee.query("firstName=:1";"S@")
 $notDropped:=$employees.drop(dk stop dropping on first error) //$notDropped é uma entity selection que contém a primeira entidade não eliminada
 If($notDropped.length=0) //A ação de eliminação é exitosa, todas as entidades foram eliminadas
    ALERT("You have dropped "+String($employees.length)+" employees") //A seleção de entidades eliminada permanece na memória
 Else
    ALERT("Problem during drop, try later")
 End if

.extract()

Histórico

Versão	Mudanças
v18 R3	Adicionado

.extract( attributePath : Text { ; option : Integer } ) : Collection
.extract( attributePath { ; targetPath } { ; ...attributePathN : Text ; targetPathN : Text } ) : Collection

Parâmetros	Tipo		Descrição
attributePath	Text	->	Rota de atributo cujos valores serão extraídos para nova coleção
targetpath	Text	->	Rota ou nome do atributo objetivo
option	Integer	->	`ck keep null`: inclui os atributos null na coleção devolvida (ignorados por padrão)
Resultados	Collection	<-	Coleção contendo valores extraídos

Descrição

A função .extract() returns a collection containing attributePath values extracted from the entity selection.

attributePath pode ser:

um atributo escalar de dataclass,
entidade relacionada,
entidades relacionadas.

Se attributePath não for válido, se devolve uma coleção vazia.

Esta função aceita duas sintaxes.

.extract( attributePath : Text { ; option : Integer } ) : Collection

Com esta sintaxe, .extract() preenche a coleção devolvida com os valores attributePath da entity selection.

Como padrão, as entidades para as que attributePath fornull ou indefinida são ignoradas na coleção resultante. Pode passar a constante ck keep null no parâmetro option para incluir esses valores como elementosnull na coleção retornada.

Atributos de Dataclass com .kind = "relatedEntity" extraídos como uma coleção de entidades (duplicações são mantidas).
Atributos de dataclass com .kind = "relatedEntities" são extraídas como coleção de seleção de entidades.

.extract ( attributePath ; targetPath { ; ...attributePathN ; ... targetPathN}) : Collection

Com esta sintaxe, .extract() preenche a coleção devolvida com as propriedades attributePath da entity selection. Cada elemento da coleção devolvida é um objeto com as propriedades targetPath preenchidas com as propriedades attributePath correspondentes. Se mantém os valores null (o parámetro option se ignora) com esta sintaxe.

Se vários attributePath, forem dados, deve dar um targetPath para cada um. Só se extraem os pares válidos [attributePath, targetPath].

Os atributos dataclass com .kind = "relatedEntity" se extraem como uma entidade.
Os atributos dataclass com .kind = "relatedEntities" se extraem como uma entity selection

Os valores Null são avaliados como inferiores aos outros valores.

Exemplo

Dada a seguinte tabela e relação:

 var $firstnames; $addresses; $mailing; $teachers : Collection
  //
  //
  //$firstnames é uma coleção de Strings


 $firstnames:=ds. Teachers.all().extract("firstname")
  //
  //$addresses é uma coleção de entities relacionadas ao dataclass Address
  //Valores Null para o endereço são extraídos
 $addresses:=ds. Teachers.all().extract("address";ck keep null)
  //
  //
  //$mailing é uma coleção de objetos com propriedades "who" e "to"
  //conteúdo propriedade "who" é do tipo String
  //conteudo propriedade "to" é do tipo entity (Address dataclass)
 $mailing:=ds. Teachers.all().extract("lastname";"who";"address";"to")
  //
  //
  //$mailing é uma coleção de objetos com propriedades "who" e "city"
  //conteúdo propriedade "who" é tipo String
  //conteúdo propriedade "city" é tipo String
 $mailing:=ds. Teachers.all().extract("lastname";"who";"address.city";"city")
  //
  //$teachers é uma coleção de objetos com propriedades "where" e "who"
  //conteúdo propriedade "where" é String
  //conteúdo propriedade "who" é uma entity selection (Teachers dataclass)
 $teachers:=ds. Address.all().extract("city";"where";"teachers";"who")
  //
  //$teachers é uma coleção de entity selections
 $teachers:=ds. Address.all().extract("teachers")

.first()

Histórico

Versão	Mudanças
v17	Adicionado

.first() : 4D. Entity

Parâmetros	Tipo		Descrição
Resultados	4D. Entity	<-	Referência à primeira entidade da seleção de entidade (Null se seleção for vazia)

Descrição

A função .first() returns a reference to the entity in the first position of the entity selection.

O resultado desta função é similar a:

 $entity:=$entitySel[0]

Há, entretanto, uma diferença entre ambas as afirmações quando a seleção estiver vazia:

 var $entitySel : cs. EmpSelection
 var $entity : cs. EmpEntity
 $entitySel:=ds. Emp.query("lastName = :1";"Nonexistentname") //nenhuma entity correspondente
  //entity selection é esvaziada
 $entity:=$entitySel.first() //retorna Null
 $entity:=$entitySel[0]  //gera um erro

Exemplo

 var $entitySelection : cs. EmpSelection
 var $entity : cs. EmpEntity
 $entitySelection:=ds. Emp.query("salary > :1";100000)
 If($entitySelection.length#0)
    $entity:=$entitySelection.first()
 End if

.getDataClass()

Histórico

Versão	Mudanças
v17 R5	Adicionado

.getDataClass() : 4D. DataClass

Parâmetros	Tipo		Descrição
Resultados	4D. DataClass	<-	Objeto dataclass ao qual a seleção de entidade pertence

Descrição

A função .getDataClass() returns the dataclass of the entity selection.

Esta função é principalmente útil no contexto do código genérico.

Exemplo

O seguinte código genérico duplica todas as entidades da entity selection:

  //duplicate_entities method
  //duplicate_entities($entity_selection)

 #DECLARE ( $entitySelection : 4D. EntitySelection )  
 var $dataClass : 4D. DataClass
 var $entity; $duplicate : 4D. Entity
 var $status : Object
 $dataClass:=$entitySelection.getDataClass()
 For each($entity;$entitySelection)
    $duplicate:=$dataClass.new()
    $duplicate.fromObject($entity.toObject())
    $duplicate[$dataClass.getInfo().primaryKey]:=Null //reset the primary key
    $status:=$duplicate.save()
 End for each

.getRemoteContextAttributes()

Histórico

Versão	Mudanças
v19R5	Adicionado

.getRemoteContextAttributes() : Text

Parâmetros	Tipo		Descrição
result	Text	<-	Atributos de contexto conectados à seleção de entidade, separados por uma vírgula

Modo avançado: Esta função destina-se a programadores que necessitem personalizar as características padrão ORDA para configurações específicas. Na maioria dos casos, não necessitará de o utilizar.

Descrição

A função .getRemoteContextAttributes() retorna informação sobre o contexto de otimização usados pela seleção de entidade.

Se não houver optimization context para a seleção de entidade, a função retorna um Texto vazio.

Exemplo

var $ds : 4D.DataStoreImplementation
var $persons : cs.PersonsSelection
var $p : cs.PersonsEntity

var $info : Text
var $text : Text

$ds:=Open datastore(New object("hostname"; "www.myserver.com"); "myDS")

$persons:=$ds.Persons.all()
$text:=""
For each ($p; $persons)
    $text:=$p.firstname+" lives in "+$p.address.city+" / "
End for each

$info:=$persons.getRemoteContextAttributes()
//$info = "firstname,address,address.city"

Veja também

Entity.getRemoteContextAttributes()
.clearAllRemoteContexts()
.getRemoteContextInfo()
.getAllRemoteContexts()
.setRemoteContextInfo()

.isAlterable()

Histórico

Versão	Mudanças
v18 R5	Adicionado

.isAlterable() : Boolean

Parâmetros	Tipo		Descrição
Resultados	Booleano	<-	True se a seleção de entidades for alterável, senão False

Descrição

The .isAlterable() function returns True if the entity selection is alterablee False se a seleção de entidade não for alterável.

Para mais informação, consulte a seção Entity selections compartilháveis ou modificáveis.

Exemplo

Vai mostrar Form.products em uma list box para que o usuário possaa adicionar novos produtos. Se quiser ter certeza que é alterável para que o usuário possa adicionar novos produtos sem erro:

If (Not(Form.products.isAlterable()))
    Form.products:=Form.products.copy()
End if
...
Form.products.add(Form.product)

.isOrdered()

Histórico

Versão	Mudanças
v17	Adicionado

.isOrdered() : Boolean

Parâmetros	Tipo		Descrição
Resultados	Booleano	<-	True se a seleção de entidade for ordenada, senão False

Descrição

A função .isOrdered() returns True if the entity selection is orderede False se não for ordenada

Esta função não modifica a seleção de entidades original.

Para mais informação, consulte Entity selection ordenadas ou desordenadas.

Exemplo

 var $employees : cs.EmployeeSelection
 var $employee : cs.EmployeeEntity
 var $isOrdered : Boolean
 $employees:=ds.Employee.newSelection(dk keep ordered)
 $employee:=ds.Employee.get(714) // Obtém a entidade com chave primaria 714

  //Em uma entity selection ordenada, podemos adicionar a mesma entidade várias vezes (os duplicados se mantém)
 $employees.add($employee)
 $employees.add($employee)
 $employees.add($employee)

 $isOrdered:=$employees.isOrdered()
 If($isOrdered)
    ALERT("The entity selection is ordered and contains "+String($employees.length)+" employees")
 End if

.last()

Histórico

Versão	Mudanças
v17	Adicionado

.last() : 4D. Entity

Parâmetros	Tipo		Descrição
Resultados	4D. Entity	<-	Referência à última entidade da seleção de entidade (Null se seleção de entidade vazia)

Descrição

A função .last() returns a reference to the entity in last position of the entity selection.

O resultado desta função é similar a:

 $entity:=$entitySel[length-1]

Se a entity selection estiver vazia, a função devolve Null.

Exemplo

 var $entitySelection : cs. EmpSelection
 var $entity : cs. EmpEntity
 $entitySelection:=ds. Emp.query("salary < :1";50000)
 If($entitySelection.length#0)
    $entity:=$entitySelection.last()
 End if

.length

Histórico

Versão	Mudanças
v17	Adicionado

.length : Integer

Descrição

A propriedade .length retorna o número de entidades na seleção de entidade. Summary -->devolve o número de entidades na entity selection com um valor não null em attributePath.

As entity selections sempre têm uma propriedade .length.

Para saber o número total de entidades em uma dataclasse, é recomendado usar a função getCount() que é mais otimizada que a expressão ds.myClass.all().length.

Exemplo

 var $vSize : Integer
 $vSize:=ds. Employee.query("gender = :1";"male").length
 ALERT(String(vSize)+" male employees found.")

.max()

Histórico

Versão	Mudanças
v17	Adicionado
v18 R6	Retorna indefinido se uma seleção de entidade for vazia

.max( attributePath : Text ) : any

Parâmetros	Tipo		Descrição
attributePath	Text	->	Rota do atributo que se utilizará para o cálculo
Resultados	any	<-	Maior valor do atributo

Descrição

A função .max() retorna o valor mais alto (ou máximo) entre todos os valores de attributePath na seleção de entidade. Summary -->combines the entity selection with the entity or entitySelection parameter using the logical (not exclusive) OR operator; it returns a new, unordered entity selection that contains all the entities from the entity selection and the parameter.

Se passar em attributePath uma rota a uma propriedade de objeto que contenha diferentes tipos de valores, a função .max() devolverá o valor máximo dentro do primeiro tipo escalar na ordem da lista de tipos 4D como padrão (ver a descrição de .sort()).

.max() returns undefined se a entity selection estiver vazia ou attributePath não for encontrado no atributo de objeto.

Um erro é retornado se:

attributePath é um atributo relativo,
attributePath designa um atributo que não existir na dataclass da entity selection.

Exemplo

Se quisermos encontrar o maior salário entre as funcionárias mulheres:

 var $sel : cs. EmpSelection
 var $maxSalary : Real
 $sel:=ds. Employee.query("gender = :1";"female")
 $maxSalary:=$sel.max("salary")

.min()

Histórico

Versão	Mudanças
v17	Adicionado
v18 R6	Retorna indefinido se uma seleção de entidade for vazia

.min( attributePath : Text ) : any

Parâmetros	Tipo		Descrição
attributePath	Text	->	Rota do atributo que se utilizará para o cálculo
Resultados	any	<-	Menor valor do atributo

Descrição

A função .min() retorna o menor valor (mínimo) entre todos os valores de attributePath na seleção de entidade. Summary -->excludes from the entity selection to which it is applied the entity or the entities of entitySelection and returns the resulting entity selection.

Se passar em attributePath uma rota a uma propriedade objeto que contenha diferentes tipos de valores, a função .min() devolverá o valor mínimo dentro do primeiro tipo de valor escalar na ordem da lista de tipos (ver a descrição de .sort()).

.min() retorna undefined se a seleção entidade for vazia ou se attributePath não for encontrado no atributo objeto.

Um erro é retornado se:

attributePath é um atributo relativo,
attributePath designa um atributo que não existir na dataclass da entity selection.

Exemplo

Neste exemplo, se quisermos encontrar o menor salário entre todos os funcionários mulheres:

 var $sel : cs. EmpSelection
 var $minSalary : Real
 $sel:=ds. Employee.query("gender = :1";"female")
 $minSalary:=$sel.min("salary")

.minus()

Histórico

Versão	Mudanças
v19 R7	Suporte do parâmetro keepOrder
v17	Adicionado

.minus( entity : 4D.Entity { ; keepOrder : Integer } ) : 4D.EntitySelection
.minus( entitySelection : 4D.EntitySelection { ; keepOrder : Integer } ) : 4D.EntitySelection

Parâmetros	Tipo		Descrição
entity	4D. Entity	->	Entidade a substrair
entitySelection	4D. EntitySelection	->	seleção de entidade a subtrair
keepOrder	Integer	->	`dk keep ordered` (inteiro) para manter a ordem inicial na seleção de entidade resultado
Resultados	4D. EntitySelection	<-	Nova seleção de entidade ou uma nova referência na seleção entidade existente.

Descrição

A função .minus() excludes from the entity selection to which it is applied the entity or the entities of entitySelection and returns the resulting entity selection.

Se passar entity como parâmetro, a função cria uma nova seleção de entidade sem entity (se entity pertencer à seleção de entidade). Se entity não for incluída na seleção de entidade original, uma nova referência para a seleção de entidade é retornada.
Se passar entitySelection como parâmetro, a função retorna uma seleção de entidade contendo as entidades que pertencem à seleção de entidade original sem as entidades que pertencem a entitySelection. > Pode comparar entity selections ordenadas ou desordenadas.

Como padrão, se omitir o parâmetro keepOrder , a seleção de entidade resultado não é ordenada. Se quiser manter a ordem da seleção de entidade original (por exemplo se quiser reutilizar a seleção de entidade em uma interface de usuário) passe a constante dk keep ordered em keepOrder. Neste caso, o resultado é uma seleção de entidade ordenada e a ordem da seleção de entidade inicial é mantida

nota

Se passar dk keep ordered em keepOrder e removida entitySelection contém entidades duplicadas na seleção de entidade original, todas as ocorrências da duplicada são removidas.

Se a seleção de entidade original ou tanto a seleção de entidade quanto o parâmetro entitySelection vazios e uma seleção de entidade vazia é retornada.

Se entitySelection estiver vazia ou se entity for Null, uma nova referência à seleção de entidade original for retornada.

Se a entity selection inicial e o parâmetro não forem relacionados com a mesma dataclass, se produz um erro.

Exemplo 1

 EmployeeSelection
 $employees:=ds.Employee.query("firstName=:1";"S@")
 $notDropped:=$employees.drop() // $notDropped for uma entity selection que contém todas as entidades não suprimidas
 If($notDropped.length=0) //A ação de eliminação for exitosa, todas as entidades foram eliminadas
    ALERT("You have dropped "+String($employees.length)+" employees") //A seleção de entidades eliminada permanece na memoria
 Else
    ALERT("Problem during drop, try later")
 End if var $employees; $notDropped : cs.

Exemplo 2

Se quisermos ter uma seleção de empregados mulheres que se chamam "Jones" que vivem em Nova York:

 var $sel1; $sel2; $sel3 : cs. EmployeeSelection
 $sel1:=ds. Employee.query("name =:1";"Jones")
 $sel2:=ds. Employee.query("city=:1";"New York")
 $sel3:=$sel1.and($sel2).minus(ds. Employee.query("gender='male'"))

Exemplo 3

Em uma interface de usuário se tivermos uma lista que exibe itens em uma ordem específica: Se o usuário selecionar itens na lista para remove-los, a ordem deve ser mantida quando refrescar a lista:

$listsel:=$listsel.minus($selectedItems; dk keep ordered)

.or()

Histórico

Versão	Mudanças
v17	Adicionado

.or( entity : 4D.Entity ) : 4D.EntitySelection
.or( entitySelection : 4D.EntitySelection ) : 4D.EntitySelection

Parâmetros	Tipo		Descrição
entity	4D. Entity	->	Entidade a intersectar
entitySelection	4D. EntitySelection	->	Entity selection a intersectar
Resultados	4D. EntitySelection	<-	Nova seleção de entidade ou nova referência para a seleção de entidade original

Descrição

A função .or() combines the entity selection with the entity or entitySelection parameter using the logical (not exclusive) OR operator; retorna uma nova seleção de entidade não ordenada que contenha todas as entidades da seleção de entidade e o parâmetro

Se passar como parâmetro entitySelection pode comparar seleções de entidade. Uma nova seleção de entidade que contenha só as entidades que são referenciadas em ambas as seleções sejam retornadas. Senão, uma nova seleção de entidade contém a seleção de entidade original e a entidade é retornada.
Se passar entitySelection como parâmetro, pode comparar seleções de entidade. Uma nova seleção de entidade contém as entidades pertencem à seleção de entidade original ou entitySelection é retornada (ou não é exclusivo, entidades referenciadas em ambas as seleções não forem duplicadas na seleção resultante).
Pode comparar entity selections ordenadas ou desordenadas. A seleção resultante é sempre desordenada.

Se a seleção de entidade original e o parâmetro entitySelection for vazio, uma seleção de entidade vazia é retornada. Se a seleção de entidade original for vazia, uma referência a entitySelection ou uma seleção de entidade contendo apenas entity será retornada.

Se entitySelection estiver vazia ou se entity for Null, uma nova referência à seleção de entidade original for retornada.

Se a entity selection inicial e o parâmetro não forem relacionados com a mesma dataclass, se produz um erro.

Exemplo 1

 var $employees1; $employees2; $result : cs. EmployeeSelection
 $employees1:=ds. Employee.query("lastName = :1";"H@") //Returns "Colin Hetrick","Grady Harness"
 $employees2:=ds. Employee.query("firstName = :1";"C@") //Returns "Colin Hetrick", "Cath Kidston"
 $result:=$employees1.or($employees2) //$result contains "Colin Hetrick", "Grady Harness","Cath Kidston"

Exemplo 2

 var $employees; $result : cs. EmployeeSelection
 var $employee : cs. EmployeeEntity
 $employees:=ds. Employee.query("lastName = :1";"H@") // Devuelve "Colin Hetrick","Grady Harness", "Sherlock Holmes"
 $employee:=ds. Employee.get(686) //a entidade com chave primária 686 não pertence a entity selection $employees 
  //Coincide com a funcionária "Mary Smith"

 $result:=$employees.or($employee) //$result contém "Colin Hetrick", "Grady Harness", "Sherlock Holmes", "Mary Smith"

.orderBy()

Histórico

Versão	Mudanças
v17	Adicionado

.orderBy( pathString : Text ) : 4D.EntitySelection
.orderBy( pathObjects : Collection ) : 4D.EntitySelection

Parâmetros	Tipo		Descrição
pathString	Text	->	Rota(s) de atributos e instruções de clasificação para a entity selection
pathObjects	Collection	->	Coleção de objetos criterio
Resultados	4D. EntitySelection	<-	Nova seleção de entidade em ordem especificada

Descrição

A função .orderBy() returns a new ordered entity selection containing all entities of the entity selection in the order specified by pathString or pathObjects criteria.

Este método não modifica a seleção de entidade original
Para saber mais sobre seleções de entidade, veja a seçãoOrdered or unordered entity selection.

Deve usar um parâmetro critério para definir como as entidades são ordenadas. Dois parâmetros diferentes são compatíveis:

pathString (Text) : Este parâmetro contém uma fórmula feita de rotas de atributo 1 a x (e opcionalmente) ordenação separado por vírgulas A sintaxe é:

"attributePath1 {desc or asc}, attributePath2 {desc or asc},..."

A ordem na qual os atributos forem passados determina a prioridade de ordenação das entidades. Como padrão, atributos são ordenados em ordem ascendente. Pode definir a ordem de clasificação de uma propriedade na string de critérios, separado da rota da propriedade por um só espaço: passe "asc" para ordenar em ordem ascendente ou "desc" em ordem descendente.

pathObjects (collection): cada elemento da coleção contém um objeto estruturado da seguinte maneira:

{
    "propertyPath": string,
    "descending": boolean
}

Como padrão, atributos são ordenados em ordem ascendente ("descendente" é false)

Pode adicionar quantos objetos quiser nos critérios da coleção.

Valores null são avaliados como menor que outros valores.

Exemplo

// ordenar por fórmula
 $sortedEntitySelection:=$entitySelection.orderBy("firstName asc, salary desc")
 $sortedEntitySelection:=$entitySelection.orderBy("firstName")

  // ordenar por colecção com ou sem ordenação
 $orderColl:=New collection
 $orderColl.push(New object("propertyPath";"firstName";"descending";False))
 $orderColl.push(New object("propertyPath";"salary";"descending";True))
 $sortedEntitySelection:=$entitySelection.orderBy($orderColl)

 $orderColl:=New collection
 $orderColl.push(New object("propertyPath";"manager.lastName"))
 $orderColl.push(New object("propertyPath";"salary"))
 $sortedEntitySelection:=$entitySelection.orderBy($orderColl)

.orderByFormula()

Histórico

Versão	Mudanças
v17 R6	Adicionado

.orderByFormula( formulaString : Text { ; sortOrder : Integer } { ; settings : Object} ) : 4D.EntitySelection
.orderByFormula( formulaObj : Object { ; sortOrder : Integer } { ; settings : Object} ) : 4D.EntitySelection

Parâmetros	Tipo		Descrição
formulaString	Text	->	Formula string
formulaObj	Objeto	->	Objecto fórmula
sortOrder	Integer	->	`dk ascending` (normal) ou `dk descending`
settings	Objeto	->	Parâmetros da fórmula
Resultados	4D. EntitySelection	<-	Nova seleção de entidade ordenada

Descrição

The .orderByFormula() function returns a new, ordered entity selection contendo todas as entidades da seleção de entidade na ordem definida através de formulaString ou formulaObj e, opcionalmente, os parâmetrossortOrder esettings.

Esta função não modifica a entity selection original.

Pode usar formulaString ou um parâmetro formulaObj:

formulaString: passa uma expressão 4D como "Year of(this.birthDate)".
formulaObj: passa um objeto fórmulada valida criado usando Formula ou Formula from string.

formulaString ouformulaObj é executado para cada entidade da seleção de entidade e seu resultado é usado para definir a posição da entidade na seleção de entidade retornada.. O resultado deve ser um tipo ordenavel (booleano, data, número, texto, hora, null).

Um resultado nullé sempre o menor valor.

Como padrão, se omitir o parâmetro keepOrder, a seleção de entidade resultado é ordenada de forma ascendente. Opcionalmente pode passar um dos valores abaixo no parâmetro sortOrder:

Constante	Value	Comentário
dk ascending	0	Ordem ascendente (padrão)
dk descending	1	Ordem descendente

Dentro de formulaString ou formulaObj, a entidade processada e seus atributos estão disponíveis através do comando This (por exemplo, This.lastName).

Pode passar parâmetro(s) à fórmula usando a propriedade (objecto) args do parâmetro settings: a fórmula recebe o objecto settings.args em $1.

Exemplo 1

Ordenar estudantes usando uma fórmula fornecida como texto:

 var $es1; $es2 : cs. StudentsSelection
 $es1:=ds. Students.query("nationality=:1";"French")
 $es2:=$es1.orderByFormula("length(this.lastname)") //ascending by default
 $es2:=$es1.orderByFormula("length(this.lastname)";dk descending)

Mesma ordem mas usando objeto fórmula:

 var $es1; $es2 : cs. StudentsSelection
 var $formula : Object
 $es1:=ds. Students.query("nationality=:1";"French")
 $formula:=Formula(Length(This.lastname))
 $es2:=$es1.orderByFormula($formula) // ascending by default
 $es2:=$es1.orderByFormula($formula;dk descending)

Exemplo 2

Uma fórmula é dada como um objecto de fórmula com parâmetros; settings.args objecto é recebido como $1 no método computeAverage.

Neste exemplo, o objeto campo "marks" em Students dataClass contém as notas de estudantes para cada tema. Um objeto fórmula é usado para computar a média das notas dos estudantes com coeficientes diferentes para schoolA e schoolB

 var $es1; $es2 : cs. StudentsSelection
 var $formula; $schoolA; $schoolB : Object
 $es1:=ds. Students.query("nationality=:1";"French")
 $formula:=Formula(computeAverage($1))

 $schoolA:=New object() //settings object
 $schoolA.args:=New object("english";1;"math";1;"history";1) // Coefficients to compute an average

  //Order students according to school A criteria
 $es2:=$es1.entitySelection.orderByFormula($formula;$schoolA)

 $schoolB:=New object() //settings object
 $schoolB.args:=New object("english";1;"math";2;"history";3) // Coefficients to compute an average

  //Order students according to school B criteria
 $es2:=$es1.entitySelection.orderByFormula($formula;dk descending;$schoolB)

  //
  // computeAverage method
  // -----------------------------
 #DECLARE ($coefList : Object) -> $result : Integer
 var $subject : Text
 var $average; $sum : Integer

 $average:=0
 $sum:=0

 For each($subject;$coefList)
    $sum:=$sum+$coefList[$subject]
 End for each

 For each($subject;This.marks)
    $average:=$average+(This.marks[$subject]*$coefList[$subject])
 End for each

 $result:=$average/$sum

.query()

Histórico

Versão	Mudanças
v17 R6	Soporte dos Parâmetros Formula
v17 R5	Suporte dos marcadores para os valores
v17	Adicionado

.query( queryString : Text { ; ...value : any } { ; querySettings : Object } ) : 4D. EntitySelection
.query( formula : Object { ; querySettings : Object } ) : 4D. EntitySelection

Parâmetros	Tipo		Descrição
queryString	Text	->	Criterios de pesquisa como string
formula	Objeto	->	Criterios de pesquisa como objeto fórmula
value	any	->	Valores a usar para placeholders indexados
querySettings	Objeto	->	Opções de pesquisa: parâmetros, atributos, args, allowFormulas, contexto, queryPath,queryPlan
Resultados	4D. EntitySelection	<-	Nova seleção de entidade feita de entidades da seleção de entidade que satisfazem o critério de pesquisa especificado em queryString ou formula

Descrição

A função .query() pesquisa por entidades que satisfazem o critério de pesquisa especificado em queryString ou formula e (opcionalmente) value(s) entre todas as entidades na seleção de entidade, and returns a new object of type EntitySelection containing all the entities that are found. Se aplica carregamento diferido/lazy loading.

Esta função não modifica a entity selection original.

Se não houver entidades correspondentes encontradas, uma EntitySelection vazia é retornada.

para informações detalhadas de como usar queryString, valuee querySettings, veja a descrição DataClass .query().

Como padrão se omitir order by em queryString, a seleção de entidade retornada é não ordenada. Note entretanto que em modo Cliente Servidor funciona como uma seleção de entidade ordenada (entidades são adicionadas no final da seleção)

Exemplo 1

 var $entitySelectionTemp : cs. EmployeeSelection
 $entitySelectionTemp:=ds. Employee.query("lastName = :1";"M@")
 Form.emps:=$entitySelectionTemp.query("manager.lastName = :1";"S@")

Exemplo 2

A maioria dos exemplos de pesquisa podem ser encontrados na página DataClass .query() .

Veja também

.query() para dataclass

.queryPath

Histórico

Versão	Mudanças
v17	Adicionado

.queryPath : Text

Descrição

A propriedade .queryPath contém uma descrição detalhada da pesquisa como foi realizada em 4D. Summary -->retorna una coleção que contenha os valores de attributePath extraídos da entity selection.

para saber mais veja o parágrafo querySettings parameter na página Dataclass.query().

.queryPlan

Histórico

Versão	Mudanças
v17	Adicionado

.queryPlan : Text

Descrição

A propriedade .queryPlan contém uma descrição detalhada da pesquisa antes da execução (ou seja, a pesquisa planejada). This property is available for EntitySelection objects generated through queries if the "queryPlan":true property was passed in the querySettings parameter of the .query() function.

para saber mais veja o parágrafo querySettings parameter na página Dataclass.query().

.refresh()

Histórico

Versão	Mudanças
v18 R3	Adicionado

.refresh()

Parâmetros	Tipo		Descrição
			Não exige nenhum parâmetro

Descrição

Esta função só funciona com datastore remota (cliente / servidor ou conexãoOpen datastore ).

A função .refresh() immediately "invalidates" the entity selection data in the local ORDA cache de forma que na próxima vez que 4D exige a seleção de entidade será recarregada da database.

Como padrão, a cache ORDA local é invaidade depois de 30 segundos. No contexto de aplicações cliente/servidor usando ORDA e a linguagem clássica, este método permite assegurar que a aplicação remota vai sempre funcionar com os últimos dados.

Exemplo 1

Neste exemplo, clássico e ORDA modifica os mesmos dados simultaneamente.

 //On a 4D remote

 var $selection : cs. StudentsSelection
 var $student : cs. StudentsEntity

 $selection:=ds. Students.query("lastname=:1";"Collins")
  //A primeira entidade é carregada na cache ORDA
 $student:=$selection.first()

  //Atualizar com clássico 4D, ORDA cache não está se
 QUERY([Students];[Students]lastname="Collins")
 [Students]lastname:="Colin"
 SAVE RECORD([Students])

  //pra obter a última versão a cache ORDA deve ser invalidada
 $selection.refresh()
  // Mesmo se cache não for expirada, a primeira entidade é carregada do disco
 $student:=$selection.first()

  //$student.lastname contains "Colin"

Exemplo 2

Uma list box exibe a seleção de entidade Form.students e vários clientes trabalham nele.

// Método de formulário:
 Case of
    :(Form event code=On Load)
       Form.students:=ds. Students.all()
 End case
  //
  //
  // Em client #1, o usuário carrega atualiza e salva a primeira entidade
  // Em client #2, o usuário carrega atualiza e salva a mesma entidade
  //
  //
  // Em client #1:
 Form.students.refresh() // Invalida a cache ORDA para a seleção de entidade Form.students
  // O conteúdo list box é atualizado na database com atuaização feita pelo  client #2

.selected()

Histórico

Versão	Mudanças
v19 R3	Adicionado

.selected( selectedEntities : 4D. EntitySelection ) : Object

Parâmetros	Tipo		Descrição
selectedEntities	4D. EntitySelection	->	Seleção de entidade com entidades para qual saber o ranking da seleção de entidade
Resultados	Objeto	<-	Intervalos da seleção de entidade da seleção de entidade

Descrição

A função .selected() retorna um objeto descrevendo a posição da selectedEntities na seleção de entidade original.

Esta função não modifica a entity selection original.

Passe o parâmetro selectedEntities uma seleção de entidade contendo entidades para qual quiser saber a posição na seleção de entidade original. selectedEntities deve ser uma seleção de entidade pertencendo a mesma dataclass que a seleção de entidade original, senão acontece um erro 1587 - "The entity selection comes from an incompatible dataclass" .

Resultados

O objeto retornado contém as propriedades abaixo:

Propriedade	Tipo	Descrição
ranges	Collection	Coleção de objetos intervalos
ranges[].start	Integer	Primeiro indice de entidade do intervalo
ranges[].end	Integer	Último indice de entidade no intervalo.

Se uma propriedade ranges conter uma única entidade, start = end. Indice começa em 0

A função retorna uma coleção vazia da propriedade ranges se a seleção de entidade original ou a seleção de entidade é vazia selectedEntities.

Exemplo

var $invoices; $cashSel; $creditSel : cs. Invoices
var $result1; $result2 : Object

$invoices:=ds. Invoices.all()

$cashSelection:=ds. Invoices.query("payment = :1"; "Cash")
$creditSel:=ds. Invoices.query("payment IN :1"; New collection("Cash"; "Credit Card"))

$result1:=$invoices.selected($cashSelection)
$result2:=$invoices.selected($creditSel)

//$result1 = {ranges:[{start:0;end:0},{start:3;end:3},{start:6;end:6}]}
//$result2 = {ranges:[{start:0;end:1},{start:3;end:4},{start:6;end:7}]}

.slice()

Histórico

Versão	Mudanças
v17	Adicionado

.slice( startFrom : Integer { ; end : Integer } ) : 4D. EntitySelection

Parâmetros	Tipo		Descrição
startFrom	Integer	->	Indice para iniciar a operação em (incluido)
end	Integer	->	Final do índice (não incluído)
Resultados	4D. EntitySelection	<-	Nova seleção de entidade contendo entidades slices (cópia superficial)

Descrição

A função .slice() retorna uma porção da seleção de entidade em uma nova seleção de entidade, selected from the startFrom index to the end index (end is not included) or to the last entity of the entity selection. Summary --> devolve uma cópia da entity selection original.

Esta função não modifica a entity selection original.

A seleção de entidade retornada contém as entidades especificadas por startFrom e todas as entidades subsequentes até, mas não incluindo, a entidade especificada por end. Se só o parâmetro startFrom for especificado, a entidade de seleção retornada contém todas as entidades de startFrom à última entidade da seleção de entidade original.

Se startFrom < 0, é recalculada como startFrom:=startFrom+length (é considerada como o offset do final da entidade de seleção). Se o valor calculado < 0, index será estabelecido como 0.
Se startFrom >= length, a função retorna uma seleção vazia de entidade.
Se end < 0, é recalculada como end:=end+length.
Se end < startFrom (valores passados ou calculados), o método não faz nada.

Se a seleção de entidade contém entidades que foram abandonadas, também serão retornadas.

Exemplo 1

Se quiser obter uma seleção das primeiras 9 entidades da seleção de entidade:

var $sel; $sliced : cs. EmployeeSelection
$sel:=ds. Employee.query("salary > :1";50000)
$sliced:=$sel.slice(0;9) //

Exemplo 2

Assuming we have ds. Employee.all().length = 10

var $slice : cs. EmployeeSelection
$slice:=ds. Employee.all().slice(-1;-2) //tries to return entities from index 9 to 8, but since 9 > 8, returns an empty entity selection

.sum()

Histórico

Versão	Mudanças
v17	Adicionado

.sum( attributePath : Text ) : Real

Parâmetros	Tipo		Descrição
attributePath	Text	->	Rota do atributo que se utilizará para o cálculo
Resultados	Real	<-	Soma dos valores da seleção de entidade

Descrição

A função .sum() returns the sum for all attributePath values in the entity selection.

.sum() retorna 0 se a seleção de entidade for vazia.

A soma só pode ser feita em valores do tipo de número. Se o atributo attributePath for uma propriedade objecto, apenas valores numéricos são tidos em conta para o cálculo (outros tipos de valores são ignorados). Neste caso, se attributePath conduz a uma propriedade que não existe no objecto ou não contém quaisquer valores numéricos, .sum() retorna 0.

Um erro é retornado se:

attributePath não é um atributo numérico nem um atributo de objecto,
attributePath é um atributo relativo,
attributePath não se encontra na classe de dados da entity selection.

Exemplo

var $sel : cs. EmployeeSelection
var $sum : Real

$sel:=ds. Employee.query("salary < :1";20000)
$sum:=$sel.sum("salary")

.toCollection()

Histórico

Versão	Mudanças
v17	Adicionado

.toCollection( { options : Integer { ; begin : Integer { ; howMany : Integer } } ) : Collection
.toCollection( filterString : Text {; options : Integer { ; begin : Integer { ; howMany : Integer }}} ) : Collection
.toCollection( filterCol : Collection {; options : Integer { ; begin : Integer { ; howMany : Integer }}} ) : Collection

Parâmetros	Tipo		Descrição
filterString	Text	->	String com caminho(s) de atributo(s) de entidade a extrair
filterCol	Collection	->	Coleção de caminho(s) de atributo(s) de entidade a extrair
options	Integer	->	`dk com chave primária`: adiciona a chave primária `dk com selo`: adiciona o selo
begin	Integer	->	Designa o índice inicial
howMany	Integer	->	Número de entidades a extrair
Resultados	Collection	<-	Colecção de objectos contendo atributos e valores de selecção de entidades

Descrição

The .toCollection() function creates and returns a collection where each element is an object containing a set of properties and values correspondentes aos nomes e valores dos atributos para a selecção da entidade.

Se nenhum parâmetro de filtro for passado ou se o primeiro parâmetro contiver uma cadeia vazia ou "*", todos os atributos são extraídos. Atributos com tipo propriedade como "relatedEntity" são extraídos com a forma simples: um objecto com propriedade _KEY (chave primária). Atributos com propriedade tipo como "Entidades relacionadas" não são extraídos.

Ou, pode designar os atributos da entidade a extrair utilizando um parâmetro de filtro. Pode usar um destes dois filtros:

filterString - uma string com caminhos de propriedade separados por vírgulas: "propertyPath1, propertyPath2, ...".
filterCol - uma coleção de strings contendo caminhos de propriedade: ["propertyPath1", "propertyPath2",...

Se for especificado um filtro para um atributo do tipo relatedEntity :

propertyPath = "relatedEntity" -> é extraído de forma simples
propertyPath = "relatedEntity.*" -> todas as propriedades foram extraídas
propertyPath = "relatedEntity.propertyName1, relatedEntity.propertyName2, ..." -> só se extraem essas propriedades

Se for especificado um filtro para um atributo do tipo relatedEntities :

propertyPath = "relatedEntities.*" -> se extraem todas as propriedades
propertyPath = "relatedEntities.propertyName1, relatedEntities.propertyName2, ..." -> só se extraem essas propriedades

No parâmetro opções , pode passar os seletores dk com chave primária e/ou dk with stamp para adicionar as chaves primárias da entidade e/ou carimbos nos objectos extraídos.

Alerta

Se utilizar outro atributo que não a chave primária como o atributo Um numa relação, o valor deste atributo será escrito na propriedade "__KEY". Tenha em mente que é recomendado usar a chave primária como um atributo nas suas relações, especialmente quando usa funções .toCollection() e .fromCollection().

O parâmetro start permite indicar o índice inicial das entidades a extrair. Pode passar qualquer valor entre 0 e o comprimento-1 da selecção da entidade.

O parâmetro howMany permite especificar o número de entidades a extrair, começando com o especificado em begin. As entidades abandonadas não são devolvidas, mas são tidas em conta de acordo com howMany. Por exemplo, se howMany= 3 e houver 1 entidade abandonada, apenas 2 entidades são extraídas.

Se howMany > comprimento da selecção da entidade, o método retorna (comprimento - início) objectos.

Uma colecção vazia é devolvida se:

a selecção da entidade está vazia, ou
begin é maior do que a duração da selecção da entidade.

Exemplo 1

A estrutura abaixo será usada nos exemplos desta seção:

Exemplo sem filtro ou parâmetro de opções:

 var $employeesCollection : Collection
 var $employees : cs. EmployeeSelection

 $employeesCollection:=New collection
 $employees:=ds. Employee.all()
 $employeesCollection:=$employees.toCollection()

Retorna:

[
    {
        "ID": 416,
        "firstName": "Gregg",
        "lastName": "Wahl",
        "salary": 79100,
        "birthDate": "1963-02-01T00:00:00.000Z",
        "woman": false,
        "managerID": 412,
        "employerID": 20,
        "photo": "[object Picture]",
        "extra": null,
        "employer": {
            "__KEY": 20
        },
        "manager": {
            "__KEY": 412

        }
    },
    {
        "ID": 417,
        "firstName": "Irma",
        "lastName": "Durham",
        "salary": 47000,
        "birthDate": "1992-06-16T00:00:00.000Z",
        "woman": true,
        "managerID": 412,
        "employerID": 20,
        "photo": "[object Picture]",
        "extra": null,
        "employer": {
            "__KEY": 20
        },
        "manager": {
            "__KEY": 412
        }
    }
]

Exemplo 2

Exemplo com opções:

var $employeesCollection : Collection
var $employees : cs. EmployeeSelection

$employeesCollection:=New collection
$employees:=ds. Employee.all()
$employeesCollection:=$employees.toCollection("";dk with primary key+dk with stamp)

Retorna:

[
    {
        "__KEY": 416,
        "__STAMP": 1,
        "ID": 416,
        "firstName": "Gregg",
        "lastName": "Wahl",
        "salary": 79100,
        "birthDate": "1963-02-01T00:00:00.000Z",
        "woman": false,
        "managerID": 412,
        "employerID": 20,
        "photo": "[object Picture]",
        "extra": null,
        "employer": {
            "__KEY": 20
        },
        "manager": {
            "__KEY": 412
        }
    },
    {
        "__KEY": 417,
        "__STAMP": 1,
        "ID": 417,
        "firstName": "Irma",
        "lastName": "Durham",
        "salary": 47000,
        "birthDate": "1992-06-16T00:00:00.000Z",
        "woman": true,
        "managerID": 412,
        "employerID": 20,
        "photo": "[object Picture]",
        "extra": null,
        "employer": {
            "__KEY": 20
        },
        "manager": {
            "__KEY": 412
        }
    }]

Exemplo 3

Exemplo com fatiagem e filtragem nas propriedades:

var $employeesCollection; $filter : Collection
var $employees : cs.EmployeeSelection

$employeesCollection:=New collection
$filter:=New collection


$filter.push("firstName")
$filter.push("lastName")

$employees:=ds.Employee.all()
$employeesCollection:=$employees.toCollection($filter;0;0;2)

Retorna:

[
    {
        "firstName": "Gregg",
        "lastName": "Wahl"
    },
    {
        "firstName": "Irma",
        "lastName": "Durham"
    }
]

Exemplo 4

Exemplo com relatedEntity tipo com formulário simples:

var $employeesCollection : Collection
$employeesCollection:=New collection
$employeesCollection:=$employees.toCollection("firstName,lastName,employer")

retorna:

[
    {
        "firstName": "Gregg",
        "lastName": "Wahl",
        "employer": {
            "__KEY": 20
        }
    },
    {
        "firstName": "Irma",
        "lastName": "Durham",
        "employer": {
            "__KEY": 20
        }
    },
    {
        "firstName": "Lorena",
        "lastName": "Boothe",
        "employer": {
            "__KEY": 20
        }
    }
   ]

Exemplo 5

Exemplo com parâmetro filterCol:

var $employeesCollection; $coll : Collection
$employeesCollection:=New collection
$coll:=New collection("firstName";"lastName")
$employeesCollection:=$employees.toCollection($coll)

Retorna:

[
    {
        "firstName": "Joanna",
        "lastName": "Cabrera"
    },
    {
        "firstName": "Alexandra",
        "lastName": "Coleman"
    }
]

Exemplo 6

Exemplo com extracção de todas as propriedades de relatedEntity:

var $employeesCollection; $coll : Collection
$employeesCollection:=New collection
$coll:=New collection
$coll.push("firstName")
$coll.push("lastName")
$coll.push("employer.*")
$employeesCollection:=$employees.toCollection($coll)

Retorna:

[
    {
        "firstName": "Gregg",
        "lastName": "Wahl",
        "employer": {
            "ID": 20,
            "name": "Irma",
        "lastName": "Durham",
        "employer": {
            "ID": 20,
            "name": "Lorena",
        "lastName": "Boothe",
        "employer": {
            "ID": 20,
            "name": "India Astral Secretary",
            "creationDate": "1984-08-25T00:00:00.000Z",
            "revenues": 12000000,
            "extra": null
        }
    }
  ]

Exemplo 7

Exemplo com extracção de algumas propriedades de uma relatedEntity:

var $employeesCollection : Collection
$employeesCollection:=New collection
$employeesCollection:=$employees.toCollection("firstName, lastName, employer.name")

[
    {
        "firstName": "Gregg",
        "lastName": "Wahl",

        "employer": {
            "name": "Irma",
        "lastName": "Durham",
        "employer": {
            "name": "Lorena",
        "lastName": "Boothe",
        "employer": {
            "name": "India Astral Secretary"
        }
    }]

Exemplo 8

Exemplo com extracção de algumas propriedades de relatedEntities:

 var $employeesCollection : Collection
 $employeesCollection:=New collection
 $employeesCollection:=$employees.toCollection("firstName, lastName, directReports.firstName")

Retorna:

[
    {
        "firstName": "Gregg",
        "lastName": "Wahl",
        "directReports": []
    },
    {
        "firstName": "Mike",
        "lastName": "Phan",
        "directReports": [
            {
                "firstName": "Gary"
            },
            {
                "firstName": "Sadie"
            },
            {
                "firstName": "Christie"
            }
        ]
    },
    {
        "firstName": "Gary",

        "lastName": "Reichert",
        "directReports": [
            {
                "firstName": "Rex"
            },
            {
                "firstName": "Jenny"
            },
            {
                "firstName": "Lowell"
            }
        ]
    }]

Exemplo 9

Exemplo com extração de todas as propriedades de relatedEntities:

var $employeesCollection : Collection
$employeesCollection:=New collection
$employeesCollection:=$employees.toCollection("firstName, lastName, directReports.*")

[
    {
        "firstName": "Gregg",
        "lastName": "Wahl",
        "directReports": []
    },    
    {
        "firstName": "Mike",
        "lastName": "Phan",
        "directReports": [
            {
                "ID": 425,
                "firstName": "Gary",
                "lastName": "Reichert",
                "salary": 65800,
                "birthDate": "1957-12-23T00:00:00.000Z",
                "woman": false,
                "managerID": 424,
                "employerID": 21,
                "photo": "[object Picture]",
                "extra": null,
                "employer": {
                    "__KEY": 21
                },
                "manager": {
                    "__KEY": 424
                }
            },
            {
                "ID": 426,
                "firstName": "Sadie",
                "lastName": "Gallant",
                "salary": 35200,
                "birthDate": "2022-01-03T00:00:00.000Z",
                "woman": true,
                "managerID": 424,
                "employerID": 21,
                "photo": "[object Picture]",
                "extra": null,
                "employer": {
                    "__KEY": 21
                },
                "manager": {
                    "__KEY": 424
                }
            }
                   ]
    },
    {
        "firstName": "Gary",
        "lastName": "Reichert",
        "directReports": [
            {
                "ID": 428,
                "firstName": "Rex",
                "lastName": "Chance",
                "salary": 71600,
                "birthDate": "1968-08-09T00:00:00.000Z",
                "woman": false,

                "managerID": 425,
                "employerID": 21,
                "photo": "[object Picture]",
                "extra": null,
                "employer": {
                    "__KEY": 21
                },
                "manager": {
                    "__KEY": 425
                }
            },
            {
                "ID": 429,
                "firstName": "Jenny",
                "lastName": "Parks",
                "salary": 51300,
                "birthDate": "1984-05-25T00:00:00.000Z",
                "woman": true,
                "managerID": 425,
                "employerID": 21,
                "photo": "[object Picture]",
                "extra": null,
                "employer": {
                    "__KEY": 21
                },
                "manager": {
                    "__KEY": 425
                }
            }
           ]
 }
]

Resumo​

Criar uma seleção de entidades (entity selection)​

Descrição​

Exemplo​

Veja também​

USE ENTITY SELECTION​

Descrição​

Exemplo​

[index]​

Descrição​

Exemplo​

.attributeName​

Descrição​

Exemplo 1​

Exemplo 2​

Exemplo 3​

.add()​

Descrição​

Exemplo 1​

Exemplo 2​

Exemplo 3​

.and()​

Descrição​

Exemplo 1​

Exemplo 2​

.average()​

Descrição​

Exemplo​

.contains()​

Descrição​

Exemplo​

.count()​

Descrição​

Exemplo​

.copy()​

Descrição​

Exemplo​

.distinct()​

Descrição​

Exemplos​

.drop()​

Descrição​

Exemplo​

.extract()​

Descrição​

Exemplo​

.first()​

Descrição​

Exemplo​

.getDataClass()​

Descrição​

Exemplo​

.getRemoteContextAttributes()​

Descrição​

Exemplo​

Veja também​

.isAlterable()​

Descrição​

Exemplo​

.isOrdered()​

Descrição​

Exemplo​

.last()​

Descrição​

Exemplo​

.length​

Descrição​

Exemplo​

.max()​

Descrição​

Exemplo​

.min()​

Descrição​

Exemplo​

.minus()​

Descrição​

Exemplo 1​

Exemplo 2​

Exemplo 3​

.or()​

Resumo

Criar uma seleção de entidades (entity selection)

Descrição

Exemplo

Veja também

USE ENTITY SELECTION

Descrição

Exemplo

[index]

Descrição

Exemplo

.attributeName

Descrição

Exemplo 1

Exemplo 2

Exemplo 3

.add()

Descrição

Exemplo 1

Exemplo 2

Exemplo 3

.and()

Descrição

Exemplo 1

Exemplo 2

.average()

Descrição

Exemplo

.contains()

Descrição

Exemplo

.count()

Descrição

Exemplo

.copy()

Descrição

Exemplo

.distinct()

Descrição

Exemplos

.drop()

Descrição

Exemplo

.extract()

Descrição

Exemplo

.first()

Descrição

Exemplo

.getDataClass()

Descrição

Exemplo

.getRemoteContextAttributes()

Descrição

Exemplo

Veja também

.isAlterable()

Descrição

Exemplo

.isOrdered()

Descrição

Exemplo

.last()

Descrição

Exemplo

.length

Descrição

Exemplo

.max()

Descrição

Exemplo

.min()

Descrição

Exemplo

.minus()

Descrição

Exemplo 1

Exemplo 2

Exemplo 3

.or()