Edit

ZIPArchive

Um arquivo 4D Zip é um objetoFile ou Folder contendo um ou mais arquivos ou pastas, que são comprimidos para ter um tamanho menor que o original. Esses arquivos são criados com uma extensão ".zip" e podem ser usados para poupar espaço em disco ou transferir arquivos via meios que tenham limitações de tamanho (por exemplo, um email ou por uma rede).

• Pode criar um arquivo 4D ZIP com o comando ZIP Create archive.
• As instâncias ZIPFile e ZIPFolder de 4D estão disponíveis vai a propriedade root (ZIPFolder) do objeto retornado pelo comando ZIP Read archive.

Exemplo

Para recuperar e ver os conteúdos de um objeto ZIP file:

var $path; $archive : 4D.File
var $zipFile : 4D.ZipFile
var $zipFolder : 4D.ZipFolder
var $txt : Text

$path:=Folder(fk desktop folder).file("MyDocs/Archive.zip")
$archive:=ZIP Read archive($path)
$zipFolder:=$archive.root // armazenar a pasta principal zip
$zipFile:=$zipFolder.files()[0] //ler o primeiro arquivo zipado

If($zipFile.extension=".txt")
    $txt:=$zipFile.getText()
End if

Resumo

.root : 4D.ZipFolder     a virtual folder providing access to the contents of the ZIP archive

ZIP Create archive

Histórico

Versão	Mudanças
v18	Adicionado

ZIP Create archive ( fileToZip : 4D.File ; destinationFile : 4D.File ) : Object
ZIP Create archive ( folderToZip : 4D.Folder ; destinationFile : 4D.File { ; options : Integer }) : Object
ZIP Create archive ( zipStructure : Object ; destinationFile : 4D.File ) : Object

Parâmetros	Tipo		Descrição
fileToZip	4D.File	->	Objeto File ou Folder a comprimir
folderToZip	4D.Folder	->	Objeto File ou Folder a comprimir
zipStructure	Objeto	->	Objeto File ou Folder a comprimir
destinationFile	4D.File	->	Arquivo destino para o arquivo
options	Integer	->	folderToZip option: ZIP Without enclosing folder
Resultados	Objeto	<-	Objeto de estado

Descrição

O comando ZIP Create archive cria um arquivo compactado ZIP e retorna o estado da operação.

Pode passar um objeto 4D.File, 4D.Folder, ou um objeto de estrutura zip como primeiro parâmetro:

• fileToZip: simplesmente passar 4D.File para compactar.

• folderToZip: Passa um 4D.Folder para compactar. In this case, the options parameter allows you to compress only the contents of the folder (i.e., exclude the enclosing folder). By default, ZIP Create archive will compress the folder and its contents, so that the decompressing operation will recreate a folder. If you want the decompressing operation to restore only the contents of the folder, pass the ZIP Without enclosing folder constant in the options parameter.

• zipStructure: You pass an object describing the ZIP archive object. The following properties are available to define the structure:

• a collection of 4D.File or 4D.Folder objects or
• a collection of objects with the following properties:

Property	Type	Description
source	4D.File or 4D.Folder <td> File or Folder </td></tr> <tr> <td> destination </td> <td> Texto </td> <td> (optional) - Specify a relative filepath to change the organization of the contents of the archive </td> </tr> <tr> <td> option </td> <td> number </td> <td> (optional) - `ZIP Ignore invisible files` or 0 to compress all of the file </td> </tr></table></html>
callback	4D.Function	A callback formula that will receive the compression progress (0 - 100) in $1.

In the destinationFile parameter, pass a 4D.File object describing the ZIP archive to create (name, location, etc.). It is advised to use the ".zip" extension if you want the ZIP archive to be processed automatically by any software.

Once an archive is created, you can use the ZIP Read archive command to access it.

Status object

The returned status object contains the following properties:

Property	Type	Description
statusText	Texto	Error message (if any): Cannot open ZIP archive Cannot create ZIP archive Password is required for encryption
status	Integer	Status code
success	Booleano	True if archive created successfully, else false

Example 1

To compress a 4D.File:

 var $file; $destination : 4D.File
 var $status : Object

 $destination:=Folder(fk desktop folder).file("MyDocs/file.zip")
 $file:=Folder(fk desktop folder).file("MyDocs/text.txt")

 $status:=ZIP Create archive($file;$destination)

Example 2

To compress a 4D.Folder without the folder itself:

 var $folder : 4D.Folder
 var $destination : 4D.File
 var $status : Object

 $destination:=Folder(fk desktop folder).file("MyDocs/Images.zip")
 $folder:=Folder(fk desktop folder).folder("MyDocs/Images")

 $status:=ZIP Create archive($folder;$destination;ZIP Without enclosing folder)

Exemplo 3

To compress a ZIP archive structure with a password and progress bar:

 var $destination : 4D.File
 var $zip;$status : Object
 var progID : Integer

 $destination:=Folder(fk desktop folder).file("MyDocs/Archive.zip")

 $zip:=New object
 $zip.files:=Folder(fk desktop folder).folder("MyDocs/Resources").folders()
 $zip.password:="password"
 $zip.callback:=Formula(myFormulaCompressingMethod($1))

 progID:=Progress New //we use the 4D Progress component

 $status:=ZIP Create archive($zip;$destination)

 Progress QUIT(progID)

myFormulaCompressingMethod:

 var $1 : Integer
 Progress SET PROGRESS(progID;Num($1/100))

Exemplo 4

You want to pass a collection of folders and files to compress to the zipStructure object:

 var $destination : 4D.File
 var $zip;$err : Object
 $zip:=New object
 $zip.files:=New collection
 $zip.files.push(New object("source";Folder(fk desktop folder).file("Tests/text.txt")))
 $zip.files.push(New object("source";Folder(fk desktop folder).file("Tests/text2.txt")))
 $zip.files.push(New object("source";Folder(fk desktop folder).file("Images/image.png")))

 $destination:=Folder(fk desktop folder).file("file.zip")
 $err:=ZIP Create archive($zip;$destination)

ZIP Read archive

Histórico

Versão	Mudanças
v18	Adicionado

ZIP Read archive ( zipFile : 4D.File { ; password : Text }) : 4D.ZipArchive

Parameter	Type		Description
zipFile	4D.File	->	Zip archive file
password	Texto	->	ZIP archive password if any
Result	4D.ZipArchive	<-	Archive object

Description

The ZIP Read archive command retrieves the contents of zipFile and returns it as a 4D.ZipArchive object.

This command does not uncompress the ZIP archive, it only provides a view of its contents. To extract the contents of an archive, you need to use methods such as file.copyTo() or folder.copyTo().

Pass a 4D.File object referencing the compressed ZIP archive in the zipFile parameter. The target archive file will be opened until the ZIP Read archive has finished executing and all contents/references have been extracted/released, then it will be closed automatically.

If the zipFile is password protected, you need to use the optional password parameter to provide a password. If a password is required but not passed when trying to read the contents of the archive, an error is generated.

Archive object

The returned 4D.ZipArchive object contains a single root property whose value is a 4D.ZipFolder object. This folder describes the whole contents of the ZIP archive.

Exemplo

To retrieve and view the contents of a ZIP file object:

 var $archive : 4D.ZipArchive
 var $path : 4D.File

 $path:=Folder(fk desktop folder).file("MyDocs/Archive.zip")
 $archive:=ZIP Read archive($path)

To retrieve the list of the files and folders in the archive:

 $folders:=$archive.root.folders()
 $files:=$archive.root.files()

To read the contents of a file without extracting it from the root folder:

 If($files[$i].extension=".txt")
    $txt:=$files[$i].getText()
 Else
    $blob:=$files[$i].getContent()
 End if

To extract from the root folder:

  //extract a file
 $folderResult:=$files[$i].copyTo(Folder(fk desktop folder).folder("MyDocs"))

  //extract all files
 $folderResult:=$archive.root.copyTo(Folder(fk desktop folder).folder("MyDocs"))

.root

.root : 4D.ZipFolder

Description

The .root property contains a virtual folder providing access to the contents of the ZIP archive.

The root folder and its contents can be manipulated with the ZipFile and ZipFolder functions and properties.

Essa propriedade éapenas leitura.