DIALOG

DIALOG ( {aTable ;} form {; formData}{; *} )

Parámetros	Tipo		Descripción
aTable	Tabla	→	Table owning the form or If omitted: default table or use of project form
form	Text, Object	→	Name (string) of table or project form, or a POSIX path (string) to a .json file describing the form, or an object describing the form
formData	Object	→	Datos a asociar al formulario
*	Operador	→	Usar el mismo proceso

Descripción

El comando DIALOG presenta el formulario al usuario, junto con (el) los parámetro(s) formData (opcional).

This command is designed to work with customized and advanced user interfaces based on forms. You can use it to display information coming from the database or other locations, or to provide data entry features. A diferencia de ADD RECORD o MODIFY RECORD, DIALOG le ofrece un control total sobre el formulario, su contenido y los botones de navegación y validación.

Este comando suele invocarse junto con el comando Open form window para mostrar formularios sofisticados, como se muestra en el siguiente ejemplo:

The DIALOG command can also be used instead of ALERT, CONFIRM or Request when the information to be presented or gathered is more complex than those commands can manage.

En el parámetro form, puede pasar:

• el nombre de un formulario (formulario proyecto o formulario tabla) a utilizar;
• the path (in POSIX syntax) to a valid .json file containing a description of the form to use;
• an object containing a description of the form to use.

Opcionalmente, puede pasar uno o varios parámetros al form utilizando un objeto "form data". Any properties of the form data object will then be available from within the form context through the Form command. For example, if you use a form data object containing {"version";"12"}, you will be able to get or set the value of the "version" property in the form by calling:

 $v:=Form.version //"12"
 Form.version:=13

To fill the "form data" object, you have two possibilities:

• usar el parámetro formData. Using a local variable for formData allows you to safely pass parameters to your forms, whatever the calling context. In particular, if the same form is called from different places in the same process, you will always be able to access its specific values by simply calling Form.myProperty. Moreover, since objects are passed by reference, if the user modifies a property value in the form, it will automatically be saved in the object itself.

• asociar una clase usuario al formulario, en cuyo caso 4D instanciará automáticamente un objeto de esta clase cuando se cargará el formulario. Las propiedades y funciones del objeto estarán automáticamente disponibles a través del objeto devuelto por Form. Puede escribir por ejemplo Form.myFunction().

nota

• El parámetro formData tiene prioridad sobre una clase de formulario (el objeto de clase no es instanciado si se pasa un parámetro formData).
• If you do not pass the formData parameter (or if you pass an undefined object) and no user class is associated to the form, DIALOG creates a new empty object bound to the form.

The dialog is closed by the user either with an "accept" action (triggered by the ak accept standard action, the Enter key, or the ACCEPT command), or with a "cancel" action (triggered by the ak cancel standard action, the Escape key, or the CANCEL command). An accept action will set the OK system variable to 1, while a cancel action will set OK to 0.

Tenga en cuenta que la validación no es igual al guardado: si el diálogo incluye campos, debe llamar explícitamente al comando SAVE RECORD para guardar cualquier dato que haya sido modificado.

If you pass the optional * parameter, the form is loaded and displayed in the last open window of the current process and the command finishes its execution while leaving the active form on the screen.
If you pass the optional * parameter, the form is loaded and displayed in the last open window of the current process and the command finishes its execution while leaving the active form on the screen.
If you pass the optional * parameter, the form is loaded and displayed in the last open window of the current process and the command finishes its execution while leaving the active form on the screen.
This form then reacts “normally” to user actions and is closed using a standard action or when 4D code related to the form (object method or form method) calls the CANCEL or ACCEPT command.
If you pass the optional * parameter, the form is loaded and displayed in the last open window of the current process and the command finishes its execution while leaving the active form on the screen.
If you pass the optional * parameter, the form is loaded and displayed in the last open window of the current process and the command finishes its execution while leaving the active form on the screen.
This form then reacts “normally” to user actions and is closed using a standard action or when 4D code related to the form (object method or form method) calls the CANCEL or ACCEPT command. Si el proceso actual termina, los formularios creados de este modo se cierran automáticamente del mismo modo que si se hubiera llamado a un comando CANCEL. This opening mode is particularly useful for displaying a floating palette with a document, without necessarily requiring another process.

Notas:

• Puede combinar el uso de la sintaxis DIALOG(form;*) con el comando CALL FORM para establecer la comunicación entre los formularios.
• You must create a window before calling the DIALOG(form;*) statement. It is not possible to use the current dialog window in the process nor the window created by default for each process. Otherwise, error -9909 is generated.
• When the * parameter is used, the window is closed automatically following a standard action or a call to the CANCEL or ACCEPT command. You do not have to manage the closing of the window itself.

Ejemplo 1

The following example can be used to create a tool palette:

  //Display tool palette
 $palette_window:=Open form window("tools";Palette form window)
 DIALOG("tools";*) //Give back the control immediately
  //Display main document windowl
 $document_window:=Open form window("doc";Plain form window)
 DIALOG("doc")

Ejemplo 2

In a form displaying the record of a person, a "Check children" button opens a dialog to verify/modify the names and ages of their children:

Note: The "Children" object field is represented only to show its structure for this example.

In the verification form, you have assigned some Form object properties to variables:

Here is the code for the "Check children" button:

 var $win;$n;$i : Integer
 var $save : Boolean
 ARRAY OBJECT($children;0)
 OB GET ARRAY([Person]Children;"children";$children) //get the children collection
 $save:=False //initialize the save variable
 
 $n:=Size of array($children)
 If($n>0)
    $win:=Open form window("Edit_Children";Movable form dialog box)
    SET WINDOW TITLE("Check children for "+[Person]Name)
    For($i;1;$n) //for each child
       DIALOG("Edit_Children";$children{$i}) //displays dialog filled with values
       If(OK=1) //the user clicked OK
          $save:=True
       End if
    End for
    If($save=True)
       [Person]Children:=[Person]Children //forces object field update
    End if
    CLOSE WINDOW($win)
 Else
    ALERT("No child to check.")
 End if

The form displays information for each child:

If values are edited and the OK button is clicked, the field is updated (the parent record must be saved afterwards).

Ejemplo 3

The following example uses the path to a .json form to display the records in an employee list:

 Open form window("/RESOURCES/OutputPersonnel.json";Plain form window)
 ALL RECORDS([Personnel])
 DIALOG("/RESOURCES/OutputPersonnel.json";*)

que muestra:

Ejemplo 4

The following example uses a .json file as an object and modifies a few properties:

 var $form : Object
 $form:=JSON Parse(Document to text(Get 4D folder(Current resources folder)+"OutputPersonnel.json"))
 $form.windowTitle:="The Avengers"
 $form.pages[1].objects.logo.picture:="/RESOURCES/Images/Avengers.png"
 $form.pages[1].objects.myListBox.borderStyle:="double"
 Open form window($form;Plain form window)
 DIALOG($form;*)

The altered form is displayed with the title, logo and border modified:

Variables y conjuntos sistema

After a call to DIALOG, if the dialog is accepted, OK is set to 1; if it is canceled, OK is set to 0.

Ver también

ACCEPT
ADD RECORD
CALL FORM
CANCEL
Form
Open window

Propiedades

Número de comando	40
Hilo seguro	✗
Modifica las variables	OK, error