Edit

ZIP Archive

A 4D ZIP archive is a `File` or `Folder` object containing one or more files or folders, which are compressed to be smaller than their original size. These archives are created with a ".zip" extension and can be used to save disk space or transfer files via mediums which may have size limitations (e.g., email or network).

• You create a 4D ZIP archive with the ZIP Create archive command.
• 4D ZIP file and folder instances are available through the root property (ZIP Folder) of the object returned by ZIP Read archive command.

Example

To retrieve and view the contents of a ZIP file object:

var $path; $archive : 4D.File
var $zipFile : 4D.ZipFile
var $zipFolder : 4D.ZipFolder
var $txt : Text

$path:=Folder(fk desktop folder).file("MyDocs/Archive.zip")
$archive:=ZIP Read archive($path)
$zipFolder:=$archive.root // store the zip main folder
$zipFile:=$zipFolder.files()[0] //read the first zipped file

If($zipFile.extension=".txt")
    $txt:=$zipFile.getText()
End if

---

ZIP Create archive

History

Version	Changes
v18	Added

ZIP Create archive ( fileToZip : 4D.File ; destinationFile : 4D.File ) : Object
ZIP Create archive ( folderToZip : 4D.Folder ; destinationFile : 4D.File { ; options : Integer }) : Object
ZIP Create archive ( zipStructure : Object ; destinationFile : 4D.File ) : Object

Parameter	Type		Description
fileToZip	4D.File	->	File or Folder object to compress
folderToZip	4D.Folder	->	File or Folder object to compress
zipStructure	Object	->	File or Folder object to compress
destinationFile	4D.File	->	Destination file for the archive
options	Integer	->	folderToZip option: ZIP Without enclosing folder
Result	Object	<-	Status object

Description

The ZIP Create archive command creates a compressed ZIP archive object and returns the status of the operation.

You can pass a 4D.File, a 4D.Folder, or a zip structure object as first parameter:

• fileToZip: You simply pass a 4D.File to compress.

• folderToZip: You pass a 4D.Folder to compress. In this case, the options parameter allows you to compress only the contents of the folder (i.e., exclude the enclosing folder). By default, ZIP Create archive will compress the folder and its contents, so that the decompressing operation will recreate a folder. If you want the decompressing operation to restore only the contents of the folder, pass the ZIP Without enclosing folder constant in the options parameter.

• zipStructure: You pass an object describing the ZIP archive object. The following properties are available to define the structure:

• a collection of 4D.File or 4D.Folder objects or
• a collection of objects with the following properties:

Property	Type	Description
source	4D.File or 4D.Folder <td> File or Folder </td></tr> <tr> <td> destination </td> <td> Text </td> <td> (optional) - Specify a relative filepath to change the organization of the contents of the archive </td> </tr> <tr> <td> option </td> <td> number </td> <td> (optional) - `ZIP Ignore invisible files` or 0 to compress all of the file </td> </tr></table></html>
callback	4D.Function	A callback formula that will receive the compression progress (0 - 100) in $1.

In the destinationFile parameter, pass a 4D.File object describing the ZIP archive to create (name, location, etc.). It is advised to use the ".zip" extension if you want the ZIP archive to be processed automatically by any software.

Once an archive is created, you can use the ZIP Read archive command to access it.

Status object

The returned status object contains the following properties:

Property	Type	Description
statusText	Text	Error message (if any): Cannot open ZIP archive Cannot create ZIP archive Password is required for encryption
status	Integer	Status code
success	Boolean	True if archive created successfully, else false

Example 1

To compress a 4D.File:

 var $file;$destination : 4D.File
 var $status : Object

 $destination:=Folder(fk desktop folder).file("MyDocs/file.zip")
 $file:=Folder(fk desktop folder).file("MyDocs/text.txt")

 $status:=ZIP Create archive($file;$destination)

Example 2

To compress a 4D.Folder without the folder itself:

 var $folder : 4D.Folder
 var $destination : 4D.File
 var $status : Object

 $destination:=Folder(fk desktop folder).file("MyDocs/Images.zip")
 $folder:=Folder(fk desktop folder).folder("MyDocs/Images")

 $status:=ZIP Create archive($folder;$destination;ZIP Without enclosing folder)

Example 3

To compress a ZIP archive structure with a password and progress bar:

 var $destination : 4D.File
 var $zip;$status : Object
 var progID : Integer

 $destination:=Folder(fk desktop folder).file("MyDocs/Archive.zip")

 $zip:=New object
 $zip.files:=Folder(fk desktop folder).folder("MyDocs/Resources").folders()
 $zip.password:="password"
 $zip.callback:=Formula(myFormulaCompressingMethod($1))

 progID:=Progress New //we use the 4D Progress component

 $status:=ZIP Create archive($zip;$destination)

 Progress QUIT(progID)

myFormulaCompressingMethod:

 var $1 : Integer
 Progress SET PROGRESS(progID;Num($1/100))

Example 4

You want to pass a collection of folders and files to compress to the zipStructure object:

 var $destination : 4D.File
 var $zip;$err : Object
 $zip:=New object
 $zip.files:=New collection
 $zip.files.push(New object("source";Folder(fk desktop folder).file("Tests/text.txt")))
 $zip.files.push(New object("source";Folder(fk desktop folder).file("Tests/text2.txt")))
 $zip.files.push(New object("source";Folder(fk desktop folder).file("Images/image.png")))

 $destination:=Folder(fk desktop folder).file("file.zip")
 $err:=ZIP Create archive($zip;$destination)

ZIP Read archive

History

Version	Changes
v18	Added

ZIP Read archive ( zipFile : 4D.File { ; password : Text }) : 4D.ZipArchive

Parameter	Type		Description
zipFile	4D.File	->	Zip archive file
password	Text	->	ZIP archive password if any
Result	4D.ZipArchive	<-	Archive object

Description

The ZIP Read archive command retrieves the contents of zipFile and returns it as a 4D.ZipArchive object.

This command does not uncompress the ZIP archive, it only provides a view of its contents. To extract the contents of an archive, you need to use methods such as file.copyTo() or folder.copyTo().

Pass a 4D.File object referencing the compressed ZIP archive in the zipFile parameter. The target archive file will be opened until the ZIP Read archive has finished executing and all contents/references have been extracted/released, then it will be closed automatically.

If the zipFile is password protected, you need to use the optional password parameter to provide a password. If a password is required but not passed when trying to read the contents of the archive, an error is generated.

Archive object

The returned 4D.ZipArchive object contains a single root property whose value is a 4D.Folder object. This folder describes the whole contents of the ZIP archive:

Property	Type	Description
root	4D.Folder	A virtual folder containing the contents of the ZIP archive.

The root folder and its contents can be manipulated with the File and Folder methods and properties.

Example

To retrieve and view the contents of a ZIP file object:

 var $archive : 4D.ZipArchive
 var $path : 4D.File

 $path:=Folder(fk desktop folder).file("MyDocs/Archive.zip")
 $archive:=ZIP Read archive($path)

To retrieve the list of the files and folders in the archive:

 $folders:=$archive.root.folders()
 $files:=$archive.root.files()

To read the contents of a file without extracting it from the root folder:

 If($files[$i].extension=".txt")
    $txt:=$files[$i].getText()
 Else
    $blob:=$files[$i].getContent()
 End if

To extract from the root folder:

  //extract a file
 $folderResult:=$files[$i].copyTo(Folder(fk desktop folder).folder("MyDocs"))

  //extract all files
 $folderResult:=$archive.root.copyTo(Folder(fk desktop folder).folder("MyDocs"))

---

Zip File object

The following properties and functions from the File class are available to 4D ZIP file objects:

Available File APIs for ZIP files	Comment
.copyTo( destinationFolder : 4D.Folder { ; newName : Text } { ; overwrite : Integer } ) : 4D.File
.creationDate : Date
.creationTime : Time
.exists : Boolean
.extension : Text
.fullName : Text
.getContent( ) : Blob
.getIcon( { size : Integer } ) : Picture
.getText( { charSetName : Text } { ; } { breakMode : integer} ) : Text .getText( { charSetNum : integer } { ; } { breakMode : integer} ) : Text
.hidden : Boolean
.isAlias : Boolean
.isFile : Boolean
.isFolder : Boolean
.isWritable : Boolean	Always false with ZIP archive
.modificationDate : Date
.modificationTime : Time
.name : Text
.original : 4D.File .original : 4D.Folder
.parent : 4D.Folder
.path : Text	Returns a path relative to the archive
.platformPath : Text

Zip Folder object

The following properties and functions from the Folder class are available to 4D ZIP folder objects:

Available Folder APIs for ZIP folder	Comment
.copyTo( destinationFolder : 4D.Folder { ; newName : Text } { ; overwrite : Integer } ) : 4D Folder
.creationDate : Date	Date may be different for the root folder from a folder within the archive
.creationTime : Time	Time may be different for the root folder from a folder within the archive
.exists : Boolean
.extension : Text
.file( path : Text ) : 4D.File
.files( { options : Integer } ) : Collection
.folder( path : Text ) : 4D.Folder
.folders( { options : Integer } ) : Collection
.fullName : Text
.getIcon( { size : Integer } ) : Picture
.hidden : Boolean
.isAlias : Boolean
.isFile : Boolean
.isFolder : Boolean
.isPackage : Boolean
.modificationDate : Date	Date may be different for the root folder from a folder within the archive
.modificationTime : Time	Time may be different for the root folder from a folder within the archive
.name : Text
.original : 4D.Folder
.parent : 4D.Folder	The archive's virtual root folder has no parent. However, the folders within the archive may have a parent other than the root.
.path : Text	Returns a path relative to the archive
.platformPath : Text