WP EXPORT DOCUMENT

WP EXPORT DOCUMENT ( wpDoc : Object ; filePath : Text {; format : Integer {; option : Object, Integer}} )
WP EXPORT DOCUMENT ( wpDoc : Object ; fileObj : 4D.File {; format : Integer {; option : Object, Integer}} )

Paramètres	Type		Description
wpDoc	Object	→	Variable 4D Write Pro
filePath	Text	→	Chemin du fichier d'export
fileObj	4D.File	→	Objet du fichier à exporter
format	Integer	→	Format de sortie du document (ex : .docx, .pdf, etc.)
option	Object, Integer	→	Options d'export, qui peuvent varier en fonction du format choisi.

Description

La commande WP EXPORT DOCUMENT exporte l'objet 4D Write Pro wpDoc vers un document sur disque selon le paramètre filePath ou fileObj ainsi que tout paramètre optionnel.

Dans wpDoc, passez l'objet 4D Write Pro que vous souhaitez exporter.

Vous pouvez passer soit un filePath ou fileObj :

• Dans filePath, passez le chemin de destination et le nom du document à exporter. Si vous ne passez que le nom du document, il sera sauvegardé au même niveau que le fichier de structure 4D.

• Dans le paramètre fileObj, passez un objet 4D.File représentant le fichier à exporter.

Vous pouvez omettre le paramètre format, auquel cas vous devez spécifier l'extension dans filePath. Vous pouvez également passer une constante du thème 4D Write Pro Constants dans le paramètre format. Dans ce cas, 4D ajoute l'extension appropriée au nom du fichier si nécessaire. Les formats suivants sont pris en charge:

Constante	Valeur	Commentaire
wk 4wp	4	Le document 4D Write Pro est sauvegardé dans un format d'archive natif (HTML zippé et images sauvegardées dans un dossier séparé). Les balises spécifiques 4D sont incluses et les expressions 4D ne sont pas calculées. Ce format est particulièrement adapté à la sauvegarde et à l'archivage des documents 4D Write Pro sur disque sans aucune perte.
wk docx	7	Extension .docx. Le document 4D Write Pro est enregistré au format Microsoft Word. Prise en charge certifiée de Microsoft Word 2010 et versions ultérieures. Les parties du document exportées sont les suivantes Corps / en-têtes / pieds de page / sections Page / paramètres d'impression (marges, image / couleur d'arrière-plan, bordures, padding, taille du papier / orientation) Images - en ligne, ancrées, et motif d'image d'arrière-plan (défini avec wk background image) Feuilles de style (caractère, paragraphe) Variables et expressions compatibles (numéro de page, nombre de pages, date, heure, métadonnées). Les variables et expressions non compatibles seront évaluées et figées avant l'exportation. Liens - Signets et URLs Notez que certains paramètres de 4D Write Pro peuvent ne pas être disponibles ou se comporter différemment dans Microsoft Word.
wk mime html	1	Le document 4D Write Pro est sauvegardé en tant que MIME HTML standard avec les documents HTML et les images intégrées en tant que parties MIME (encodées en base64). Les expressions sont calculées et les balises spécifiques à 4D ainsi que les liens de méthode sont supprimés. Seules les zones de texte ancrées dans la vue intégrée sont exportées (sous forme de divs). Ce format est particulièrement adapté à l'envoi de mails HTML.
wk pdf	5	Extension .pdf. Le document 4D Write Pro est enregistré au format PDF, sur la base du mode d'affichage Page. Les métadonnées suivantes sont exportées dans un document PDF : Titre / Auteur / Sujet / Créateur du contenu Notes : Les expressions sont automatiquement figées lors de l'exportation du document. Les liens vers les méthodes ne sont PAS exportés.
wk svg	8	La page du document 4D Write Pro est sauvegardée au format SVG, sur la base du mode d'affichage Page. Note: Lors de l'exportation en SVG, vous ne pouvez exporter qu'une page à la fois. Utilisez wk page index pour spécifier la page à exporter.
wk web page complete	2	Extension .htm ou .html. Le document est sauvegardé en HTML standard et ses ressources sont sauvegardées séparément. Les balises 4D et les liens vers les méthodes 4D sont supprimés et les expressions sont calculées. Seules les zones de texte ancrées dans la vue intégrée sont exportées (sous forme de divs). Ce format est particulièrement adapté lorsque vous souhaitez afficher un document 4D Write Pro dans un navigateur web.

Notes :

• "Balises spécifiques 4D" signifie XHTML 4D avec un espace de noms 4D et des styles CSS 4D.
• Pour plus d'informations sur le format du document 4D Write Pro, reportez-vous à .4wp document format.
• Pour consulter la liste des différences ou des incompatibilités connues lors de l'utilisation du format .docx, voir Importation et exportation au format .docx.
• Pour plus d'informations sur l'exportation au format SVG, voir Exportation au format SVG.

Paramètre option

Passez dans option un objet contenant les valeurs pour définir les propriétés du document exporté. Les propriétés suivantes sont disponibles :

Constante	Valeur	Commentaire
wk CID host domain name	cidHostDomain	Nom du domaine de l'hôte CID : domaine de l'hôte qui sera ajouté aux URL CID générées, y compris un "@" comme séparateur. Disponible uniquement lorsque le format wk mime html est utilisé.
wk embedded pictures	embeddedPictures	Pour l'exportation SVG uniquement. Définit si les images sont intégrées dans le fichier .svg exporté lorsque vous appelez WP EXPORT DOCUMENT. Valeurs disponibles : true (par défaut) : Les images sont intégrées dans le fichier .svg exporté false : Les images sont exportées dans un dossier appelé "nom_de_fichier_images" au niveau du fichier .svg exporté, "nom_de_fichier" étant le nom transmis à la commande pour le fichier, sans l'extension. Les images ne sont pas intégrées, mais sont référencées dans le fichier .svg. Note : Si le dossier existe déjà, il est vidé avant l'exportation du fichier. S'il n'y a pas d'image sur la page exportée, le dossier est supprimé
wk factur x	facturX	Pour l'exportation PDF uniquement. Valeur : un objet configurant un export PDF "Factur-X (ZUGFeRD)" (voir wk factur x object).
wk files	Historique	Pour l'exportation PDF uniquement. Valeur : collection d'objets, chacun d'entre eux décrivant un fichier à intégrer dans le document final (voir wk files collection). Cette fonctionnalité n'est prise en charge que dans les documents PDF/A-3 : lorsque l'attribut wk files est utilisé, la version "PDF/A-3" est automatiquement définie (l'attribut wk pdfa version est ignoré). Dans le cas d'un export PDF Factur-X (voir ci-dessous), le premier objet de la collection doit contenir le fichier xml Factur-X.
wk google fonts tag	googleFontsTag	Pour l'exportation SVG uniquement. Définit la règle d'importation des polices google dans le SVG exporté. Valeurs possibles : false (par défaut) : Aucune règle d'importation des polices de Google n'est ajoutée. true : Ajoute la règle @import au fichier exporté. Utile si vous voulez utiliser des polices qui ne sont pas disponibles par défaut sur Windows ou macOS. Note: Cette propriété est définie sur false par défaut car, lorsqu'elle est activée, les polices Google ont la priorité sur les polices natives, et ces dernières sont généralement mieux rendues dans le navigateur.
wk HTML pretty print	htmlPrettyPrint	Le code HTML est formaté pour être plus facile à lire.
wk max picture DPI	maxPictureDPI	Utilisé pour rééchantillonner (réduire) les images à la résolution souhaitée. Pour les images SVG dans Windows, utilisé pour le tramage. Valeurs par défaut : 300 (pour wk optimized for = wk print) 192 (pour wk optimized for = wk screen) Valeur maximale possible : 1440
wk optimized for	optimizedFor	Définit la manière dont un document exporté est optimisé en fonction du media auquel il est destiné. Valeurs possibles : wk print (valeur par défaut pour wk pdf et wk svg) Les images bitmap peuvent être réduites en utilisant le DPI défini par wk max picture DPI ou 300 (valeur par défaut) et peuvent être converties en PNG si le codec n'est pas pris en charge pour le type d'exportation. Les images vectorielles sont converties en PNG en utilisant le DPI défini par wk max picture DPI ou 300 (Windows uniquement). Si une image contient plus d'un format, le meilleur format pour l'impression est utilisé (e.g., .tiff au lieu de .jpg) wk screen (valeur par défaut pour wk web page complete et wk mime html). Les images bitmap peuvent être réduites en utilisant le DPI défini par wk max picture DPI ou 192 (valeur par défaut) et peuvent être converties en JPEG (images opaques) ou PNG (images transparentes) si le codec n'est pas pris en charge pour le type d'exportation. Les images vectorielles sont converties en PNG en utilisant le DPI défini par wk max picture DPI ou 192 (Windows uniquement). Si une image contient plus d'un format, le format de rendu d'écran est utilisé. Note: Les documents exportés au format wk docx sont toujours optimisés pour wk print (l'option wk optimized for est ignorée).
wk page index	pageIndex	Pour l'exportation SVG uniquement. Indice de la page à exporter au format svg (1 par défaut). L'indice des pages commence à 1 pour la première page du document. Note : L'indice des pages est indépendant de la numérotation des pages.
wk pdfa version	pdfaVersion	Exporte des PDF conformes à une version PDF/A. Pour plus d'informations sur les propriétés et les versions du PDF/A, veuillez consulter la page PDF/A sur Wikipedia. Valeurs possibles : wk pdfa2 : Exporte en version "PDF/A-2" wk pdfa3 : Exporte en version "PDF/A-3" Note: Sous macOS, wk pdfa2 peut exporter vers PDF/A-2 ou PDF/A-3 ou plus, selon l'implémentation de la plateforme. Aussi, wk pdfa3 signifie "exporte vers au moins PDF/A-3". Sous Windows, le fichier PDF de sortie sera toujours égal à la conformité souhaitée.
wk recompute formulas	recomputeFormulas	Définit si les formules doivent être recalculées lorsqu'elles sont exportées. Valeurs possibles : true - Valeur par défaut. Toutes les formules sont recalculées false - Ne pas recalculer les formules
wk visible background and anchored elements	visibleBackground	Affiche ou exporte les images/couleurs d'arrière-plan, les images ancrées et les zones de texte (pour l'affichage, effet visible en mode d'affichage Page ou Inclus uniquement). Valeurs possibles : True/False
wk visible empty images	visibleEmptyImages	Affiche ou exporte un rectangle noir par défaut pour les images qui ne peuvent pas être chargées ou calculées (images vides ou images dans un format non pris en charge). Valeurs possibles : True/False. Valeur par défaut : Vrai. Si la valeur est False, les éléments d'image manquants ne seront pas affichés du tout, même s'ils ont des bordures, une largeur, une hauteur ou un arrière-plan ; cela peut avoir un impact sur la mise en page pour les images en ligne.
wk visible footers	visibleFooters	Affiche ou exporte les pieds de page (pour l'affichage, effet visible en mode Page uniquement). Valeurs possibles : True/False
wk visible headers	visibleHeaders	Affiche ou exporte les en-têtes (pour l'affichage, effet visible en mode Page uniquement). Valeurs possibles : True/False
wk visible references	visibleReferences	Affiche ou exporte toutes les expressions 4D insérées dans le document en tant que références. Valeurs possibles : True/False
wk whitespace	whitespace	Définit la valeur css "white-space" pour les formats d'exportation wk mime html et wk web page complete. Le style white-space css est appliqué aux paragraphes. Valeurs possibles : "normal", "nowrap", "pre", "pre-wrap" (par défaut), "pre-line", "break-spaces".

Le tableau suivant indique l'option disponible par format d'export :

	wk 4wp	wk docx	wk mime html	wk pdf	wk web page complete	wk svg
wk CID host domain name	-	-		-	-	-
wk embedded pictures	-	-	-	-	-	(par défaut : true)
wk factur x	-	-	-		-	-
wk files	-	-	-		-	-
wk google fonts tag	-	-	-	-	-	(par défaut : false)
wk HTML pretty print	(par défaut : false)	-	(par défaut : False)	(par défaut : False)	(par défaut : False)	(par défaut : false)
wk max picture DPI	-	toujours 300		(par défaut : 300)	-	(par défaut : 300)
wk optimized for	-	toujours wk print	(default: wk screen)	toujours wk print	-	(par défaut : wk print)
wk page index	-	-	-	-	-	(par défaut : 1)
wk pdfa version	-	-	-		-	-
wk recompute formulas	-	(par défaut : true)	(par défaut : true)	(par défaut : true)	-	(par défaut : true)
wk visible background and anchored elements	-	(par défaut : true)	toujours true	(par défaut : true)	-	(par défaut : true)
wk visible empty images	-	(par défaut : true)	(par défaut : true)	(par défaut : true)	-	(par défaut : true)
wk visible footers	-	toujours true	toujours false	(par défaut : true)	-	(par défaut : true)
wk visible headers	-	toujours true	toujours false	(par défaut : true)	-	(par défaut : true)
wk visible references	-	-	-	(par défaut : false)	-	(par défaut : false)
wk whitespace	-	-	(par défaut : "pre-wrap")	-	(par défaut : "pre-wrap")	-

Note de compatibilité : Passer une valeur longint dans option est pris en charge pour des raisons de compatibilité, mais il est recommandé d'utiliser un paramètre objet.

Collection wk files

La propriété wk files vous permet d'exporter un PDF avec des pièces jointes. Cette propriété doit contenir une collection d'objets décrivant les fichiers à incorporer dans le document final. Chaque objet de la collection peut contenir les propriétés suivantes :

Propriété	Type	Description
name	Text	Nom de fichier. Facultatif si la propriété file est utilisée, auquel cas le nom est déduit par défaut du nom de fichier. Obligatoire si la propriété data est utilisée (sauf pour le premier fichier d'un export Factur-X, auquel cas le nom du fichier est automatiquement "factur-x.xml", voir ci-dessous)
Description	Text	Optionnel. Si omis, la valeur par défaut du premier fichier d'exportation vers Factur-X est "Factur-X/ZUGFeRD Invoice", sinon il est vide.
mimeType	Text	Optionnel. Si omis, la valeur par défaut peut généralement être déduite à partir de l'extension de fichier; sinon, "application/octet-stream" est utilisé. Si cette option est passée, assurez-vous d'utiliser un type mime ISO, sinon le fichier exporté pourrait être invalide.
data	Text ou BLOB	Obligatoire si la propriété file est manquante
file	4D.File object	Obligatoire si la propriété data est manquante, ignorée sinon.
relationship	Text	Optionnel. Si omis, la valeur par défaut est "Data". Possible values for Factur-X first file: for BASIC, EN 16931 or EXTENDED profiles: "Alternative", "Source" or "Data" ("Alternative" only for German invoice) for MINIMUM and BASIC WL profiles: "Data" only. for other profiles: "Alternative", "Source" or "Data" (with restrictions perhaps depending on country: see profile specification for more info about other profiles - for instance for RECHNUNG profile only "Alternative" is allowed) for other files (but Factur-X invoice xml file) : "Alternative", "Source", "Data", "Supplement" or "Unspecified" any other value generates an error.

Si le paramètre option contient également une propriété wk factur x, le premier élément de la collection wk files doit être le fichier xml de la facture Factur-X (ZUGFeRD) (voir ci-dessous).

note

Les pièces jointes au format PDF sont uniquement prises en charge par la version PDF/A-3. Lorsque vous passez la propriété wk files, la version "PDF/A-3" est automatiquement utilisée.

Objet wk factur x

La propriété wk factur x est un objet qui peut contenir jusqu'à deux propriétés :

Propriété	Type	Description
profile	Text	Optionnel. S'il est omis, profile est déterminé à partir du fichier xml ou du texte fourni (qui doit utiliser un profil standard). S'il est passé, il peut s'agir d'un nom de profil non standard (pour l'utilisation d'autres profils - par exemple RECHNUNG). Note : Les noms de profil standard sont : MINIMUM, BASIC WL, BASIC, EN 16931 (aka COMFORT qui est un alias), EXTENDED.
version	Text	Optionnel. La valeur par défaut est "1.0"

À propos des documents PDF Factur-X / ZUGFeRD

Factur-X / ZUGFeRD est une norme européenne pour les factures électroniques hybrides (PDF pour les utilisateurs et données XML pour l'automatisation des processus). Pour plus d'informations, veuillez lire cet article de blog.

Pour déclencher une exportation PDF "Factur-X", passez les propriétés wk factur x et wk files dans le paramètre option (voir exemple 5). Dans ce cas :

• un PDF Factur-X (ZUGFeRD) est généré,
• le premier élément de la collection wk files est utilisé comme fichier xml Factur-X,
• si la propriété wk files est manquante ou contient une collection vide, ou si son premier élément n'est pas un fichier xml, une erreur est générée.

note

Pour un exemple détaillé de la mise en œuvre de l'exportation Factur-X / ZUGFeRD, vous pouvez télécharger ce projet HDI 4D.

Exemple 1

Vous souhaitez exporter le contenu de l'objet 4D Write Pro myArea aux formats HTML et PDF :

  // exporter HTML
 var $option : Object
 $option:=New object

 $option[wk recompute formulas]:=False
 $option[wk HTML pretty print]:=False
 $option[wk optimized for]:=wk print
 $option[wk max picture DPI]:=600 //remplacer la valeur par défaut pour l'impression (300 DPI)

 WP EXPORT DOCUMENT(myArea;$path;wk web page complete;$option)

  //exporter PDF
 var $option : Object
 $option:=New object

 $option[wk visible headers]:=True
 $option[wk visible footers]:=True
 $option[wk visible background]:=True
 $option[wk max picture DPI]:=96 //remplacer la valeur par défaut pour l'écran (192 DPI) pour limiter la taille du document
 $option[wk optimized for]:=wk screen
 $option[wk recompute formulas]:=True

 WP EXPORT DOCUMENT(myArea;$path;wk pdf;$option)

Exemple 2

Vous souhaitez exporter le contenu de l'objet 4D Write Pro myArea au format .4wp :

 var $path : Text

 Case of
    :(Form event code=On Clicked)

       $path:=Get 4D folder(Database folder)+"Export"+Folder separator
       $path:=Select document($path;".4wp";" title";File name entry)

       If($path#"")
          WP EXPORT DOCUMENT(myArea;document;wk 4wp)
       End if
 End case

Exemple 3

Pour exporter la deuxième page du document en SVG et exporter les images depuis le document :

 var $options : Object

 $options:=New object
 $options[wk embedded pictures]:=False
 $options[wk page index]:=2

 WP EXPORT DOCUMENT(WPArea;"my exported document";wk svg;$options)

Exemple 4

Exportation d'un document PDF conforme à la norme PDF/A-2 :

 var $options: Object:={}
 $options[wk visible empty images] :=False
 $options[wk pdfa version]:=wk pdfa2 // conformité "PDF/A-2"
 WP EXPORT DOCUMENT(wpDoc;"invoice.pdf";wk pdf;$options)

Exemple 5

Exemples d'exportations PDF de Factur-X :

  //BASIC (profil standard)
 var $options;$fileInfo : Object
 $options:={}
 $options[wk factur x]:={}
 $options[wk factur x].profile:="BASIC"
 $options[wk factur x].version:="1.0"

 $fileInfo:={}
 $fileInfo.file:=$file  //$file est un 4D.File avec un fichier .xml comme cible
 $options[wk files]:=[$fileInfo]

 WP EXPORT DOCUMENT(wpDoc;"facturX_basic.pdf";wk pdf;$options)

  //Profil RECHNUNG (profil personnalisé)
 $options:={}
 $options[wk factur x]:={}
 $options[wk factur x].profile:="RECHNUNG"
 $options[wk factur x].version:="2.1" //dernière version pour RECHNUNG

 $fileInfo:={}
 $fileInfo.file:=$file  //$file est un 4D.File avec un fichier .xml comme cible
 $fileInfo.name:="rechnung.xml" //Nom de fichier obligatoire dans le PDF pour RECHNUNG
 $fileInfo.relationship:="Alternative" //obligatoire pour l'Allemagne
 $fileInfo.description:="ZUGFeRD Rechnung"
 $options[wk files]:=[$fileInfo]

 WP EXPORT DOCUMENT(wpDoc;"facturX_rechnung.pdf";wk pdf;$options)

Exemple 6

Exportation d'un document docx en utilisant un objet File :

var $file : 4D.File

$file:=File("/DATA/test-export")

$options:=New object(wk visible background and anchored elements; False)

WP EXPORT DOCUMENT(WParea; $file; wk docx; $options)

Voir également

4D QPDF (Component) - PDF Get attachments
Exporter aux formats HTML et MIME HTML
Importer et exporter au format .docx
Blog post - 4D Write Pro: Electronic invoice generation
Blog post - 4D Write Pro: Export to PDF with enclosures
WP EXPORT VARIABLE