WP New style sheet

WP New style sheet ( wpDoc : Object ; styleSheetType : Integer ; styleSheetName : Text {; listLevelCount : Integer} ) : Object

Paramètres	Type		Description
wpDoc	Object	→	Document 4D Write Pro
styleSheetType	Integer	→	Type de la feuille de style
styleSheetName	Text	→	Nom de la feuille de style
listLevelCount	Integer	→	Nombre total de niveaux dans la hiérarchie
Résultat	Object	←	Objet feuille de style

Historique

Release	Modifications
4D 18	Created
4D 21 R3	Ajout du paramètre listLevelCount

Description

La commande WP New style sheet crée un nouvel objet de feuille de style (vide) pour le wpDoc désigné.

Dans le paramètre wpDoc, passez un document 4D Write Pro.

Le paramètre styleSheetType vous permet d'indiquer le type de la feuille de style, c'est-à-dire la partie du wpDoc qui sera affectée par la feuille de style. Deux types sont disponibles :

• wk type character: Applique les attributs de style aux caractères.
• wk type paragraph: Applique les attributs de style aux paragraphes (nécessaire si vous souhaitez créer des feuilles de style de liste hiérarchique).

Passez un nom pour la feuille de style dans le paramètre styleSheetName. Le nom de la feuille de style est stocké avec le document et facilite la réutilisation ou la modification du style. Il peut également être utilisé avec les commandes WP Get style sheet et WP DELETE STYLE SHEET. Le nom de la feuille de style doit respecter les règles suivantes :

• il doit commencer par une lettre
• il peut alors contenir des caractères alphanumériques, des caractères d'espacement, des caractères "-" ou des caractères unicode >= 128
• il doit être unique dans le document, quel que soit le type
• il ne doit pas commencer par "section", qui est réservé
• le "_" est remplacé par un espace et les espaces qui suivent sont supprimés.

Vous pouvez spécifier les attributs de la feuille de style en utilisant la commande WP SET ATTRIBUTES ou la notation objet (voir 4D Write Pro Attributes). Pour la liste des attributs disponibles, voir la section Attributs des feuilles de style.

Notes :

• Une feuille de style ne modifie que l'affichage d'un caractère ou d'un paragraphe, et non la façon dont il est stocké dans le document. Si une feuille de style est supprimée, le texte reprendra le style par défaut.
• Tous les attributs de style qui ne sont pas définis dans la nouvelle feuille de style utiliseront automatiquement le style Normal. Pour plus d'informations, voir la page Feuilles de style.

Feuille de style de liste hiérarchique

Si le paramètre styleSheetType est défini sur wk type paragraph, vous pouvez optionnellement passer le paramètre listLevelCount pour créer une feuille de style liste hiérarchique.

Le paramètre listLevelCount définit le nombre total de niveaux dans la hiérarchie. Lorsqu'elle est spécifiée (valeur ≥ 1), la commande crée automatiquement une feuille de style de niveau racine et les feuilles de style de niveau inférieur correspondantes.

Les valeurs prédéfinies suivantes sont appliquées :

• wk list style type est fixé à wk decimal
• wk list level index est automatiquement assigné (1 pour le niveau racine, incrémenté pour les sous-niveaux)
• wk list level count est fixé à la valeur spécifiée pour tous les niveaux
• wk margin left est automatiquement calculé (0,75 cm × indice de niveau ou 0,25 pouces * indice de niveau, en fonction de l'unité de mise en page actuelle) : le décalage peut donc être différent selon que l'unité de mise en page est métrique ou en pouces (pour un meilleur alignement par défaut avec les graduations de la règle d'écriture courante).

Si le paramètre est omis ou fixé à 0, une feuille de style de paragraphe standard (non-liste) est créée.

Exemple 1

Le code suivant crée et définit une feuille de style de paragraphe :

 var $styleSheet : Object
 $styleSheet:=WP New style sheet(wpArea;wk type paragraph;"Main title")
 
  //définir les paramètres de la feuille de style
 WP SET ATTRIBUTES($styleSheet;wk font family;"Papyrus")
 WP SET ATTRIBUTES($styleSheet;wk font size;"48pt")
 WP SET ATTRIBUTES($styleSheet;wk text color;"red")
 WP SET ATTRIBUTES($styleSheet;wk text align;wk left)
 
  //Appliquer la feuille de style au premier paragraphe
 var $Paragraphs : Collection
 $Paragraphs:=WP Get elements(wpArea;wk type paragraph)
 If($Paragraphs.length>0)
    WP SET ATTRIBUTES($Paragraphs[0];wk style sheet;$styleSheet)
 End if

Exemple 2

Le code suivant crée une feuille de style de liste hiérarchique à 3 niveaux :

var $mainList : Object

$mainList:=WP New style sheet(wpArea ; wk type paragraph ; "MainList" ; 3)

// La commande crée automatiquement :
// - 1 feuille de style de niveau racine (" MainList ")
// - 2 feuilles de style de niveau inférieur (" MainList lvl 2 " et " MainList lvl 3 ")

Résultat:

• La feuille de style racine :

  • wk list level index = 1
  • wk list level count = 3
  • wk list style type = wk decimal

• Les feuilles de style de sous-niveau :

  • ont des valeurs wk list level index incrémentées (2 et 3)
  • partagent le même wk list level count
  • sont automatiquement indentés (0,75 cm × indice de niveau)
  • font référence à la feuille de style racine via wk root style

Voir également

Style sheets
WP DELETE STYLE SHEET
WP Get style sheet
WP Get style sheets
WP IMPORT STYLE SHEETS